zget52.f

Go to the documentation of this file.

*> \brief \b ZGET52
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGET52( LEFT, N, A, LDA, B, LDB, E, LDE, ALPHA, BETA,
*                          WORK, RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            LEFT
*       INTEGER            LDA, LDB, LDE, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   RESULT( 2 ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), ALPHA( * ), B( LDB, * ),
*      $                   BETA( * ), E( LDE, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGET52  does an eigenvector check for the generalized eigenvalue
*> problem.
*>
*> The basic test for right eigenvectors is:
*>
*>                           | b(i) A E(i) -  a(i) B E(i) |
*>         RESULT(1) = max   -------------------------------
*>                      i    n ulp max( |b(i) A|, |a(i) B| )
*>
*> using the 1-norm.  Here, a(i)/b(i) = w is the i-th generalized
*> eigenvalue of A - w B, or, equivalently, b(i)/a(i) = m is the i-th
*> generalized eigenvalue of m A - B.
*>
*>                         H   H  _      _
*> For left eigenvectors, A , B , a, and b  are used.
*>
*> ZGET52 also tests the normalization of E.  Each eigenvector is
*> supposed to be normalized so that the maximum "absolute value"
*> of its elements is 1, where in this case, "absolute value"
*> of a complex value x is  |Re(x)| + |Im(x)| ; let us call this
*> maximum "absolute value" norm of a vector v  M(v).  
*> If a(i)=b(i)=0, then the eigenvector is set to be the jth coordinate
*> vector. The normalization test is:
*>
*>         RESULT(2) =      max       | M(v(i)) - 1 | / ( n ulp )
*>                    eigenvectors v(i)
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] LEFT
*> \verbatim
*>          LEFT is LOGICAL
*>          =.TRUE.:  The eigenvectors in the columns of E are assumed
*>                    to be *left* eigenvectors.
*>          =.FALSE.: The eigenvectors in the columns of E are assumed
*>                    to be *right* eigenvectors.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrices.  If it is zero, ZGET52 does
*>          nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA, N)
*>          The matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB, N)
*>          The matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of B.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is COMPLEX*16 array, dimension (LDE, N)
*>          The matrix of eigenvectors.  It must be O( 1 ).
*> \endverbatim
*>
*> \param[in] LDE
*> \verbatim
*>          LDE is INTEGER
*>          The leading dimension of E.  It must be at least 1 and at
*>          least N.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*>          ALPHA is COMPLEX*16 array, dimension (N)
*>          The values a(i) as described above, which, along with b(i),
*>          define the generalized eigenvalues.
*> \endverbatim
*>
*> \param[in] BETA
*> \verbatim
*>          BETA is COMPLEX*16 array, dimension (N)
*>          The values b(i) as described above, which, along with a(i),
*>          define the generalized eigenvalues.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (N**2)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (2)
*>          The values computed by the test described above.  If A E or
*>          B E is likely to overflow, then RESULT(1:2) is set to
*>          10 / ulp.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zget52( LEFT, N, A, LDA, B, LDB, E, LDE, ALPHA, BETA,
     $                   work, rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            left
      INTEGER            lda, ldb, lde, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( 2 ), rwork( * )
      COMPLEX*16         a( lda, * ), alpha( * ), b( ldb, * ),
     $                   beta( * ), e( lde, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          normab, trans
      INTEGER            j, jvec
      DOUBLE PRECISION   abmax, alfmax, anorm, betmax, bnorm, enorm,
     $                   enrmer, errnrm, safmax, safmin, scale, temp1,
     $                   ulp
      COMPLEX*16         acoeff, alphai, bcoeff, betai, x
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, dimag, max
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   abs1
*     ..
*     .. Statement Function definitions ..
      abs1( x ) = abs( dble( x ) ) + abs( dimag( x ) )
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   return
*
      safmin = dlamch( 'Safe minimum' )
      safmax = one / safmin
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
      IF( left ) THEN
         trans = 'C'
         normab = 'I'
      ELSE
         trans = 'N'
         normab = 'O'
      END IF
*
*     Norm of A, B, and E:
*
      anorm = max( zlange( normab, n, n, a, lda, rwork ), safmin )
      bnorm = max( zlange( normab, n, n, b, ldb, rwork ), safmin )
      enorm = max( zlange( 'O', n, n, e, lde, rwork ), ulp )
      alfmax = safmax / max( one, bnorm )
      betmax = safmax / max( one, anorm )
*
*     Compute error matrix.
*     Column i = ( b(i) A - a(i) B ) E(i) / max( |a(i) B| |b(i) A| )
*
      DO 10 jvec = 1, n
         alphai = alpha( jvec )
         betai = beta( jvec )
         abmax = max( abs1( alphai ), abs1( betai ) )
         IF( abs1( alphai ).GT.alfmax .OR. abs1( betai ).GT.betmax .OR.
     $       abmax.LT.one ) THEN
            scale = one / max( abmax, safmin )
            alphai = scale*alphai
            betai = scale*betai
         END IF
         scale = one / max( abs1( alphai )*bnorm, abs1( betai )*anorm,
     $           safmin )
         acoeff = scale*betai
         bcoeff = scale*alphai
         IF( left ) THEN
            acoeff = dconjg( acoeff )
            bcoeff = dconjg( bcoeff )
         END IF
         CALL zgemv( trans, n, n, acoeff, a, lda, e( 1, jvec ), 1,
     $               czero, work( n*( jvec-1 )+1 ), 1 )
         CALL zgemv( trans, n, n, -bcoeff, b, lda, e( 1, jvec ), 1,
     $               cone, work( n*( jvec-1 )+1 ), 1 )
   10 continue
*
      errnrm = zlange( 'One', n, n, work, n, rwork ) / enorm
*
*     Compute RESULT(1)
*
      result( 1 ) = errnrm / ulp
*
*     Normalization of E:
*
      enrmer = zero
      DO 30 jvec = 1, n
         temp1 = zero
         DO 20 j = 1, n
            temp1 = max( temp1, abs1( e( j, jvec ) ) )
   20    continue
         enrmer = max( enrmer, temp1-one )
   30 continue
*
*     Compute RESULT(2) : the normalization error in E.
*
      result( 2 ) = enrmer / ( dble( n )*ulp )
*
      return
*
*     End of ZGET52
*
      END