secondtst.f

Go to the documentation of this file.

*> \brief \b SECONDTST
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup auxOTHERcomputational
*
*  =====================================================================      PROGRAM SECONDTST
*
*  -- LAPACK test routine (version 3.4.0) --
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
* =====================================================================
*
*     .. Parameters ..
      INTEGER            nmax, its
      parameter( nmax = 1000, its = 50000 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      REAL               alpha, avg, t1, t2, tnosec, total
*     ..
*     .. Local Arrays ..
      REAL               x( nmax ), y( nmax )
*     ..
*     .. External Functions ..
      REAL               second
      EXTERNAL           second
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*    .. Figure TOTAL flops ..
      total = REAL(NMAX) * REAL(ITS) * 2.0
*
*     Initialize X and Y
*
      DO 10 i = 1, nmax
         x( i ) = REAL( 1 ) / REAL( i )
         y( i ) = REAL( NMAX-I ) / REAL( nmax )
   10 continue
      alpha = 0.315
*
*     Time TOTAL SAXPY operations
*
      t1 = second( )
      DO 30 j = 1, its
         DO 20 i = 1, nmax
            y( i ) = y( i ) + alpha*x( i )
   20    continue
         alpha = -alpha
   30 continue
      t2 = second( )
      tnosec = t2 - t1
      WRITE( 6, 9999 )total, tnosec
      IF( tnosec.GT.0.0 ) THEN
         WRITE( 6, 9998 )(total/1.0e6)/tnosec
      ELSE
         WRITE( 6, 9994 )
      END IF
*
*     Time TOTAL SAXPY operations with SECOND in the outer loop
*
      t1 = second( )
      DO 50 j = 1, its
         DO 40 i = 1, nmax
            y( i ) = y( i ) + alpha*x( i )
   40    continue
         alpha = -alpha
         t2 = second( )
   50 continue
*
*     Compute the time used in milliseconds used by an average call
*     to SECOND.
*
      WRITE( 6, 9997 )t2 - t1
      avg = ( ( t2-t1 ) - tnosec ) * 1000.0e+00/REAL( its )
      IF( avg.GT.0.0)
     $   WRITE( 6, 9996 )avg
*
*     Compute the equivalent number of floating point operations used
*     by an average call to SECOND.
*
      IF(( avg.GT.0.0 ).AND.( tnosec.GT.0.0 ))
     $   WRITE( 6, 9995 )(avg/1000) * total / tnosec
*
 9999 format( ' Time for ', g10.3,' SAXPY ops = ', g10.3, ' seconds' )
 9998 format( ' SAXPY performance rate        = ', g10.3, ' mflops ' )
 9997 format( ' Including SECOND, time        = ', g10.3, ' seconds' )
 9996 format( ' Average time for SECOND       = ', g10.3,
     $      ' milliseconds' )
 9995 format( ' Equivalent floating point ops = ', g10.3, ' ops' )
 9994 format( ' *** Warning:  Time for operations was less or equal',
     $        ' than zero => timing in TESTING might be dubious' )
      CALL mysub(nmax,x,y)
      END
      SUBROUTINE mysub(N,X,Y)
      INTEGER n
      REAL x(n), y(n)
      return
      END