dlafts.f

Go to the documentation of this file.

*> \brief \b DLAFTS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLAFTS( TYPE, M, N, IMAT, NTESTS, RESULT, ISEED,
*                          THRESH, IOUNIT, IE )
* 
*       .. Scalar Arguments ..
*       CHARACTER*3        TYPE
*       INTEGER            IE, IMAT, IOUNIT, M, N, NTESTS
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       DOUBLE PRECISION   RESULT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    DLAFTS tests the result vector against the threshold value to
*>    see which tests for this matrix type failed to pass the threshold.
*>    Output is to the file given by unit IOUNIT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \verbatim
*>  TYPE   - CHARACTER*3
*>           On entry, TYPE specifies the matrix type to be used in the
*>           printed messages.
*>           Not modified.
*>
*>  N      - INTEGER
*>           On entry, N specifies the order of the test matrix.
*>           Not modified.
*>
*>  IMAT   - INTEGER
*>           On entry, IMAT specifies the type of the test matrix.
*>           A listing of the different types is printed by DLAHD2
*>           to the output file if a test fails to pass the threshold.
*>           Not modified.
*>
*>  NTESTS - INTEGER
*>           On entry, NTESTS is the number of tests performed on the
*>           subroutines in the path given by TYPE.
*>           Not modified.
*>
*>  RESULT - DOUBLE PRECISION               array of dimension( NTESTS )
*>           On entry, RESULT contains the test ratios from the tests
*>           performed in the calling program.
*>           Not modified.
*>
*>  ISEED  - INTEGER            array of dimension( 4 )
*>           Contains the random seed that generated the matrix used
*>           for the tests whose ratios are in RESULT.
*>           Not modified.
*>
*>  THRESH - DOUBLE PRECISION
*>           On entry, THRESH specifies the acceptable threshold of the
*>           test ratios.  If RESULT( K ) > THRESH, then the K-th test
*>           did not pass the threshold and a message will be printed.
*>           Not modified.
*>
*>  IOUNIT - INTEGER
*>           On entry, IOUNIT specifies the unit number of the file
*>           to which the messages are printed.
*>           Not modified.
*>
*>  IE     - INTEGER
*>           On entry, IE contains the number of tests which have
*>           failed to pass the threshold so far.
*>           Updated on exit if any of the ratios in RESULT also fail.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dlafts( TYPE, M, N, IMAT, NTESTS, RESULT, ISEED,
     $                   thresh, iounit, ie )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER*3        type
      INTEGER            ie, imat, iounit, m, n, ntests
      DOUBLE PRECISION   thresh
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
      DOUBLE PRECISION   result( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            k
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlahd2
*     ..
*     .. Executable Statements ..
*
      IF( m.EQ.n ) THEN
*
*     Output for square matrices:
*
         DO 10 k = 1, ntests
            IF( result( k ).GE.thresh ) THEN
*
*           If this is the first test to fail, call DLAHD2
*           to print a header to the data file.
*
               IF( ie.EQ.0 )
     $            CALL dlahd2( iounit, TYPE )
               ie = ie + 1
               IF( result( k ).LT.10000.0d0 ) THEN
                  WRITE( iounit, fmt = 9999 )n, imat, iseed, k,
     $               result( k )
 9999             format( ' Matrix order=', i5, ', type=', i2,
     $                  ', seed=', 4( i4, ',' ), ' result ', i3, ' is',
     $                  0p, f8.2 )
               ELSE
                  WRITE( iounit, fmt = 9998 )n, imat, iseed, k,
     $               result( k )
 9998             format( ' Matrix order=', i5, ', type=', i2,
     $                  ', seed=', 4( i4, ',' ), ' result ', i3, ' is',
     $                  1p, d10.3 )
               END IF
            END IF
   10    continue
      ELSE
*
*     Output for rectangular matrices
*
         DO 20 k = 1, ntests
            IF( result( k ).GE.thresh ) THEN
*
*              If this is the first test to fail, call DLAHD2
*              to print a header to the data file.
*
               IF( ie.EQ.0 )
     $            CALL dlahd2( iounit, TYPE )
               ie = ie + 1
               IF( result( k ).LT.10000.0d0 ) THEN
                  WRITE( iounit, fmt = 9997 )m, n, imat, iseed, k,
     $               result( k )
 9997             format( 1x, i5, ' x', i5, ' matrix, type=', i2, ', s',
     $                  'eed=', 3( i4, ',' ), i4, ': result ', i3,
     $                  ' is', 0p, f8.2 )
               ELSE
                  WRITE( iounit, fmt = 9996 )m, n, imat, iseed, k,
     $               result( k )
 9996             format( 1x, i5, ' x', i5, ' matrix, type=', i2, ', s',
     $                  'eed=', 3( i4, ',' ), i4, ': result ', i3,
     $                  ' is', 1p, d10.3 )
               END IF
            END IF
   20    continue
*
      END IF
      return
*
*     End of DLAFTS
*
      END