zchkhs.f

Go to the documentation of this file.

*> \brief \b ZCHKHS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKHS( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          NOUNIT, A, LDA, H, T1, T2, U, LDU, Z, UZ, W1,
*                          W3, EVECTL, EVECTR, EVECTY, EVECTX, UU, TAU,
*                          WORK, NWORK, RWORK, IWORK, SELECT, RESULT,
*                          INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDU, NOUNIT, NSIZES, NTYPES, NWORK
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * ), SELECT( * )
*       INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
*       DOUBLE PRECISION   RESULT( 14 ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), EVECTL( LDU, * ),
*      $                   EVECTR( LDU, * ), EVECTX( LDU, * ),
*      $                   EVECTY( LDU, * ), H( LDA, * ), T1( LDA, * ),
*      $                   T2( LDA, * ), TAU( * ), U( LDU, * ),
*      $                   UU( LDU, * ), UZ( LDU, * ), W1( * ), W3( * ),
*      $                   WORK( * ), Z( LDU, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    ZCHKHS  checks the nonsymmetric eigenvalue problem routines.
*>
*>            ZGEHRD factors A as  U H U' , where ' means conjugate
*>            transpose, H is hessenberg, and U is unitary.
*>
*>            ZUNGHR generates the unitary matrix U.
*>
*>            ZUNMHR multiplies a matrix by the unitary matrix U.
*>
*>            ZHSEQR factors H as  Z T Z' , where Z is unitary and T
*>            is upper triangular.  It also computes the eigenvalues,
*>            w(1), ..., w(n); we define a diagonal matrix W whose
*>            (diagonal) entries are the eigenvalues.
*>
*>            ZTREVC computes the left eigenvector matrix L and the
*>            right eigenvector matrix R for the matrix T.  The
*>            columns of L are the complex conjugates of the left
*>            eigenvectors of T.  The columns of R are the right
*>            eigenvectors of T.  L is lower triangular, and R is
*>            upper triangular.
*>
*>            ZHSEIN computes the left eigenvector matrix Y and the
*>            right eigenvector matrix X for the matrix H.  The
*>            columns of Y are the complex conjugates of the left
*>            eigenvectors of H.  The columns of X are the right
*>            eigenvectors of H.  Y is lower triangular, and X is
*>            upper triangular.
*>
*>    When ZCHKHS is called, a number of matrix "sizes" ("n's") and a
*>    number of matrix "types" are specified.  For each size ("n")
*>    and each type of matrix, one matrix will be generated and used
*>    to test the nonsymmetric eigenroutines.  For each matrix, 14
*>    tests will be performed:
*>
*>    (1)     | A - U H U**H | / ( |A| n ulp )
*>
*>    (2)     | I - UU**H | / ( n ulp )
*>
*>    (3)     | H - Z T Z**H | / ( |H| n ulp )
*>
*>    (4)     | I - ZZ**H | / ( n ulp )
*>
*>    (5)     | A - UZ H (UZ)**H | / ( |A| n ulp )
*>
*>    (6)     | I - UZ (UZ)**H | / ( n ulp )
*>
*>    (7)     | T(Z computed) - T(Z not computed) | / ( |T| ulp )
*>
*>    (8)     | W(Z computed) - W(Z not computed) | / ( |W| ulp )
*>
*>    (9)     | TR - RW | / ( |T| |R| ulp )
*>
*>    (10)    | L**H T - W**H L | / ( |T| |L| ulp )
*>
*>    (11)    | HX - XW | / ( |H| |X| ulp )
*>
*>    (12)    | Y**H H - W**H Y | / ( |H| |Y| ulp )
*>
*>    (13)    | AX - XW | / ( |A| |X| ulp )
*>
*>    (14)    | Y**H A - W**H Y | / ( |A| |Y| ulp )
*>
*>    The "sizes" are specified by an array NN(1:NSIZES); the value of
*>    each element NN(j) specifies one size.
*>    The "types" are specified by a logical array DOTYPE( 1:NTYPES );
*>    if DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*>    Currently, the list of possible types is:
*>
*>    (1)  The zero matrix.
*>    (2)  The identity matrix.
*>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
*>
*>    (4)  A diagonal matrix with evenly spaced entries
*>         1, ..., ULP  and random complex angles.
*>         (ULP = (first number larger than 1) - 1 )
*>    (5)  A diagonal matrix with geometrically spaced entries
*>         1, ..., ULP  and random complex angles.
*>    (6)  A diagonal matrix with "clustered" entries 1, ULP, ..., ULP
*>         and random complex angles.
*>
*>    (7)  Same as (4), but multiplied by SQRT( overflow threshold )
*>    (8)  Same as (4), but multiplied by SQRT( underflow threshold )
*>
*>    (9)  A matrix of the form  U' T U, where U is unitary and
*>         T has evenly spaced entries 1, ..., ULP with random complex
*>         angles on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (10) A matrix of the form  U' T U, where U is unitary and
*>         T has geometrically spaced entries 1, ..., ULP with random
*>         complex angles on the diagonal and random O(1) entries in
*>         the upper triangle.
*>
*>    (11) A matrix of the form  U' T U, where U is unitary and
*>         T has "clustered" entries 1, ULP,..., ULP with random
*>         complex angles on the diagonal and random O(1) entries in
*>         the upper triangle.
*>
*>    (12) A matrix of the form  U' T U, where U is unitary and
*>         T has complex eigenvalues randomly chosen from
*>         ULP < |z| < 1   and random O(1) entries in the upper
*>         triangle.
*>
*>    (13) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
*>         with random complex angles on the diagonal and random O(1)
*>         entries in the upper triangle.
*>
*>    (14) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has geometrically spaced entries
*>         1, ..., ULP with random complex angles on the diagonal
*>         and random O(1) entries in the upper triangle.
*>
*>    (15) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has "clustered" entries 1, ULP,..., ULP
*>         with random complex angles on the diagonal and random O(1)
*>         entries in the upper triangle.
*>
*>    (16) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has complex eigenvalues randomly chosen
*>         from   ULP < |z| < 1   and random O(1) entries in the upper
*>         triangle.
*>
*>    (17) Same as (16), but multiplied by SQRT( overflow threshold )
*>    (18) Same as (16), but multiplied by SQRT( underflow threshold )
*>
*>    (19) Nonsymmetric matrix with random entries chosen from |z| < 1
*>    (20) Same as (19), but multiplied by SQRT( overflow threshold )
*>    (21) Same as (19), but multiplied by SQRT( underflow threshold )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \verbatim
*>  NSIZES - INTEGER
*>           The number of sizes of matrices to use.  If it is zero,
*>           ZCHKHS does nothing.  It must be at least zero.
*>           Not modified.
*>
*>  NN     - INTEGER array, dimension (NSIZES)
*>           An array containing the sizes to be used for the matrices.
*>           Zero values will be skipped.  The values must be at least
*>           zero.
*>           Not modified.
*>
*>  NTYPES - INTEGER
*>           The number of elements in DOTYPE.   If it is zero, ZCHKHS
*>           does nothing.  It must be at least zero.  If it is MAXTYP+1
*>           and NSIZES is 1, then an additional type, MAXTYP+1 is
*>           defined, which is to use whatever matrix is in A.  This
*>           is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>           DOTYPE(MAXTYP+1) is .TRUE. .
*>           Not modified.
*>
*>  DOTYPE - LOGICAL array, dimension (NTYPES)
*>           If DOTYPE(j) is .TRUE., then for each size in NN a
*>           matrix of that size and of type j will be generated.
*>           If NTYPES is smaller than the maximum number of types
*>           defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>           MAXTYP will not be generated.  If NTYPES is larger
*>           than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>           will be ignored.
*>           Not modified.
*>
*>  ISEED  - INTEGER array, dimension (4)
*>           On entry ISEED specifies the seed of the random number
*>           generator. The array elements should be between 0 and 4095;
*>           if not they will be reduced mod 4096.  Also, ISEED(4) must
*>           be odd.  The random number generator uses a linear
*>           congruential sequence limited to small integers, and so
*>           should produce machine independent random numbers. The
*>           values of ISEED are changed on exit, and can be used in the
*>           next call to ZCHKHS to continue the same random number
*>           sequence.
*>           Modified.
*>
*>  THRESH - DOUBLE PRECISION
*>           A test will count as "failed" if the "error", computed as
*>           described above, exceeds THRESH.  Note that the error
*>           is scaled to be O(1), so THRESH should be a reasonably
*>           small multiple of 1, e.g., 10 or 100.  In particular,
*>           it should not depend on the precision (single vs. double)
*>           or the size of the matrix.  It must be at least zero.
*>           Not modified.
*>
*>  NOUNIT - INTEGER
*>           The FORTRAN unit number for printing out error messages
*>           (e.g., if a routine returns IINFO not equal to 0.)
*>           Not modified.
*>
*>  A      - COMPLEX*16 array, dimension (LDA,max(NN))
*>           Used to hold the matrix whose eigenvalues are to be
*>           computed.  On exit, A contains the last matrix actually
*>           used.
*>           Modified.
*>
*>  LDA    - INTEGER
*>           The leading dimension of A, H, T1 and T2.  It must be at
*>           least 1 and at least max( NN ).
*>           Not modified.
*>
*>  H      - COMPLEX*16 array, dimension (LDA,max(NN))
*>           The upper hessenberg matrix computed by ZGEHRD.  On exit,
*>           H contains the Hessenberg form of the matrix in A.
*>           Modified.
*>
*>  T1     - COMPLEX*16 array, dimension (LDA,max(NN))
*>           The Schur (="quasi-triangular") matrix computed by ZHSEQR
*>           if Z is computed.  On exit, T1 contains the Schur form of
*>           the matrix in A.
*>           Modified.
*>
*>  T2     - COMPLEX*16 array, dimension (LDA,max(NN))
*>           The Schur matrix computed by ZHSEQR when Z is not computed.
*>           This should be identical to T1.
*>           Modified.
*>
*>  LDU    - INTEGER
*>           The leading dimension of U, Z, UZ and UU.  It must be at
*>           least 1 and at least max( NN ).
*>           Not modified.
*>
*>  U      - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The unitary matrix computed by ZGEHRD.
*>           Modified.
*>
*>  Z      - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The unitary matrix computed by ZHSEQR.
*>           Modified.
*>
*>  UZ     - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The product of U times Z.
*>           Modified.
*>
*>  W1     - COMPLEX*16 array, dimension (max(NN))
*>           The eigenvalues of A, as computed by a full Schur
*>           decomposition H = Z T Z'.  On exit, W1 contains the
*>           eigenvalues of the matrix in A.
*>           Modified.
*>
*>  W3     - COMPLEX*16 array, dimension (max(NN))
*>           The eigenvalues of A, as computed by a partial Schur
*>           decomposition (Z not computed, T only computed as much
*>           as is necessary for determining eigenvalues).  On exit,
*>           W3 contains the eigenvalues of the matrix in A, possibly
*>           perturbed by ZHSEIN.
*>           Modified.
*>
*>  EVECTL - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The conjugate transpose of the (upper triangular) left
*>           eigenvector matrix for the matrix in T1.
*>           Modified.
*>
*>  EVEZTR - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The (upper triangular) right eigenvector matrix for the
*>           matrix in T1.
*>           Modified.
*>
*>  EVECTY - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The conjugate transpose of the left eigenvector matrix
*>           for the matrix in H.
*>           Modified.
*>
*>  EVECTX - COMPLEX*16 array, dimension (LDU,max(NN))
*>           The right eigenvector matrix for the matrix in H.
*>           Modified.
*>
*>  UU     - COMPLEX*16 array, dimension (LDU,max(NN))
*>           Details of the unitary matrix computed by ZGEHRD.
*>           Modified.
*>
*>  TAU    - COMPLEX*16 array, dimension (max(NN))
*>           Further details of the unitary matrix computed by ZGEHRD.
*>           Modified.
*>
*>  WORK   - COMPLEX*16 array, dimension (NWORK)
*>           Workspace.
*>           Modified.
*>
*>  NWORK  - INTEGER
*>           The number of entries in WORK.  NWORK >= 4*NN(j)*NN(j) + 2.
*>
*>  RWORK  - DOUBLE PRECISION array, dimension (max(NN))
*>           Workspace.  Could be equivalenced to IWORK, but not SELECT.
*>           Modified.
*>
*>  IWORK  - INTEGER array, dimension (max(NN))
*>           Workspace.
*>           Modified.
*>
*>  SELECT - LOGICAL array, dimension (max(NN))
*>           Workspace.  Could be equivalenced to IWORK, but not RWORK.
*>           Modified.
*>
*>  RESULT - DOUBLE PRECISION array, dimension (14)
*>           The values computed by the fourteen tests described above.
*>           The values are currently limited to 1/ulp, to avoid
*>           overflow.
*>           Modified.
*>
*>  INFO   - INTEGER
*>           If 0, then everything ran OK.
*>            -1: NSIZES < 0
*>            -2: Some NN(j) < 0
*>            -3: NTYPES < 0
*>            -6: THRESH < 0
*>            -9: LDA < 1 or LDA < NMAX, where NMAX is max( NN(j) ).
*>           -14: LDU < 1 or LDU < NMAX.
*>           -26: NWORK too small.
*>           If  ZLATMR, CLATMS, or CLATME returns an error code, the
*>               absolute value of it is returned.
*>           If 1, then ZHSEQR could not find all the shifts.
*>           If 2, then the EISPACK code (for small blocks) failed.
*>           If >2, then 30*N iterations were not enough to find an
*>               eigenvalue or to decompose the problem.
*>           Modified.
*>
*>-----------------------------------------------------------------------
*>
*>     Some Local Variables and Parameters:
*>     ---- ----- --------- --- ----------
*>
*>     ZERO, ONE       Real 0 and 1.
*>     MAXTYP          The number of types defined.
*>     MTEST           The number of tests defined: care must be taken
*>                     that (1) the size of RESULT, (2) the number of
*>                     tests actually performed, and (3) MTEST agree.
*>     NTEST           The number of tests performed on this matrix
*>                     so far.  This should be less than MTEST, and
*>                     equal to it by the last test.  It will be less
*>                     if any of the routines being tested indicates
*>                     that it could not compute the matrices that
*>                     would be tested.
*>     NMAX            Largest value in NN.
*>     NMATS           The number of matrices generated so far.
*>     NERRS           The number of tests which have exceeded THRESH
*>                     so far (computed by DLAFTS).
*>     COND, CONDS,
*>     IMODE           Values to be passed to the matrix generators.
*>     ANORM           Norm of A; passed to matrix generators.
*>
*>     OVFL, UNFL      Overflow and underflow thresholds.
*>     ULP, ULPINV     Finest relative precision and its inverse.
*>     RTOVFL, RTUNFL,
*>     RTULP, RTULPI   Square roots of the previous 4 values.
*>
*>             The following four arrays decode JTYPE:
*>     KTYPE(j)        The general type (1-10) for type "j".
*>     KMODE(j)        The MODE value to be passed to the matrix
*>                     generator for type "j".
*>     KMAGN(j)        The order of magnitude ( O(1),
*>                     O(overflow^(1/2) ), O(underflow^(1/2) )
*>     KCONDS(j)       Selects whether CONDS is to be 1 or
*>                     1/sqrt(ulp).  (0 means irrelevant.)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zchkhs( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   nounit, a, lda, h, t1, t2, u, ldu, z, uz, w1,
     $                   w3, evectl, evectr, evecty, evectx, uu, tau,
     $                   work, nwork, rwork, iwork, SELECT, result,
     $                   info )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, ldu, nounit, nsizes, ntypes, nwork
      DOUBLE PRECISION   thresh
*     ..
*     .. Array Arguments ..
      LOGICAL            dotype( * ), select( * )
      INTEGER            iseed( 4 ), iwork( * ), nn( * )
      DOUBLE PRECISION   result( 14 ), rwork( * )
      COMPLEX*16         a( lda, * ), evectl( ldu, * ),
     $                   evectr( ldu, * ), evectx( ldu, * ),
     $                   evecty( ldu, * ), h( lda, * ), t1( lda, * ),
     $                   t2( lda, * ), tau( * ), u( ldu, * ),
     $                   uu( ldu, * ), uz( ldu, * ), w1( * ), w3( * ),
     $                   work( * ), z( ldu, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
      INTEGER            maxtyp
      parameter( maxtyp = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            badnn, match
      INTEGER            i, ihi, iinfo, ilo, imode, in, itype, j, jcol,
     $                   jj, jsize, jtype, k, mtypes, n, n1, nerrs,
     $                   nmats, nmax, ntest, ntestt
      DOUBLE PRECISION   aninv, anorm, cond, conds, ovfl, rtovfl, rtulp,
     $                   rtulpi, rtunfl, temp1, temp2, ulp, ulpinv, unfl
*     ..
*     .. Local Arrays ..
      INTEGER            idumma( 1 ), ioldsd( 4 ), kconds( maxtyp ),
     $                   kmagn( maxtyp ), kmode( maxtyp ),
     $                   ktype( maxtyp )
      DOUBLE PRECISION   dumma( 4 )
      COMPLEX*16         cdumma( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad, dlafts, dlasum, xerbla, zcopy, zgehrd,
     $                   zgemm, zget10, zget22, zhsein, zhseqr, zhst01,
     $                   zlacpy, zlaset, zlatme, zlatmr, zlatms, ztrevc,
     $                   zunghr, zunmhr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      ntestt = 0
      info = 0
*
      badnn = .false.
      nmax = 0
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 continue
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldu.LE.1 .OR. ldu.LT.nmax ) THEN
         info = -14
      ELSE IF( 4*nmax*nmax+2.GT.nwork ) THEN
         info = -26
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZCHKHS', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   return
*
*     More important constants
*
      unfl = dlamch( 'Safe minimum' )
      ovfl = dlamch( 'Overflow' )
      CALL dlabad( unfl, ovfl )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
      ulpinv = one / ulp
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
      nmats = 0
*
      DO 260 jsize = 1, nsizes
         n = nn( jsize )
         IF( n.EQ.0 )
     $      go to 260
         n1 = max( 1, n )
         aninv = one / dble( n1 )
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 250 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         go to 250
            nmats = nmats + 1
            ntest = 0
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       continue
*
*           Initialize RESULT
*
            DO 30 j = 1, 14
               result( j ) = zero
   30       continue
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   hermitian, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random hermitian
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         go to 100
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            go to( 40, 50, 60 )kmagn( jtype )
*
   40       continue
            anorm = one
            go to 70
*
   50       continue
            anorm = ( rtovfl*ulp )*aninv
            go to 70
*
   60       continue
            anorm = rtunfl*n*ulpinv
            go to 70
*
   70       continue
*
            CALL zlaset( 'Full', lda, n, czero, czero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices
*
            IF( itype.EQ.1 ) THEN
*
*              Zero
*
               iinfo = 0
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = anorm
   80          continue
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 90 jcol = 1, n
                  a( jcol, jcol ) = anorm
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = one
   90          continue
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL zlatmr( n, n, 'D', iseed, 'N', work, imode, cond,
     $                      cone, 'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Hermitian, eigenvalues specified
*
               CALL zlatms( n, n, 'D', iseed, 'H', rwork, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work, iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               CALL zlatme( n, 'D', iseed, work, imode, cond, cone,
     $                      'T', 'T', 'T', rwork, 4, conds, n, n, anorm,
     $                      a, lda, work( n+1 ), iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL zlatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Hermitian, random eigenvalues
*
               CALL zlatmr( n, n, 'D', iseed, 'H', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL zlatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL zlatmr( n, n, 'D', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               return
            END IF
*
  100       continue
*
*           Call ZGEHRD to compute H and U, do tests.
*
            CALL zlacpy( ' ', n, n, a, lda, h, lda )
            ntest = 1
*
            ilo = 1
            ihi = n
*
            CALL zgehrd( n, ilo, ihi, h, lda, work, work( n+1 ),
     $                   nwork-n, iinfo )
*
            IF( iinfo.NE.0 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'ZGEHRD', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
            DO 120 j = 1, n - 1
               uu( j+1, j ) = czero
               DO 110 i = j + 2, n
                  u( i, j ) = h( i, j )
                  uu( i, j ) = h( i, j )
                  h( i, j ) = czero
  110          continue
  120       continue
            CALL zcopy( n-1, work, 1, tau, 1 )
            CALL zunghr( n, ilo, ihi, u, ldu, work, work( n+1 ),
     $                   nwork-n, iinfo )
            ntest = 2
*
            CALL zhst01( n, ilo, ihi, a, lda, h, lda, u, ldu, work,
     $                   nwork, rwork, result( 1 ) )
*
*           Call ZHSEQR to compute T1, T2 and Z, do tests.
*
*           Eigenvalues only (W3)
*
            CALL zlacpy( ' ', n, n, h, lda, t2, lda )
            ntest = 3
            result( 3 ) = ulpinv
*
            CALL zhseqr( 'E', 'N', n, ilo, ihi, t2, lda, w3, uz, ldu,
     $                   work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHSEQR(E)', iinfo, n, jtype,
     $            ioldsd
               IF( iinfo.LE.n+2 ) THEN
                  info = abs( iinfo )
                  go to 240
               END IF
            END IF
*
*           Eigenvalues (W1) and Full Schur Form (T2)
*
            CALL zlacpy( ' ', n, n, h, lda, t2, lda )
*
            CALL zhseqr( 'S', 'N', n, ilo, ihi, t2, lda, w1, uz, ldu,
     $                   work, nwork, iinfo )
            IF( iinfo.NE.0 .AND. iinfo.LE.n+2 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHSEQR(S)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
*           Eigenvalues (W1), Schur Form (T1), and Schur Vectors (UZ)
*
            CALL zlacpy( ' ', n, n, h, lda, t1, lda )
            CALL zlacpy( ' ', n, n, u, ldu, uz, ldu )
*
            CALL zhseqr( 'S', 'V', n, ilo, ihi, t1, lda, w1, uz, ldu,
     $                   work, nwork, iinfo )
            IF( iinfo.NE.0 .AND. iinfo.LE.n+2 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHSEQR(V)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
*           Compute Z = U' UZ
*
            CALL zgemm( 'C', 'N', n, n, n, cone, u, ldu, uz, ldu, czero,
     $                  z, ldu )
            ntest = 8
*
*           Do Tests 3: | H - Z T Z' | / ( |H| n ulp )
*                and 4: | I - Z Z' | / ( n ulp )
*
            CALL zhst01( n, ilo, ihi, h, lda, t1, lda, z, ldu, work,
     $                   nwork, rwork, result( 3 ) )
*
*           Do Tests 5: | A - UZ T (UZ)' | / ( |A| n ulp )
*                and 6: | I - UZ (UZ)' | / ( n ulp )
*
            CALL zhst01( n, ilo, ihi, a, lda, t1, lda, uz, ldu, work,
     $                   nwork, rwork, result( 5 ) )
*
*           Do Test 7: | T2 - T1 | / ( |T| n ulp )
*
            CALL zget10( n, n, t2, lda, t1, lda, work, rwork,
     $                   result( 7 ) )
*
*           Do Test 8: | W3 - W1 | / ( max(|W1|,|W3|) ulp )
*
            temp1 = zero
            temp2 = zero
            DO 130 j = 1, n
               temp1 = max( temp1, abs( w1( j ) ), abs( w3( j ) ) )
               temp2 = max( temp2, abs( w1( j )-w3( j ) ) )
  130       continue
*
            result( 8 ) = temp2 / max( unfl, ulp*max( temp1, temp2 ) )
*
*           Compute the Left and Right Eigenvectors of T
*
*           Compute the Right eigenvector Matrix:
*
            ntest = 9
            result( 9 ) = ulpinv
*
*           Select every other eigenvector
*
            DO 140 j = 1, n
               SELECT( j ) = .false.
  140       continue
            DO 150 j = 1, n, 2
               SELECT( j ) = .true.
  150       continue
            CALL ztrevc( 'Right', 'All', SELECT, n, t1, lda, cdumma,
     $                   ldu, evectr, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTREVC(R,A)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
*           Test 9:  | TR - RW | / ( |T| |R| ulp )
*
            CALL zget22( 'N', 'N', 'N', n, t1, lda, evectr, ldu, w1,
     $                   work, rwork, dumma( 1 ) )
            result( 9 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'ZTREVC',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           Compute selected right eigenvectors and confirm that
*           they agree with previous right eigenvectors
*
            CALL ztrevc( 'Right', 'Some', SELECT, n, t1, lda, cdumma,
     $                   ldu, evectl, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTREVC(R,S)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
            k = 1
            match = .true.
            DO 170 j = 1, n
               IF( SELECT( j ) ) THEN
                  DO 160 jj = 1, n
                     IF( evectr( jj, j ).NE.evectl( jj, k ) ) THEN
                        match = .false.
                        go to 180
                     END IF
  160             continue
                  k = k + 1
               END IF
  170       continue
  180       continue
            IF( .NOT.match )
     $         WRITE( nounit, fmt = 9997 )'Right', 'ZTREVC', n, jtype,
     $         ioldsd
*
*           Compute the Left eigenvector Matrix:
*
            ntest = 10
            result( 10 ) = ulpinv
            CALL ztrevc( 'Left', 'All', SELECT, n, t1, lda, evectl, ldu,
     $                   cdumma, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTREVC(L,A)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
*           Test 10:  | LT - WL | / ( |T| |L| ulp )
*
            CALL zget22( 'C', 'N', 'C', n, t1, lda, evectl, ldu, w1,
     $                   work, rwork, dumma( 3 ) )
            result( 10 ) = dumma( 3 )
            IF( dumma( 4 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'ZTREVC', dumma( 4 ),
     $            n, jtype, ioldsd
            END IF
*
*           Compute selected left eigenvectors and confirm that
*           they agree with previous left eigenvectors
*
            CALL ztrevc( 'Left', 'Some', SELECT, n, t1, lda, evectr,
     $                   ldu, cdumma, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTREVC(L,S)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               go to 240
            END IF
*
            k = 1
            match = .true.
            DO 200 j = 1, n
               IF( SELECT( j ) ) THEN
                  DO 190 jj = 1, n
                     IF( evectl( jj, j ).NE.evectr( jj, k ) ) THEN
                        match = .false.
                        go to 210
                     END IF
  190             continue
                  k = k + 1
               END IF
  200       continue
  210       continue
            IF( .NOT.match )
     $         WRITE( nounit, fmt = 9997 )'Left', 'ZTREVC', n, jtype,
     $         ioldsd
*
*           Call ZHSEIN for Right eigenvectors of H, do test 11
*
            ntest = 11
            result( 11 ) = ulpinv
            DO 220 j = 1, n
               SELECT( j ) = .true.
  220       continue
*
            CALL zhsein( 'Right', 'Qr', 'Ninitv', SELECT, n, h, lda, w3,
     $                   cdumma, ldu, evectx, ldu, n1, in, work, rwork,
     $                   iwork, iwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHSEIN(R)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            go to 240
            ELSE
*
*              Test 11:  | HX - XW | / ( |H| |X| ulp )
*
*                        (from inverse iteration)
*
               CALL zget22( 'N', 'N', 'N', n, h, lda, evectx, ldu, w3,
     $                      work, rwork, dumma( 1 ) )
               IF( dumma( 1 ).LT.ulpinv )
     $            result( 11 ) = dumma( 1 )*aninv
               IF( dumma( 2 ).GT.thresh ) THEN
                  WRITE( nounit, fmt = 9998 )'Right', 'ZHSEIN',
     $               dumma( 2 ), n, jtype, ioldsd
               END IF
            END IF
*
*           Call ZHSEIN for Left eigenvectors of H, do test 12
*
            ntest = 12
            result( 12 ) = ulpinv
            DO 230 j = 1, n
               SELECT( j ) = .true.
  230       continue
*
            CALL zhsein( 'Left', 'Qr', 'Ninitv', SELECT, n, h, lda, w3,
     $                   evecty, ldu, cdumma, ldu, n1, in, work, rwork,
     $                   iwork, iwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHSEIN(L)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            go to 240
            ELSE
*
*              Test 12:  | YH - WY | / ( |H| |Y| ulp )
*
*                        (from inverse iteration)
*
               CALL zget22( 'C', 'N', 'C', n, h, lda, evecty, ldu, w3,
     $                      work, rwork, dumma( 3 ) )
               IF( dumma( 3 ).LT.ulpinv )
     $            result( 12 ) = dumma( 3 )*aninv
               IF( dumma( 4 ).GT.thresh ) THEN
                  WRITE( nounit, fmt = 9998 )'Left', 'ZHSEIN',
     $               dumma( 4 ), n, jtype, ioldsd
               END IF
            END IF
*
*           Call ZUNMHR for Right eigenvectors of A, do test 13
*
            ntest = 13
            result( 13 ) = ulpinv
*
            CALL zunmhr( 'Left', 'No transpose', n, n, ilo, ihi, uu,
     $                   ldu, tau, evectx, ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZUNMHR(L)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            go to 240
            ELSE
*
*              Test 13:  | AX - XW | / ( |A| |X| ulp )
*
*                        (from inverse iteration)
*
               CALL zget22( 'N', 'N', 'N', n, a, lda, evectx, ldu, w3,
     $                      work, rwork, dumma( 1 ) )
               IF( dumma( 1 ).LT.ulpinv )
     $            result( 13 ) = dumma( 1 )*aninv
            END IF
*
*           Call ZUNMHR for Left eigenvectors of A, do test 14
*
            ntest = 14
            result( 14 ) = ulpinv
*
            CALL zunmhr( 'Left', 'No transpose', n, n, ilo, ihi, uu,
     $                   ldu, tau, evecty, ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZUNMHR(L)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            go to 240
            ELSE
*
*              Test 14:  | YA - WY | / ( |A| |Y| ulp )
*
*                        (from inverse iteration)
*
               CALL zget22( 'C', 'N', 'C', n, a, lda, evecty, ldu, w3,
     $                      work, rwork, dumma( 3 ) )
               IF( dumma( 3 ).LT.ulpinv )
     $            result( 14 ) = dumma( 3 )*aninv
            END IF
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  240       continue
*
            ntestt = ntestt + ntest
            CALL dlafts( 'ZHS', n, n, jtype, ntest, result, ioldsd,
     $                   thresh, nounit, nerrs )
*
  250    continue
  260 continue
*
*     Summary
*
      CALL dlasum( 'ZHS', nounit, nerrs, ntestt )
*
      return
*
 9999 format( ' ZCHKHS: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
 9998 format( ' ZCHKHS: ', a, ' Eigenvectors from ', a, ' incorrectly ',
     $      'normalized.', / ' Bits of error=', 0p, g10.3, ',', 9x,
     $      'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5,
     $      ')' )
 9997 format( ' ZCHKHS: Selected ', a, ' Eigenvectors from ', a,
     $      ' do not match other eigenvectors ', 9x, 'N=', i6,
     $      ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
*     End of ZCHKHS
*
      END