dchkbl.f

Go to the documentation of this file.

*> \brief \b DCHKBL
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKBL( NIN, NOUT )
* 
*       .. Scalar Arguments ..
*       INTEGER            NIN, NOUT
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DCHKBL tests DGEBAL, a routine for balancing a general real
*> matrix and isolating some of its eigenvalues.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NIN
*> \verbatim
*>          NIN is INTEGER
*>          The logical unit number for input.  NIN > 0.
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The logical unit number for output.  NOUT > 0.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dchkbl( NIN, NOUT )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            nin, nout
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            lda
      parameter( lda = 20 )
      DOUBLE PRECISION   zero
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ihi, ihiin, ilo, iloin, info, j, knt, n,
     $                   ninfo
      DOUBLE PRECISION   anorm, meps, rmax, sfmin, temp, vmax
*     ..
*     .. Local Arrays ..
      INTEGER            lmax( 3 )
      DOUBLE PRECISION   a( lda, lda ), ain( lda, lda ), dummy( 1 ),
     $                   scale( lda ), scalin( lda )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgebal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
      vmax = zero
      sfmin = dlamch( 'S' )
      meps = dlamch( 'E' )
*
   10 continue
*
      READ( nin, fmt = * )n
      IF( n.EQ.0 )
     $   go to 70
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 continue
*
      READ( nin, fmt = * )iloin, ihiin
      DO 30 i = 1, n
         READ( nin, fmt = * )( ain( i, j ), j = 1, n )
   30 continue
      READ( nin, fmt = * )( scalin( i ), i = 1, n )
*
      anorm = dlange( 'M', n, n, a, lda, dummy )
      knt = knt + 1
*
      CALL dgebal( 'B', n, a, lda, ilo, ihi, scale, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      IF( ilo.NE.iloin .OR. ihi.NE.ihiin ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      DO 50 i = 1, n
         DO 40 j = 1, n
            temp = max( a( i, j ), ain( i, j ) )
            temp = max( temp, sfmin )
            vmax = max( vmax, abs( a( i, j )-ain( i, j ) ) / temp )
   40    continue
   50 continue
*
      DO 60 i = 1, n
         temp = max( scale( i ), scalin( i ) )
         temp = max( temp, sfmin )
         vmax = max( vmax, abs( scale( i )-scalin( i ) ) / temp )
   60 continue
*
*
      IF( vmax.GT.rmax ) THEN
         lmax( 3 ) = knt
         rmax = vmax
      END IF
*
      go to 10
*
   70 continue
*
      WRITE( nout, fmt = 9999 )
 9999 format( 1x, '.. test output of DGEBAL .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 format( 1x, 'value of largest test error            = ', d12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 format( 1x, 'example number where info is not zero  = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 format( 1x, 'example number where ILO or IHI wrong  = ', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 format( 1x, 'example number having largest error    = ', i4 )
      WRITE( nout, fmt = 9994 )ninfo
 9994 format( 1x, 'number of examples where info is not 0 = ', i4 )
      WRITE( nout, fmt = 9993 )knt
 9993 format( 1x, 'total number of examples tested        = ', i4 )
*
      return
*
*     End of DCHKBL
*
      END