slatdf.f

Go to the documentation of this file.

*> \brief \b SLATDF uses the LU factorization of the n-by-n matrix computed by sgetc2 and computes a contribution to the reciprocal Dif-estimate.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download SLATDF + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slatdf.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slatdf.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slatdf.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLATDF( IJOB, N, Z, LDZ, RHS, RDSUM, RDSCAL, IPIV,
*                          JPIV )
* 
*       .. Scalar Arguments ..
*       INTEGER            IJOB, LDZ, N
*       REAL               RDSCAL, RDSUM
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * ), JPIV( * )
*       REAL               RHS( * ), Z( LDZ, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLATDF uses the LU factorization of the n-by-n matrix Z computed by
*> SGETC2 and computes a contribution to the reciprocal Dif-estimate
*> by solving Z * x = b for x, and choosing the r.h.s. b such that
*> the norm of x is as large as possible. On entry RHS = b holds the
*> contribution from earlier solved sub-systems, and on return RHS = x.
*>
*> The factorization of Z returned by SGETC2 has the form Z = P*L*U*Q,
*> where P and Q are permutation matrices. L is lower triangular with
*> unit diagonal elements and U is upper triangular.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] IJOB
*> \verbatim
*>          IJOB is INTEGER
*>          IJOB = 2: First compute an approximative null-vector e
*>              of Z using SGECON, e is normalized and solve for
*>              Zx = +-e - f with the sign giving the greater value
*>              of 2-norm(x). About 5 times as expensive as Default.
*>          IJOB .ne. 2: Local look ahead strategy where all entries of
*>              the r.h.s. b is choosen as either +1 or -1 (Default).
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix Z.
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is REAL array, dimension (LDZ, N)
*>          On entry, the LU part of the factorization of the n-by-n
*>          matrix Z computed by SGETC2:  Z = P * L * U * Q
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDA >= max(1, N).
*> \endverbatim
*>
*> \param[in,out] RHS
*> \verbatim
*>          RHS is REAL array, dimension N.
*>          On entry, RHS contains contributions from other subsystems.
*>          On exit, RHS contains the solution of the subsystem with
*>          entries acoording to the value of IJOB (see above).
*> \endverbatim
*>
*> \param[in,out] RDSUM
*> \verbatim
*>          RDSUM is REAL
*>          On entry, the sum of squares of computed contributions to
*>          the Dif-estimate under computation by STGSYL, where the
*>          scaling factor RDSCAL (see below) has been factored out.
*>          On exit, the corresponding sum of squares updated with the
*>          contributions from the current sub-system.
*>          If TRANS = 'T' RDSUM is not touched.
*>          NOTE: RDSUM only makes sense when STGSY2 is called by STGSYL.
*> \endverbatim
*>
*> \param[in,out] RDSCAL
*> \verbatim
*>          RDSCAL is REAL
*>          On entry, scaling factor used to prevent overflow in RDSUM.
*>          On exit, RDSCAL is updated w.r.t. the current contributions
*>          in RDSUM.
*>          If TRANS = 'T', RDSCAL is not touched.
*>          NOTE: RDSCAL only makes sense when STGSY2 is called by
*>                STGSYL.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= i <= N, row i of the
*>          matrix has been interchanged with row IPIV(i).
*> \endverbatim
*>
*> \param[in] JPIV
*> \verbatim
*>          JPIV is INTEGER array, dimension (N).
*>          The pivot indices; for 1 <= j <= N, column j of the
*>          matrix has been interchanged with column JPIV(j).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup realOTHERauxiliary
*
*> \par Further Details:
*  =====================
*>
*>  This routine is a further developed implementation of algorithm
*>  BSOLVE in [1] using complete pivoting in the LU factorization.
*
*> \par Contributors:
*  ==================
*>
*>     Bo Kagstrom and Peter Poromaa, Department of Computing Science,
*>     Umea University, S-901 87 Umea, Sweden.
*
*> \par References:
*  ================
*>
*> \verbatim
*>
*>
*>  [1] Bo Kagstrom and Lars Westin,
*>      Generalized Schur Methods with Condition Estimators for
*>      Solving the Generalized Sylvester Equation, IEEE Transactions
*>      on Automatic Control, Vol. 34, No. 7, July 1989, pp 745-751.
*>
*>  [2] Peter Poromaa,
*>      On Efficient and Robust Estimators for the Separation
*>      between two Regular Matrix Pairs with Applications in
*>      Condition Estimation. Report IMINF-95.05, Departement of
*>      Computing Science, Umea University, S-901 87 Umea, Sweden, 1995.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE slatdf( IJOB, N, Z, LDZ, RHS, RDSUM, RDSCAL, IPIV,
     $                   jpiv )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            ijob, ldz, n
      REAL               rdscal, rdsum
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * ), jpiv( * )
      REAL               rhs( * ), z( ldz, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            maxdim
      parameter( maxdim = 8 )
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j, k
      REAL               bm, bp, pmone, sminu, splus, temp
*     ..
*     .. Local Arrays ..
      INTEGER            iwork( maxdim )
      REAL               work( 4*maxdim ), xm( maxdim ), xp( maxdim )
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, sgecon, sgesc2, slassq, slaswp,
     $                   sscal
*     ..
*     .. External Functions ..
      REAL               sasum, sdot
      EXTERNAL           sasum, sdot
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( ijob.NE.2 ) THEN
*
*        Apply permutations IPIV to RHS
*
         CALL slaswp( 1, rhs, ldz, 1, n-1, ipiv, 1 )
*
*        Solve for L-part choosing RHS either to +1 or -1.
*
         pmone = -one
*
         DO 10 j = 1, n - 1
            bp = rhs( j ) + one
            bm = rhs( j ) - one
            splus = one
*
*           Look-ahead for L-part RHS(1:N-1) = + or -1, SPLUS and
*           SMIN computed more efficiently than in BSOLVE [1].
*
            splus = splus + sdot( n-j, z( j+1, j ), 1, z( j+1, j ), 1 )
            sminu = sdot( n-j, z( j+1, j ), 1, rhs( j+1 ), 1 )
            splus = splus*rhs( j )
            IF( splus.GT.sminu ) THEN
               rhs( j ) = bp
            ELSE IF( sminu.GT.splus ) THEN
               rhs( j ) = bm
            ELSE
*
*              In this case the updating sums are equal and we can
*              choose RHS(J) +1 or -1. The first time this happens
*              we choose -1, thereafter +1. This is a simple way to
*              get good estimates of matrices like Byers well-known
*              example (see [1]). (Not done in BSOLVE.)
*
               rhs( j ) = rhs( j ) + pmone
               pmone = one
            END IF
*
*           Compute the remaining r.h.s.
*
            temp = -rhs( j )
            CALL saxpy( n-j, temp, z( j+1, j ), 1, rhs( j+1 ), 1 )
*
   10    continue
*
*        Solve for U-part, look-ahead for RHS(N) = +-1. This is not done
*        in BSOLVE and will hopefully give us a better estimate because
*        any ill-conditioning of the original matrix is transfered to U
*        and not to L. U(N, N) is an approximation to sigma_min(LU).
*
         CALL scopy( n-1, rhs, 1, xp, 1 )
         xp( n ) = rhs( n ) + one
         rhs( n ) = rhs( n ) - one
         splus = zero
         sminu = zero
         DO 30 i = n, 1, -1
            temp = one / z( i, i )
            xp( i ) = xp( i )*temp
            rhs( i ) = rhs( i )*temp
            DO 20 k = i + 1, n
               xp( i ) = xp( i ) - xp( k )*( z( i, k )*temp )
               rhs( i ) = rhs( i ) - rhs( k )*( z( i, k )*temp )
   20       continue
            splus = splus + abs( xp( i ) )
            sminu = sminu + abs( rhs( i ) )
   30    continue
         IF( splus.GT.sminu )
     $      CALL scopy( n, xp, 1, rhs, 1 )
*
*        Apply the permutations JPIV to the computed solution (RHS)
*
         CALL slaswp( 1, rhs, ldz, 1, n-1, jpiv, -1 )
*
*        Compute the sum of squares
*
         CALL slassq( n, rhs, 1, rdscal, rdsum )
*
      ELSE
*
*        IJOB = 2, Compute approximate nullvector XM of Z
*
         CALL sgecon( 'I', n, z, ldz, one, temp, work, iwork, info )
         CALL scopy( n, work( n+1 ), 1, xm, 1 )
*
*        Compute RHS
*
         CALL slaswp( 1, xm, ldz, 1, n-1, ipiv, -1 )
         temp = one / sqrt( sdot( n, xm, 1, xm, 1 ) )
         CALL sscal( n, temp, xm, 1 )
         CALL scopy( n, xm, 1, xp, 1 )
         CALL saxpy( n, one, rhs, 1, xp, 1 )
         CALL saxpy( n, -one, xm, 1, rhs, 1 )
         CALL sgesc2( n, z, ldz, rhs, ipiv, jpiv, temp )
         CALL sgesc2( n, z, ldz, xp, ipiv, jpiv, temp )
         IF( sasum( n, xp, 1 ).GT.sasum( n, rhs, 1 ) )
     $      CALL scopy( n, xp, 1, rhs, 1 )
*
*        Compute the sum of squares
*
         CALL slassq( n, rhs, 1, rdscal, rdsum )
*
      END IF
*
      return
*
*     End of SLATDF
*
      END