slasd0.f

Go to the documentation of this file.

*> \brief \b SLASD0 computes the singular values of a real upper bidiagonal n-by-m matrix B with diagonal d and off-diagonal e. Used by sbdsdc.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download SLASD0 + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slasd0.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slasd0.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slasd0.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLASD0( N, SQRE, D, E, U, LDU, VT, LDVT, SMLSIZ, IWORK,
*                          WORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDU, LDVT, N, SMLSIZ, SQRE
*       ..
*       .. Array Arguments ..
*       INTEGER            IWORK( * )
*       REAL               D( * ), E( * ), U( LDU, * ), VT( LDVT, * ),
*      $                   WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> Using a divide and conquer approach, SLASD0 computes the singular
*> value decomposition (SVD) of a real upper bidiagonal N-by-M
*> matrix B with diagonal D and offdiagonal E, where M = N + SQRE.
*> The algorithm computes orthogonal matrices U and VT such that
*> B = U * S * VT. The singular values S are overwritten on D.
*>
*> A related subroutine, SLASDA, computes only the singular values,
*> and optionally, the singular vectors in compact form.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>         On entry, the row dimension of the upper bidiagonal matrix.
*>         This is also the dimension of the main diagonal array D.
*> \endverbatim
*>
*> \param[in] SQRE
*> \verbatim
*>          SQRE is INTEGER
*>         Specifies the column dimension of the bidiagonal matrix.
*>         = 0: The bidiagonal matrix has column dimension M = N;
*>         = 1: The bidiagonal matrix has column dimension M = N+1;
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>         On entry D contains the main diagonal of the bidiagonal
*>         matrix.
*>         On exit D, if INFO = 0, contains its singular values.
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is REAL array, dimension (M-1)
*>         Contains the subdiagonal entries of the bidiagonal matrix.
*>         On exit, E has been destroyed.
*> \endverbatim
*>
*> \param[out] U
*> \verbatim
*>          U is REAL array, dimension at least (LDQ, N)
*>         On exit, U contains the left singular vectors.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>         On entry, leading dimension of U.
*> \endverbatim
*>
*> \param[out] VT
*> \verbatim
*>          VT is REAL array, dimension at least (LDVT, M)
*>         On exit, VT**T contains the right singular vectors.
*> \endverbatim
*>
*> \param[in] LDVT
*> \verbatim
*>          LDVT is INTEGER
*>         On entry, leading dimension of VT.
*> \endverbatim
*>
*> \param[in] SMLSIZ
*> \verbatim
*>          SMLSIZ is INTEGER
*>         On entry, maximum size of the subproblems at the
*>         bottom of the computation tree.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (8*N)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (3*M**2+2*M)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  if INFO = 1, a singular value did not converge
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup auxOTHERauxiliary
*
*> \par Contributors:
*  ==================
*>
*>     Ming Gu and Huan Ren, Computer Science Division, University of
*>     California at Berkeley, USA
*>
*  =====================================================================
      SUBROUTINE slasd0( N, SQRE, D, E, U, LDU, VT, LDVT, SMLSIZ, IWORK,
     $                   work, info )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            info, ldu, ldvt, n, smlsiz, sqre
*     ..
*     .. Array Arguments ..
      INTEGER            iwork( * )
      REAL               d( * ), e( * ), u( ldu, * ), vt( ldvt, * ),
     $                   work( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            i, i1, ic, idxq, idxqc, im1, inode, itemp, iwk,
     $                   j, lf, ll, lvl, m, ncc, nd, ndb1, ndiml, ndimr,
     $                   nl, nlf, nlp1, nlvl, nr, nrf, nrp1, sqrei
      REAL               alpha, beta
*     ..
*     .. External Subroutines ..
      EXTERNAL           slasd1, slasdq, slasdt, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( ( sqre.LT.0 ) .OR. ( sqre.GT.1 ) ) THEN
         info = -2
      END IF
*
      m = n + sqre
*
      IF( ldu.LT.n ) THEN
         info = -6
      ELSE IF( ldvt.LT.m ) THEN
         info = -8
      ELSE IF( smlsiz.LT.3 ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLASD0', -info )
         return
      END IF
*
*     If the input matrix is too small, call SLASDQ to find the SVD.
*
      IF( n.LE.smlsiz ) THEN
         CALL slasdq( 'U', sqre, n, m, n, 0, d, e, vt, ldvt, u, ldu, u,
     $                ldu, work, info )
         return
      END IF
*
*     Set up the computation tree.
*
      inode = 1
      ndiml = inode + n
      ndimr = ndiml + n
      idxq = ndimr + n
      iwk = idxq + n
      CALL slasdt( n, nlvl, nd, iwork( inode ), iwork( ndiml ),
     $             iwork( ndimr ), smlsiz )
*
*     For the nodes on bottom level of the tree, solve
*     their subproblems by SLASDQ.
*
      ndb1 = ( nd+1 ) / 2
      ncc = 0
      DO 30 i = ndb1, nd
*
*     IC : center row of each node
*     NL : number of rows of left  subproblem
*     NR : number of rows of right subproblem
*     NLF: starting row of the left   subproblem
*     NRF: starting row of the right  subproblem
*
         i1 = i - 1
         ic = iwork( inode+i1 )
         nl = iwork( ndiml+i1 )
         nlp1 = nl + 1
         nr = iwork( ndimr+i1 )
         nrp1 = nr + 1
         nlf = ic - nl
         nrf = ic + 1
         sqrei = 1
         CALL slasdq( 'U', sqrei, nl, nlp1, nl, ncc, d( nlf ), e( nlf ),
     $                vt( nlf, nlf ), ldvt, u( nlf, nlf ), ldu,
     $                u( nlf, nlf ), ldu, work, info )
         IF( info.NE.0 ) THEN
            return
         END IF
         itemp = idxq + nlf - 2
         DO 10 j = 1, nl
            iwork( itemp+j ) = j
   10    continue
         IF( i.EQ.nd ) THEN
            sqrei = sqre
         ELSE
            sqrei = 1
         END IF
         nrp1 = nr + sqrei
         CALL slasdq( 'U', sqrei, nr, nrp1, nr, ncc, d( nrf ), e( nrf ),
     $                vt( nrf, nrf ), ldvt, u( nrf, nrf ), ldu,
     $                u( nrf, nrf ), ldu, work, info )
         IF( info.NE.0 ) THEN
            return
         END IF
         itemp = idxq + ic
         DO 20 j = 1, nr
            iwork( itemp+j-1 ) = j
   20    continue
   30 continue
*
*     Now conquer each subproblem bottom-up.
*
      DO 50 lvl = nlvl, 1, -1
*
*        Find the first node LF and last node LL on the
*        current level LVL.
*
         IF( lvl.EQ.1 ) THEN
            lf = 1
            ll = 1
         ELSE
            lf = 2**( lvl-1 )
            ll = 2*lf - 1
         END IF
         DO 40 i = lf, ll
            im1 = i - 1
            ic = iwork( inode+im1 )
            nl = iwork( ndiml+im1 )
            nr = iwork( ndimr+im1 )
            nlf = ic - nl
            IF( ( sqre.EQ.0 ) .AND. ( i.EQ.ll ) ) THEN
               sqrei = sqre
            ELSE
               sqrei = 1
            END IF
            idxqc = idxq + nlf - 1
            alpha = d( ic )
            beta = e( ic )
            CALL slasd1( nl, nr, sqrei, d( nlf ), alpha, beta,
     $                   u( nlf, nlf ), ldu, vt( nlf, nlf ), ldvt,
     $                   iwork( idxqc ), iwork( iwk ), work, info )
            IF( info.NE.0 ) THEN
               return
            END IF
   40    continue
   50 continue
*
      return
*
*     End of SLASD0
*
      END