ztpcon.f

Go to the documentation of this file.

*> \brief \b ZTPCON
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download ZTPCON + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztpcon.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztpcon.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztpcon.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZTPCON( NORM, UPLO, DIAG, N, AP, RCOND, WORK, RWORK,
*                          INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, NORM, UPLO
*       INTEGER            INFO, N
*       DOUBLE PRECISION   RCOND
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         AP( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZTPCON estimates the reciprocal of the condition number of a packed
*> triangular matrix A, in either the 1-norm or the infinity-norm.
*>
*> The norm of A is computed and an estimate is obtained for
*> norm(inv(A)), then the reciprocal of the condition number is
*> computed as
*>    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies whether the 1-norm condition number or the
*>          infinity-norm condition number is required:
*>          = '1' or 'O':  1-norm;
*>          = 'I':         Infinity-norm.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          = 'U':  A is upper triangular;
*>          = 'L':  A is lower triangular.
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>          = 'N':  A is non-unit triangular;
*>          = 'U':  A is unit triangular.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The upper or lower triangular matrix A, packed columnwise in
*>          a linear array.  The j-th column of A is stored in the array
*>          AP as follows:
*>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
*>          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
*>          If DIAG = 'U', the diagonal elements of A are not referenced
*>          and are assumed to be 1.
*> \endverbatim
*>
*> \param[out] RCOND
*> \verbatim
*>          RCOND is DOUBLE PRECISION
*>          The reciprocal of the condition number of the matrix A,
*>          computed as RCOND = 1/(norm(A) * norm(inv(A))).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16OTHERcomputational
*
*  =====================================================================
      SUBROUTINE ztpcon( NORM, UPLO, DIAG, N, AP, RCOND, WORK, RWORK,
     $                   info )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          diag, norm, uplo
      INTEGER            info, n
      DOUBLE PRECISION   rcond
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         ap( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            nounit, onenrm, upper
      CHARACTER          normin
      INTEGER            ix, kase, kase1
      DOUBLE PRECISION   ainvnm, anorm, scale, smlnum, xnorm
      COMPLEX*16         zdum
*     ..
*     .. Local Arrays ..
      INTEGER            isave( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            izamax
      DOUBLE PRECISION   dlamch, zlantp
      EXTERNAL           lsame, izamax, dlamch, zlantp
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdrscl, zlacn2, zlatps
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZTPCON', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         rcond = one
         return
      END IF
*
      rcond = zero
      smlnum = dlamch( 'Safe minimum' )*dble( max( 1, n ) )
*
*     Compute the norm of the triangular matrix A.
*
      anorm = zlantp( norm, uplo, diag, n, ap, rwork )
*
*     Continue only if ANORM > 0.
*
      IF( anorm.GT.zero ) THEN
*
*        Estimate the norm of the inverse of A.
*
         ainvnm = zero
         normin = 'N'
         IF( onenrm ) THEN
            kase1 = 1
         ELSE
            kase1 = 2
         END IF
         kase = 0
   10    continue
         CALL zlacn2( n, work( n+1 ), work, ainvnm, kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.kase1 ) THEN
*
*              Multiply by inv(A).
*
               CALL zlatps( uplo, 'No transpose', diag, normin, n, ap,
     $                      work, scale, rwork, info )
            ELSE
*
*              Multiply by inv(A**H).
*
               CALL zlatps( uplo, 'Conjugate transpose', diag, normin,
     $                      n, ap, work, scale, rwork, info )
            END IF
            normin = 'Y'
*
*           Multiply by 1/SCALE if doing so will not cause overflow.
*
            IF( scale.NE.one ) THEN
               ix = izamax( n, work, 1 )
               xnorm = cabs1( work( ix ) )
               IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
     $            go to 20
               CALL zdrscl( n, scale, work, 1 )
            END IF
            go to 10
         END IF
*
*        Compute the estimate of the reciprocal condition number.
*
         IF( ainvnm.NE.zero )
     $      rcond = ( one / anorm ) / ainvnm
      END IF
*
   20 continue
      return
*
*     End of ZTPCON
*
      END