cchktz.f

Go to the documentation of this file.

*> \brief \b CCHKTZ
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CCHKTZ( DOTYPE, NM, MVAL, NN, NVAL, THRESH, TSTERR, A,
*                          COPYA, S, TAU, WORK, RWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NM, NN, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            MVAL( * ), NVAL( * )
*       REAL               S( * ), RWORK( * )
*       COMPLEX            A( * ), COPYA( * ), TAU( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CCHKTZ tests CTZRQF and CTZRZF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX array, dimension (MMAX*NMAX)
*>          where MMAX is the maximum value of M in MVAL and NMAX is the
*>          maximum value of N in NVAL.
*> \endverbatim
*>
*> \param[out] COPYA
*> \verbatim
*>          COPYA is COMPLEX array, dimension (MMAX*NMAX)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is REAL array, dimension
*>                      (min(MMAX,NMAX))
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is COMPLEX array, dimension (MMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension
*>                      (MMAX*NMAX + 4*NMAX + MMAX)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cchktz( DOTYPE, NM, MVAL, NN, NVAL, THRESH, TSTERR, A,
     $                   copya, s, tau, work, rwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            tsterr
      INTEGER            nm, nn, nout
      REAL               thresh
*     ..
*     .. Array Arguments ..
      LOGICAL            dotype( * )
      INTEGER            mval( * ), nval( * )
      REAL               s( * ), rwork( * )
      COMPLEX            a( * ), copya( * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ntypes
      parameter( ntypes = 3 )
      INTEGER            ntests
      parameter( ntests = 6 )
      REAL               one, zero
      parameter( one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      CHARACTER*3        path
      INTEGER            i, im, imode, in, info, k, lda, lwork, m,
     $                   mnmin, mode, n, nerrs, nfail, nrun
      REAL               eps
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 ), iseedy( 4 )
      REAL               result( ntests )
*     ..
*     .. External Functions ..
      REAL               cqrt12, crzt01, crzt02, ctzt01, ctzt02, slamch
      EXTERNAL           cqrt12, crzt01, crzt02, ctzt01, ctzt02, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahd, alasum, cerrtz, cgeqr2, clacpy, claset,
     $                   clatms, ctzrqf, ctzrzf, slaord
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            lerr, ok
      CHARACTER*32       srnamt
      INTEGER            infot, iounit
*     ..
*     .. Common blocks ..
      common             / infoc / infot, iounit, ok, lerr
      common             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'TZ'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 continue
      eps = slamch( 'Epsilon' )
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrtz( path, nout )
      infot = 0
*
      DO 70 im = 1, nm
*
*        Do for each value of M in MVAL.
*
         m = mval( im )
         lda = max( 1, m )
*
         DO 60 in = 1, nn
*
*           Do for each value of N in NVAL for which M .LE. N.
*
            n = nval( in )
            mnmin = min( m, n )
            lwork = max( 1, n*n+4*m+n )
*
            IF( m.LE.n ) THEN
               DO 50 imode = 1, ntypes
                  IF( .NOT.dotype( imode ) )
     $               go to 50
*
*                 Do for each type of singular value distribution.
*                    0:  zero matrix
*                    1:  one small singular value
*                    2:  exponential distribution
*
                  mode = imode - 1
*
*                 Test CTZRQF
*
*                 Generate test matrix of size m by n using
*                 singular value distribution indicated by `mode'.
*
                  IF( mode.EQ.0 ) THEN
                     CALL claset( 'Full', m, n, cmplx( zero ),
     $                            cmplx( zero ), a, lda )
                     DO 20 i = 1, mnmin
                        s( i ) = zero
   20                continue
                  ELSE
                     CALL clatms( m, n, 'Uniform', iseed,
     $                            'Nonsymmetric', s, imode,
     $                            one / eps, one, m, n, 'No packing', a,
     $                            lda, work, info )
                     CALL cgeqr2( m, n, a, lda, work, work( mnmin+1 ),
     $                            info )
                     CALL claset( 'Lower', m-1, n, cmplx( zero ),
     $                            cmplx( zero ), a( 2 ), lda )
                     CALL slaord( 'Decreasing', mnmin, s, 1 )
                  END IF
*
*                 Save A and its singular values
*
                  CALL clacpy( 'All', m, n, a, lda, copya, lda )
*
*                 Call CTZRQF to reduce the upper trapezoidal matrix to
*                 upper triangular form.
*
                  srnamt = 'CTZRQF'
                  CALL ctzrqf( m, n, a, lda, tau, info )
*
*                 Compute norm(svd(a) - svd(r))
*
                  result( 1 ) = cqrt12( m, m, a, lda, s, work,
     $                          lwork, rwork )
*
*                 Compute norm( A - R*Q )
*
                  result( 2 ) = ctzt01( m, n, copya, a, lda, tau, work,
     $                          lwork )
*
*                 Compute norm(Q'*Q - I).
*
                  result( 3 ) = ctzt02( m, n, a, lda, tau, work, lwork )
*
*                 Test CTZRZF
*
*                 Generate test matrix of size m by n using
*                 singular value distribution indicated by `mode'.
*
                  IF( mode.EQ.0 ) THEN
                     CALL claset( 'Full', m, n, cmplx( zero ),
     $                            cmplx( zero ), a, lda )
                     DO 30 i = 1, mnmin
                        s( i ) = zero
   30                continue
                  ELSE
                     CALL clatms( m, n, 'Uniform', iseed,
     $                            'Nonsymmetric', s, imode,
     $                            one / eps, one, m, n, 'No packing', a,
     $                            lda, work, info )
                     CALL cgeqr2( m, n, a, lda, work, work( mnmin+1 ),
     $                            info )
                     CALL claset( 'Lower', m-1, n, cmplx( zero ),
     $                            cmplx( zero ), a( 2 ), lda )
                     CALL slaord( 'Decreasing', mnmin, s, 1 )
                  END IF
*
*                 Save A and its singular values
*
                  CALL clacpy( 'All', m, n, a, lda, copya, lda )
*
*                 Call CTZRZF to reduce the upper trapezoidal matrix to
*                 upper triangular form.
*
                  srnamt = 'CTZRZF'
                  CALL ctzrzf( m, n, a, lda, tau, work, lwork, info )
*
*                 Compute norm(svd(a) - svd(r))
*
                  result( 4 ) = cqrt12( m, m, a, lda, s, work,
     $                          lwork, rwork )
*
*                 Compute norm( A - R*Q )
*
                  result( 5 ) = crzt01( m, n, copya, a, lda, tau, work,
     $                          lwork )
*
*                 Compute norm(Q'*Q - I).
*
                  result( 6 ) = crzt02( m, n, a, lda, tau, work, lwork )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 40 k = 1, 6
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )m, n, imode, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
   40             continue
                  nrun = nrun + 6
   50          continue
            END IF
   60    continue
   70 continue
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 format( ' M =', i5, ', N =', i5, ', type ', i2, ', test ', i2,
     $      ', ratio =', g12.5 )
*
*     End if CCHKTZ
*
      END