LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
dgbsvx.f
Go to the documentation of this file.
1 *> \brief <b> DGBSVX computes the solution to system of linear equations A * X = B for GB matrices</b>
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DGBSVX + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgbsvx.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgbsvx.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgbsvx.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DGBSVX( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
22 * LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX,
23 * RCOND, FERR, BERR, WORK, IWORK, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER EQUED, FACT, TRANS
27 * INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
28 * DOUBLE PRECISION RCOND
29 * ..
30 * .. Array Arguments ..
31 * INTEGER IPIV( * ), IWORK( * )
32 * DOUBLE PRECISION AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
33 * $ BERR( * ), C( * ), FERR( * ), R( * ),
34 * $ WORK( * ), X( LDX, * )
35 * ..
36 *
37 *
38 *> \par Purpose:
39 * =============
40 *>
41 *> \verbatim
42 *>
43 *> DGBSVX uses the LU factorization to compute the solution to a real
44 *> system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
45 *> where A is a band matrix of order N with KL subdiagonals and KU
46 *> superdiagonals, and X and B are N-by-NRHS matrices.
47 *>
48 *> Error bounds on the solution and a condition estimate are also
49 *> provided.
50 *> \endverbatim
51 *
52 *> \par Description:
53 * =================
54 *>
55 *> \verbatim
56 *>
57 *> The following steps are performed by this subroutine:
58 *>
59 *> 1. If FACT = 'E', real scaling factors are computed to equilibrate
60 *> the system:
61 *> TRANS = 'N': diag(R)*A*diag(C) *inv(diag(C))*X = diag(R)*B
62 *> TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
63 *> TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
64 *> Whether or not the system will be equilibrated depends on the
65 *> scaling of the matrix A, but if equilibration is used, A is
66 *> overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
67 *> or diag(C)*B (if TRANS = 'T' or 'C').
68 *>
69 *> 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
70 *> matrix A (after equilibration if FACT = 'E') as
71 *> A = L * U,
72 *> where L is a product of permutation and unit lower triangular
73 *> matrices with KL subdiagonals, and U is upper triangular with
74 *> KL+KU superdiagonals.
75 *>
76 *> 3. If some U(i,i)=0, so that U is exactly singular, then the routine
77 *> returns with INFO = i. Otherwise, the factored form of A is used
78 *> to estimate the condition number of the matrix A. If the
79 *> reciprocal of the condition number is less than machine precision,
80 *> INFO = N+1 is returned as a warning, but the routine still goes on
81 *> to solve for X and compute error bounds as described below.
82 *>
83 *> 4. The system of equations is solved for X using the factored form
84 *> of A.
85 *>
86 *> 5. Iterative refinement is applied to improve the computed solution
87 *> matrix and calculate error bounds and backward error estimates
88 *> for it.
89 *>
90 *> 6. If equilibration was used, the matrix X is premultiplied by
91 *> diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
92 *> that it solves the original system before equilibration.
93 *> \endverbatim
94 *
95 * Arguments:
96 * ==========
97 *
98 *> \param[in] FACT
99 *> \verbatim
100 *> FACT is CHARACTER*1
101 *> Specifies whether or not the factored form of the matrix A is
102 *> supplied on entry, and if not, whether the matrix A should be
103 *> equilibrated before it is factored.
104 *> = 'F': On entry, AFB and IPIV contain the factored form of
105 *> A. If EQUED is not 'N', the matrix A has been
106 *> equilibrated with scaling factors given by R and C.
107 *> AB, AFB, and IPIV are not modified.
108 *> = 'N': The matrix A will be copied to AFB and factored.
109 *> = 'E': The matrix A will be equilibrated if necessary, then
110 *> copied to AFB and factored.
111 *> \endverbatim
112 *>
113 *> \param[in] TRANS
114 *> \verbatim
115 *> TRANS is CHARACTER*1
116 *> Specifies the form of the system of equations.
117 *> = 'N': A * X = B (No transpose)
118 *> = 'T': A**T * X = B (Transpose)
119 *> = 'C': A**H * X = B (Transpose)
120 *> \endverbatim
121 *>
122 *> \param[in] N
123 *> \verbatim
124 *> N is INTEGER
125 *> The number of linear equations, i.e., the order of the
126 *> matrix A. N >= 0.
127 *> \endverbatim
128 *>
129 *> \param[in] KL
130 *> \verbatim
131 *> KL is INTEGER
132 *> The number of subdiagonals within the band of A. KL >= 0.
133 *> \endverbatim
134 *>
135 *> \param[in] KU
136 *> \verbatim
137 *> KU is INTEGER
138 *> The number of superdiagonals within the band of A. KU >= 0.
139 *> \endverbatim
140 *>
141 *> \param[in] NRHS
142 *> \verbatim
143 *> NRHS is INTEGER
144 *> The number of right hand sides, i.e., the number of columns
145 *> of the matrices B and X. NRHS >= 0.
146 *> \endverbatim
147 *>
148 *> \param[in,out] AB
149 *> \verbatim
150 *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
151 *> On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
152 *> The j-th column of A is stored in the j-th column of the
153 *> array AB as follows:
154 *> AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
155 *>
156 *> If FACT = 'F' and EQUED is not 'N', then A must have been
157 *> equilibrated by the scaling factors in R and/or C. AB is not
158 *> modified if FACT = 'F' or 'N', or if FACT = 'E' and
159 *> EQUED = 'N' on exit.
160 *>
161 *> On exit, if EQUED .ne. 'N', A is scaled as follows:
162 *> EQUED = 'R': A := diag(R) * A
163 *> EQUED = 'C': A := A * diag(C)
164 *> EQUED = 'B': A := diag(R) * A * diag(C).
165 *> \endverbatim
166 *>
167 *> \param[in] LDAB
168 *> \verbatim
169 *> LDAB is INTEGER
170 *> The leading dimension of the array AB. LDAB >= KL+KU+1.
171 *> \endverbatim
172 *>
173 *> \param[in,out] AFB
174 *> \verbatim
175 *> AFB is DOUBLE PRECISION array, dimension (LDAFB,N)
176 *> If FACT = 'F', then AFB is an input argument and on entry
177 *> contains details of the LU factorization of the band matrix
178 *> A, as computed by DGBTRF. U is stored as an upper triangular
179 *> band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
180 *> and the multipliers used during the factorization are stored
181 *> in rows KL+KU+2 to 2*KL+KU+1. If EQUED .ne. 'N', then AFB is
182 *> the factored form of the equilibrated matrix A.
183 *>
184 *> If FACT = 'N', then AFB is an output argument and on exit
185 *> returns details of the LU factorization of A.
186 *>
187 *> If FACT = 'E', then AFB is an output argument and on exit
188 *> returns details of the LU factorization of the equilibrated
189 *> matrix A (see the description of AB for the form of the
190 *> equilibrated matrix).
191 *> \endverbatim
192 *>
193 *> \param[in] LDAFB
194 *> \verbatim
195 *> LDAFB is INTEGER
196 *> The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1.
197 *> \endverbatim
198 *>
199 *> \param[in,out] IPIV
200 *> \verbatim
201 *> IPIV is INTEGER array, dimension (N)
202 *> If FACT = 'F', then IPIV is an input argument and on entry
203 *> contains the pivot indices from the factorization A = L*U
204 *> as computed by DGBTRF; row i of the matrix was interchanged
205 *> with row IPIV(i).
206 *>
207 *> If FACT = 'N', then IPIV is an output argument and on exit
208 *> contains the pivot indices from the factorization A = L*U
209 *> of the original matrix A.
210 *>
211 *> If FACT = 'E', then IPIV is an output argument and on exit
212 *> contains the pivot indices from the factorization A = L*U
213 *> of the equilibrated matrix A.
214 *> \endverbatim
215 *>
216 *> \param[in,out] EQUED
217 *> \verbatim
218 *> EQUED is CHARACTER*1
219 *> Specifies the form of equilibration that was done.
220 *> = 'N': No equilibration (always true if FACT = 'N').
221 *> = 'R': Row equilibration, i.e., A has been premultiplied by
222 *> diag(R).
223 *> = 'C': Column equilibration, i.e., A has been postmultiplied
224 *> by diag(C).
225 *> = 'B': Both row and column equilibration, i.e., A has been
226 *> replaced by diag(R) * A * diag(C).
227 *> EQUED is an input argument if FACT = 'F'; otherwise, it is an
228 *> output argument.
229 *> \endverbatim
230 *>
231 *> \param[in,out] R
232 *> \verbatim
233 *> R is DOUBLE PRECISION array, dimension (N)
234 *> The row scale factors for A. If EQUED = 'R' or 'B', A is
235 *> multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
236 *> is not accessed. R is an input argument if FACT = 'F';
237 *> otherwise, R is an output argument. If FACT = 'F' and
238 *> EQUED = 'R' or 'B', each element of R must be positive.
239 *> \endverbatim
240 *>
241 *> \param[in,out] C
242 *> \verbatim
243 *> C is DOUBLE PRECISION array, dimension (N)
244 *> The column scale factors for A. If EQUED = 'C' or 'B', A is
245 *> multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
246 *> is not accessed. C is an input argument if FACT = 'F';
247 *> otherwise, C is an output argument. If FACT = 'F' and
248 *> EQUED = 'C' or 'B', each element of C must be positive.
249 *> \endverbatim
250 *>
251 *> \param[in,out] B
252 *> \verbatim
253 *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
254 *> On entry, the right hand side matrix B.
255 *> On exit,
256 *> if EQUED = 'N', B is not modified;
257 *> if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
258 *> diag(R)*B;
259 *> if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
260 *> overwritten by diag(C)*B.
261 *> \endverbatim
262 *>
263 *> \param[in] LDB
264 *> \verbatim
265 *> LDB is INTEGER
266 *> The leading dimension of the array B. LDB >= max(1,N).
267 *> \endverbatim
268 *>
269 *> \param[out] X
270 *> \verbatim
271 *> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
272 *> If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
273 *> to the original system of equations. Note that A and B are
274 *> modified on exit if EQUED .ne. 'N', and the solution to the
275 *> equilibrated system is inv(diag(C))*X if TRANS = 'N' and
276 *> EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
277 *> and EQUED = 'R' or 'B'.
278 *> \endverbatim
279 *>
280 *> \param[in] LDX
281 *> \verbatim
282 *> LDX is INTEGER
283 *> The leading dimension of the array X. LDX >= max(1,N).
284 *> \endverbatim
285 *>
286 *> \param[out] RCOND
287 *> \verbatim
288 *> RCOND is DOUBLE PRECISION
289 *> The estimate of the reciprocal condition number of the matrix
290 *> A after equilibration (if done). If RCOND is less than the
291 *> machine precision (in particular, if RCOND = 0), the matrix
292 *> is singular to working precision. This condition is
293 *> indicated by a return code of INFO > 0.
294 *> \endverbatim
295 *>
296 *> \param[out] FERR
297 *> \verbatim
298 *> FERR is DOUBLE PRECISION array, dimension (NRHS)
299 *> The estimated forward error bound for each solution vector
300 *> X(j) (the j-th column of the solution matrix X).
301 *> If XTRUE is the true solution corresponding to X(j), FERR(j)
302 *> is an estimated upper bound for the magnitude of the largest
303 *> element in (X(j) - XTRUE) divided by the magnitude of the
304 *> largest element in X(j). The estimate is as reliable as
305 *> the estimate for RCOND, and is almost always a slight
306 *> overestimate of the true error.
307 *> \endverbatim
308 *>
309 *> \param[out] BERR
310 *> \verbatim
311 *> BERR is DOUBLE PRECISION array, dimension (NRHS)
312 *> The componentwise relative backward error of each solution
313 *> vector X(j) (i.e., the smallest relative change in
314 *> any element of A or B that makes X(j) an exact solution).
315 *> \endverbatim
316 *>
317 *> \param[out] WORK
318 *> \verbatim
319 *> WORK is DOUBLE PRECISION array, dimension (3*N)
320 *> On exit, WORK(1) contains the reciprocal pivot growth
321 *> factor norm(A)/norm(U). The "max absolute element" norm is
322 *> used. If WORK(1) is much less than 1, then the stability
323 *> of the LU factorization of the (equilibrated) matrix A
324 *> could be poor. This also means that the solution X, condition
325 *> estimator RCOND, and forward error bound FERR could be
326 *> unreliable. If factorization fails with 0<INFO<=N, then
327 *> WORK(1) contains the reciprocal pivot growth factor for the
328 *> leading INFO columns of A.
329 *> \endverbatim
330 *>
331 *> \param[out] IWORK
332 *> \verbatim
333 *> IWORK is INTEGER array, dimension (N)
334 *> \endverbatim
335 *>
336 *> \param[out] INFO
337 *> \verbatim
338 *> INFO is INTEGER
339 *> = 0: successful exit
340 *> < 0: if INFO = -i, the i-th argument had an illegal value
341 *> > 0: if INFO = i, and i is
342 *> <= N: U(i,i) is exactly zero. The factorization
343 *> has been completed, but the factor U is exactly
344 *> singular, so the solution and error bounds
345 *> could not be computed. RCOND = 0 is returned.
346 *> = N+1: U is nonsingular, but RCOND is less than machine
347 *> precision, meaning that the matrix is singular
348 *> to working precision. Nevertheless, the
349 *> solution and error bounds are computed because
350 *> there are a number of situations where the
351 *> computed solution can be more accurate than the
352 *> value of RCOND would suggest.
353 *> \endverbatim
354 *
355 * Authors:
356 * ========
357 *
358 *> \author Univ. of Tennessee
359 *> \author Univ. of California Berkeley
360 *> \author Univ. of Colorado Denver
361 *> \author NAG Ltd.
362 *
363 *> \date April 2012
364 *
365 *> \ingroup doubleGBsolve
366 *
367 * =====================================================================
368  SUBROUTINE dgbsvx( FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB,
369  $ ldafb, ipiv, equed, r, c, b, ldb, x, ldx,
370  $ rcond, ferr, berr, work, iwork, info )
371 *
372 * -- LAPACK driver routine (version 3.4.1) --
373 * -- LAPACK is a software package provided by Univ. of Tennessee, --
374 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
375 * April 2012
376 *
377 * .. Scalar Arguments ..
378  CHARACTER equed, fact, trans
379  INTEGER info, kl, ku, ldab, ldafb, ldb, ldx, n, nrhs
380  DOUBLE PRECISION rcond
381 * ..
382 * .. Array Arguments ..
383  INTEGER ipiv( * ), iwork( * )
384  DOUBLE PRECISION ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
385  $ berr( * ), c( * ), ferr( * ), r( * ),
386  $ work( * ), x( ldx, * )
387 * ..
388 *
389 * =====================================================================
390 *
391 * .. Parameters ..
392  DOUBLE PRECISION zero, one
393  parameter( zero = 0.0d+0, one = 1.0d+0 )
394 * ..
395 * .. Local Scalars ..
396  LOGICAL colequ, equil, nofact, notran, rowequ
397  CHARACTER norm
398  INTEGER i, infequ, j, j1, j2
399  DOUBLE PRECISION amax, anorm, bignum, colcnd, rcmax, rcmin,
400  $ rowcnd, rpvgrw, smlnum
401 * ..
402 * .. External Functions ..
403  LOGICAL lsame
404  DOUBLE PRECISION dlamch, dlangb, dlantb
405  EXTERNAL lsame, dlamch, dlangb, dlantb
406 * ..
407 * .. External Subroutines ..
408  EXTERNAL dcopy, dgbcon, dgbequ, dgbrfs, dgbtrf, dgbtrs,
409  $ dlacpy, dlaqgb, xerbla
410 * ..
411 * .. Intrinsic Functions ..
412  INTRINSIC abs, max, min
413 * ..
414 * .. Executable Statements ..
415 *
416  info = 0
417  nofact = lsame( fact, 'N' )
418  equil = lsame( fact, 'E' )
419  notran = lsame( trans, 'N' )
420  IF( nofact .OR. equil ) THEN
421  equed = 'N'
422  rowequ = .false.
423  colequ = .false.
424  ELSE
425  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
426  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
427  smlnum = dlamch( 'Safe minimum' )
428  bignum = one / smlnum
429  END IF
430 *
431 * Test the input parameters.
432 *
433  IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.lsame( fact, 'F' ) )
434  $ THEN
435  info = -1
436  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
437  $ lsame( trans, 'C' ) ) THEN
438  info = -2
439  ELSE IF( n.LT.0 ) THEN
440  info = -3
441  ELSE IF( kl.LT.0 ) THEN
442  info = -4
443  ELSE IF( ku.LT.0 ) THEN
444  info = -5
445  ELSE IF( nrhs.LT.0 ) THEN
446  info = -6
447  ELSE IF( ldab.LT.kl+ku+1 ) THEN
448  info = -8
449  ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
450  info = -10
451  ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
452  $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
453  info = -12
454  ELSE
455  IF( rowequ ) THEN
456  rcmin = bignum
457  rcmax = zero
458  DO 10 j = 1, n
459  rcmin = min( rcmin, r( j ) )
460  rcmax = max( rcmax, r( j ) )
461  10 continue
462  IF( rcmin.LE.zero ) THEN
463  info = -13
464  ELSE IF( n.GT.0 ) THEN
465  rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
466  ELSE
467  rowcnd = one
468  END IF
469  END IF
470  IF( colequ .AND. info.EQ.0 ) THEN
471  rcmin = bignum
472  rcmax = zero
473  DO 20 j = 1, n
474  rcmin = min( rcmin, c( j ) )
475  rcmax = max( rcmax, c( j ) )
476  20 continue
477  IF( rcmin.LE.zero ) THEN
478  info = -14
479  ELSE IF( n.GT.0 ) THEN
480  colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
481  ELSE
482  colcnd = one
483  END IF
484  END IF
485  IF( info.EQ.0 ) THEN
486  IF( ldb.LT.max( 1, n ) ) THEN
487  info = -16
488  ELSE IF( ldx.LT.max( 1, n ) ) THEN
489  info = -18
490  END IF
491  END IF
492  END IF
493 *
494  IF( info.NE.0 ) THEN
495  CALL xerbla( 'DGBSVX', -info )
496  return
497  END IF
498 *
499  IF( equil ) THEN
500 *
501 * Compute row and column scalings to equilibrate the matrix A.
502 *
503  CALL dgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
504  $ amax, infequ )
505  IF( infequ.EQ.0 ) THEN
506 *
507 * Equilibrate the matrix.
508 *
509  CALL dlaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
510  $ amax, equed )
511  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
512  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
513  END IF
514  END IF
515 *
516 * Scale the right hand side.
517 *
518  IF( notran ) THEN
519  IF( rowequ ) THEN
520  DO 40 j = 1, nrhs
521  DO 30 i = 1, n
522  b( i, j ) = r( i )*b( i, j )
523  30 continue
524  40 continue
525  END IF
526  ELSE IF( colequ ) THEN
527  DO 60 j = 1, nrhs
528  DO 50 i = 1, n
529  b( i, j ) = c( i )*b( i, j )
530  50 continue
531  60 continue
532  END IF
533 *
534  IF( nofact .OR. equil ) THEN
535 *
536 * Compute the LU factorization of the band matrix A.
537 *
538  DO 70 j = 1, n
539  j1 = max( j-ku, 1 )
540  j2 = min( j+kl, n )
541  CALL dcopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
542  $ afb( kl+ku+1-j+j1, j ), 1 )
543  70 continue
544 *
545  CALL dgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
546 *
547 * Return if INFO is non-zero.
548 *
549  IF( info.GT.0 ) THEN
550 *
551 * Compute the reciprocal pivot growth factor of the
552 * leading rank-deficient INFO columns of A.
553 *
554  anorm = zero
555  DO 90 j = 1, info
556  DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
557  anorm = max( anorm, abs( ab( i, j ) ) )
558  80 continue
559  90 continue
560  rpvgrw = dlantb( 'M', 'U', 'N', info, min( info-1, kl+ku ),
561  $ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
562  $ work )
563  IF( rpvgrw.EQ.zero ) THEN
564  rpvgrw = one
565  ELSE
566  rpvgrw = anorm / rpvgrw
567  END IF
568  work( 1 ) = rpvgrw
569  rcond = zero
570  return
571  END IF
572  END IF
573 *
574 * Compute the norm of the matrix A and the
575 * reciprocal pivot growth factor RPVGRW.
576 *
577  IF( notran ) THEN
578  norm = '1'
579  ELSE
580  norm = 'I'
581  END IF
582  anorm = dlangb( norm, n, kl, ku, ab, ldab, work )
583  rpvgrw = dlantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, work )
584  IF( rpvgrw.EQ.zero ) THEN
585  rpvgrw = one
586  ELSE
587  rpvgrw = dlangb( 'M', n, kl, ku, ab, ldab, work ) / rpvgrw
588  END IF
589 *
590 * Compute the reciprocal of the condition number of A.
591 *
592  CALL dgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
593  $ work, iwork, info )
594 *
595 * Compute the solution matrix X.
596 *
597  CALL dlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
598  CALL dgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
599  $ info )
600 *
601 * Use iterative refinement to improve the computed solution and
602 * compute error bounds and backward error estimates for it.
603 *
604  CALL dgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv,
605  $ b, ldb, x, ldx, ferr, berr, work, iwork, info )
606 *
607 * Transform the solution matrix X to a solution of the original
608 * system.
609 *
610  IF( notran ) THEN
611  IF( colequ ) THEN
612  DO 110 j = 1, nrhs
613  DO 100 i = 1, n
614  x( i, j ) = c( i )*x( i, j )
615  100 continue
616  110 continue
617  DO 120 j = 1, nrhs
618  ferr( j ) = ferr( j ) / colcnd
619  120 continue
620  END IF
621  ELSE IF( rowequ ) THEN
622  DO 140 j = 1, nrhs
623  DO 130 i = 1, n
624  x( i, j ) = r( i )*x( i, j )
625  130 continue
626  140 continue
627  DO 150 j = 1, nrhs
628  ferr( j ) = ferr( j ) / rowcnd
629  150 continue
630  END IF
631 *
632 * Set INFO = N+1 if the matrix is singular to working precision.
633 *
634  IF( rcond.LT.dlamch( 'Epsilon' ) )
635  $ info = n + 1
636 *
637  work( 1 ) = rpvgrw
638  return
639 *
640 * End of DGBSVX
641 *
642  END