zlauum.f

Go to the documentation of this file.

*> \brief \b ZLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download ZLAUUM + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlauum.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlauum.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlauum.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLAUUM( UPLO, N, A, LDA, INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, N
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLAUUM computes the product U * U**H or L**H * L, where the triangular
*> factor U or L is stored in the upper or lower triangular part of
*> the array A.
*>
*> If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
*> overwriting the factor U in A.
*> If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
*> overwriting the factor L in A.
*>
*> This is the blocked form of the algorithm, calling Level 3 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the triangular factor stored in the array A
*>          is upper or lower triangular:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the triangular factor U or L.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the triangular factor U or L.
*>          On exit, if UPLO = 'U', the upper triangle of A is
*>          overwritten with the upper triangle of the product U * U**H;
*>          if UPLO = 'L', the lower triangle of A is overwritten with
*>          the lower triangle of the product L**H * L.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -k, the k-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup complex16OTHERauxiliary
*
*  =====================================================================
      SUBROUTINE zlauum( UPLO, N, A, LDA, INFO )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one
      parameter( one = 1.0d+0 )
      COMPLEX*16         cone
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            i, ib, nb
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            ilaenv
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgemm, zherk, zlauu2, ztrmm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZLAUUM', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   return
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'ZLAUUM', uplo, n, -1, -1, -1 )
*
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL zlauu2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code
*
         IF( upper ) THEN
*
*           Compute the product U * U**H.
*
            DO 10 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL ztrmm( 'Right', 'Upper', 'Conjugate transpose',
     $                     'Non-unit', i-1, ib, cone, a( i, i ), lda,
     $                     a( 1, i ), lda )
               CALL zlauu2( 'Upper', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL zgemm( 'No transpose', 'Conjugate transpose',
     $                        i-1, ib, n-i-ib+1, cone, a( 1, i+ib ),
     $                        lda, a( i, i+ib ), lda, cone, a( 1, i ),
     $                        lda )
                  CALL zherk( 'Upper', 'No transpose', ib, n-i-ib+1,
     $                        one, a( i, i+ib ), lda, one, a( i, i ),
     $                        lda )
               END IF
   10       continue
         ELSE
*
*           Compute the product L**H * L.
*
            DO 20 i = 1, n, nb
               ib = min( nb, n-i+1 )
               CALL ztrmm( 'Left', 'Lower', 'Conjugate transpose',
     $                     'Non-unit', ib, i-1, cone, a( i, i ), lda,
     $                     a( i, 1 ), lda )
               CALL zlauu2( 'Lower', ib, a( i, i ), lda, info )
               IF( i+ib.LE.n ) THEN
                  CALL zgemm( 'Conjugate transpose', 'No transpose', ib,
     $                        i-1, n-i-ib+1, cone, a( i+ib, i ), lda,
     $                        a( i+ib, 1 ), lda, cone, a( i, 1 ), lda )
                  CALL zherk( 'Lower', 'Conjugate transpose', ib,
     $                        n-i-ib+1, one, a( i+ib, i ), lda, one,
     $                        a( i, i ), lda )
               END IF
   20       continue
         END IF
      END IF
*
      return
*
*     End of ZLAUUM
*
      END