LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
zlatrd.f
Go to the documentation of this file.
1 *> \brief \b ZLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal form by an unitary similarity transformation.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZLATRD + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlatrd.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlatrd.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlatrd.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZLATRD( UPLO, N, NB, A, LDA, E, TAU, W, LDW )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER LDA, LDW, N, NB
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION E( * )
29 * COMPLEX*16 A( LDA, * ), TAU( * ), W( LDW, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZLATRD reduces NB rows and columns of a complex Hermitian matrix A to
39 *> Hermitian tridiagonal form by a unitary similarity
40 *> transformation Q**H * A * Q, and returns the matrices V and W which are
41 *> needed to apply the transformation to the unreduced part of A.
42 *>
43 *> If UPLO = 'U', ZLATRD reduces the last NB rows and columns of a
44 *> matrix, of which the upper triangle is supplied;
45 *> if UPLO = 'L', ZLATRD reduces the first NB rows and columns of a
46 *> matrix, of which the lower triangle is supplied.
47 *>
48 *> This is an auxiliary routine called by ZHETRD.
49 *> \endverbatim
50 *
51 * Arguments:
52 * ==========
53 *
54 *> \param[in] UPLO
55 *> \verbatim
56 *> UPLO is CHARACTER*1
57 *> Specifies whether the upper or lower triangular part of the
58 *> Hermitian matrix A is stored:
59 *> = 'U': Upper triangular
60 *> = 'L': Lower triangular
61 *> \endverbatim
62 *>
63 *> \param[in] N
64 *> \verbatim
65 *> N is INTEGER
66 *> The order of the matrix A.
67 *> \endverbatim
68 *>
69 *> \param[in] NB
70 *> \verbatim
71 *> NB is INTEGER
72 *> The number of rows and columns to be reduced.
73 *> \endverbatim
74 *>
75 *> \param[in,out] A
76 *> \verbatim
77 *> A is COMPLEX*16 array, dimension (LDA,N)
78 *> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
79 *> n-by-n upper triangular part of A contains the upper
80 *> triangular part of the matrix A, and the strictly lower
81 *> triangular part of A is not referenced. If UPLO = 'L', the
82 *> leading n-by-n lower triangular part of A contains the lower
83 *> triangular part of the matrix A, and the strictly upper
84 *> triangular part of A is not referenced.
85 *> On exit:
86 *> if UPLO = 'U', the last NB columns have been reduced to
87 *> tridiagonal form, with the diagonal elements overwriting
88 *> the diagonal elements of A; the elements above the diagonal
89 *> with the array TAU, represent the unitary matrix Q as a
90 *> product of elementary reflectors;
91 *> if UPLO = 'L', the first NB columns have been reduced to
92 *> tridiagonal form, with the diagonal elements overwriting
93 *> the diagonal elements of A; the elements below the diagonal
94 *> with the array TAU, represent the unitary matrix Q as a
95 *> product of elementary reflectors.
96 *> See Further Details.
97 *> \endverbatim
98 *>
99 *> \param[in] LDA
100 *> \verbatim
101 *> LDA is INTEGER
102 *> The leading dimension of the array A. LDA >= max(1,N).
103 *> \endverbatim
104 *>
105 *> \param[out] E
106 *> \verbatim
107 *> E is DOUBLE PRECISION array, dimension (N-1)
108 *> If UPLO = 'U', E(n-nb:n-1) contains the superdiagonal
109 *> elements of the last NB columns of the reduced matrix;
110 *> if UPLO = 'L', E(1:nb) contains the subdiagonal elements of
111 *> the first NB columns of the reduced matrix.
112 *> \endverbatim
113 *>
114 *> \param[out] TAU
115 *> \verbatim
116 *> TAU is COMPLEX*16 array, dimension (N-1)
117 *> The scalar factors of the elementary reflectors, stored in
118 *> TAU(n-nb:n-1) if UPLO = 'U', and in TAU(1:nb) if UPLO = 'L'.
119 *> See Further Details.
120 *> \endverbatim
121 *>
122 *> \param[out] W
123 *> \verbatim
124 *> W is COMPLEX*16 array, dimension (LDW,NB)
125 *> The n-by-nb matrix W required to update the unreduced part
126 *> of A.
127 *> \endverbatim
128 *>
129 *> \param[in] LDW
130 *> \verbatim
131 *> LDW is INTEGER
132 *> The leading dimension of the array W. LDW >= max(1,N).
133 *> \endverbatim
134 *
135 * Authors:
136 * ========
137 *
138 *> \author Univ. of Tennessee
139 *> \author Univ. of California Berkeley
140 *> \author Univ. of Colorado Denver
141 *> \author NAG Ltd.
142 *
143 *> \date September 2012
144 *
145 *> \ingroup complex16OTHERauxiliary
146 *
147 *> \par Further Details:
148 * =====================
149 *>
150 *> \verbatim
151 *>
152 *> If UPLO = 'U', the matrix Q is represented as a product of elementary
153 *> reflectors
154 *>
155 *> Q = H(n) H(n-1) . . . H(n-nb+1).
156 *>
157 *> Each H(i) has the form
158 *>
159 *> H(i) = I - tau * v * v**H
160 *>
161 *> where tau is a complex scalar, and v is a complex vector with
162 *> v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in A(1:i-1,i),
163 *> and tau in TAU(i-1).
164 *>
165 *> If UPLO = 'L', the matrix Q is represented as a product of elementary
166 *> reflectors
167 *>
168 *> Q = H(1) H(2) . . . H(nb).
169 *>
170 *> Each H(i) has the form
171 *>
172 *> H(i) = I - tau * v * v**H
173 *>
174 *> where tau is a complex scalar, and v is a complex vector with
175 *> v(1:i) = 0 and v(i+1) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
176 *> and tau in TAU(i).
177 *>
178 *> The elements of the vectors v together form the n-by-nb matrix V
179 *> which is needed, with W, to apply the transformation to the unreduced
180 *> part of the matrix, using a Hermitian rank-2k update of the form:
181 *> A := A - V*W**H - W*V**H.
182 *>
183 *> The contents of A on exit are illustrated by the following examples
184 *> with n = 5 and nb = 2:
185 *>
186 *> if UPLO = 'U': if UPLO = 'L':
187 *>
188 *> ( a a a v4 v5 ) ( d )
189 *> ( a a v4 v5 ) ( 1 d )
190 *> ( a 1 v5 ) ( v1 1 a )
191 *> ( d 1 ) ( v1 v2 a a )
192 *> ( d ) ( v1 v2 a a a )
193 *>
194 *> where d denotes a diagonal element of the reduced matrix, a denotes
195 *> an element of the original matrix that is unchanged, and vi denotes
196 *> an element of the vector defining H(i).
197 *> \endverbatim
198 *>
199 * =====================================================================
200  SUBROUTINE zlatrd( UPLO, N, NB, A, LDA, E, TAU, W, LDW )
201 *
202 * -- LAPACK auxiliary routine (version 3.4.2) --
203 * -- LAPACK is a software package provided by Univ. of Tennessee, --
204 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
205 * September 2012
206 *
207 * .. Scalar Arguments ..
208  CHARACTER uplo
209  INTEGER lda, ldw, n, nb
210 * ..
211 * .. Array Arguments ..
212  DOUBLE PRECISION e( * )
213  COMPLEX*16 a( lda, * ), tau( * ), w( ldw, * )
214 * ..
215 *
216 * =====================================================================
217 *
218 * .. Parameters ..
219  COMPLEX*16 zero, one, half
220  parameter( zero = ( 0.0d+0, 0.0d+0 ),
221  $ one = ( 1.0d+0, 0.0d+0 ),
222  $ half = ( 0.5d+0, 0.0d+0 ) )
223 * ..
224 * .. Local Scalars ..
225  INTEGER i, iw
226  COMPLEX*16 alpha
227 * ..
228 * .. External Subroutines ..
229  EXTERNAL zaxpy, zgemv, zhemv, zlacgv, zlarfg, zscal
230 * ..
231 * .. External Functions ..
232  LOGICAL lsame
233  COMPLEX*16 zdotc
234  EXTERNAL lsame, zdotc
235 * ..
236 * .. Intrinsic Functions ..
237  INTRINSIC dble, min
238 * ..
239 * .. Executable Statements ..
240 *
241 * Quick return if possible
242 *
243  IF( n.LE.0 )
244  $ return
245 *
246  IF( lsame( uplo, 'U' ) ) THEN
247 *
248 * Reduce last NB columns of upper triangle
249 *
250  DO 10 i = n, n - nb + 1, -1
251  iw = i - n + nb
252  IF( i.LT.n ) THEN
253 *
254 * Update A(1:i,i)
255 *
256  a( i, i ) = dble( a( i, i ) )
257  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
258  CALL zgemv( 'No transpose', i, n-i, -one, a( 1, i+1 ),
259  $ lda, w( i, iw+1 ), ldw, one, a( 1, i ), 1 )
260  CALL zlacgv( n-i, w( i, iw+1 ), ldw )
261  CALL zlacgv( n-i, a( i, i+1 ), lda )
262  CALL zgemv( 'No transpose', i, n-i, -one, w( 1, iw+1 ),
263  $ ldw, a( i, i+1 ), lda, one, a( 1, i ), 1 )
264  CALL zlacgv( n-i, a( i, i+1 ), lda )
265  a( i, i ) = dble( a( i, i ) )
266  END IF
267  IF( i.GT.1 ) THEN
268 *
269 * Generate elementary reflector H(i) to annihilate
270 * A(1:i-2,i)
271 *
272  alpha = a( i-1, i )
273  CALL zlarfg( i-1, alpha, a( 1, i ), 1, tau( i-1 ) )
274  e( i-1 ) = alpha
275  a( i-1, i ) = one
276 *
277 * Compute W(1:i-1,i)
278 *
279  CALL zhemv( 'Upper', i-1, one, a, lda, a( 1, i ), 1,
280  $ zero, w( 1, iw ), 1 )
281  IF( i.LT.n ) THEN
282  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
283  $ w( 1, iw+1 ), ldw, a( 1, i ), 1, zero,
284  $ w( i+1, iw ), 1 )
285  CALL zgemv( 'No transpose', i-1, n-i, -one,
286  $ a( 1, i+1 ), lda, w( i+1, iw ), 1, one,
287  $ w( 1, iw ), 1 )
288  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
289  $ a( 1, i+1 ), lda, a( 1, i ), 1, zero,
290  $ w( i+1, iw ), 1 )
291  CALL zgemv( 'No transpose', i-1, n-i, -one,
292  $ w( 1, iw+1 ), ldw, w( i+1, iw ), 1, one,
293  $ w( 1, iw ), 1 )
294  END IF
295  CALL zscal( i-1, tau( i-1 ), w( 1, iw ), 1 )
296  alpha = -half*tau( i-1 )*zdotc( i-1, w( 1, iw ), 1,
297  $ a( 1, i ), 1 )
298  CALL zaxpy( i-1, alpha, a( 1, i ), 1, w( 1, iw ), 1 )
299  END IF
300 *
301  10 continue
302  ELSE
303 *
304 * Reduce first NB columns of lower triangle
305 *
306  DO 20 i = 1, nb
307 *
308 * Update A(i:n,i)
309 *
310  a( i, i ) = dble( a( i, i ) )
311  CALL zlacgv( i-1, w( i, 1 ), ldw )
312  CALL zgemv( 'No transpose', n-i+1, i-1, -one, a( i, 1 ),
313  $ lda, w( i, 1 ), ldw, one, a( i, i ), 1 )
314  CALL zlacgv( i-1, w( i, 1 ), ldw )
315  CALL zlacgv( i-1, a( i, 1 ), lda )
316  CALL zgemv( 'No transpose', n-i+1, i-1, -one, w( i, 1 ),
317  $ ldw, a( i, 1 ), lda, one, a( i, i ), 1 )
318  CALL zlacgv( i-1, a( i, 1 ), lda )
319  a( i, i ) = dble( a( i, i ) )
320  IF( i.LT.n ) THEN
321 *
322 * Generate elementary reflector H(i) to annihilate
323 * A(i+2:n,i)
324 *
325  alpha = a( i+1, i )
326  CALL zlarfg( n-i, alpha, a( min( i+2, n ), i ), 1,
327  $ tau( i ) )
328  e( i ) = alpha
329  a( i+1, i ) = one
330 *
331 * Compute W(i+1:n,i)
332 *
333  CALL zhemv( 'Lower', n-i, one, a( i+1, i+1 ), lda,
334  $ a( i+1, i ), 1, zero, w( i+1, i ), 1 )
335  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
336  $ w( i+1, 1 ), ldw, a( i+1, i ), 1, zero,
337  $ w( 1, i ), 1 )
338  CALL zgemv( 'No transpose', n-i, i-1, -one, a( i+1, 1 ),
339  $ lda, w( 1, i ), 1, one, w( i+1, i ), 1 )
340  CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
341  $ a( i+1, 1 ), lda, a( i+1, i ), 1, zero,
342  $ w( 1, i ), 1 )
343  CALL zgemv( 'No transpose', n-i, i-1, -one, w( i+1, 1 ),
344  $ ldw, w( 1, i ), 1, one, w( i+1, i ), 1 )
345  CALL zscal( n-i, tau( i ), w( i+1, i ), 1 )
346  alpha = -half*tau( i )*zdotc( n-i, w( i+1, i ), 1,
347  $ a( i+1, i ), 1 )
348  CALL zaxpy( n-i, alpha, a( i+1, i ), 1, w( i+1, i ), 1 )
349  END IF
350 *
351  20 continue
352  END IF
353 *
354  return
355 *
356 * End of ZLATRD
357 *
358  END