clarnd.f

Go to the documentation of this file.

*> \brief \b CLARND
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       COMPLEX FUNCTION CLARND( IDIST, ISEED )
* 
*       .. Scalar Arguments ..
*       INTEGER            IDIST
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLARND returns a random complex number from a uniform or normal
*> distribution.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] IDIST
*> \verbatim
*>          IDIST is INTEGER
*>          Specifies the distribution of the random numbers:
*>          = 1:  real and imaginary parts each uniform (0,1)
*>          = 2:  real and imaginary parts each uniform (-1,1)
*>          = 3:  real and imaginary parts each normal (0,1)
*>          = 4:  uniformly distributed on the disc abs(z) <= 1
*>          = 5:  uniformly distributed on the circle abs(z) = 1
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry, the seed of the random number generator; the array
*>          elements must be between 0 and 4095, and ISEED(4) must be
*>          odd.
*>          On exit, the seed is updated.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_matgen
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  This routine calls the auxiliary routine SLARAN to generate a random
*>  real number from a uniform (0,1) distribution. The Box-Muller method
*>  is used to transform numbers from a uniform to a normal distribution.
*> \endverbatim
*>
*  =====================================================================
      COMPLEX FUNCTION clarnd( IDIST, ISEED )
*
*  -- LAPACK auxiliary routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            idist
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one, two
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
      REAL               twopi
      parameter( twopi = 6.2831853071795864769252867663e+0 )
*     ..
*     .. Local Scalars ..
      REAL               t1, t2
*     ..
*     .. External Functions ..
      REAL               slaran
      EXTERNAL           slaran
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, exp, log, sqrt
*     ..
*     .. Executable Statements ..
*
*     Generate a pair of real random numbers from a uniform (0,1)
*     distribution
*
      t1 = slaran( iseed )
      t2 = slaran( iseed )
*
      IF( idist.EQ.1 ) THEN
*
*        real and imaginary parts each uniform (0,1)
*
         clarnd = cmplx( t1, t2 )
      ELSE IF( idist.EQ.2 ) THEN
*
*        real and imaginary parts each uniform (-1,1)
*
         clarnd = cmplx( two*t1-one, two*t2-one )
      ELSE IF( idist.EQ.3 ) THEN
*
*        real and imaginary parts each normal (0,1)
*
         clarnd = sqrt( -two*log( t1 ) )*exp( cmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.4 ) THEN
*
*        uniform distribution on the unit disc abs(z) <= 1
*
         clarnd = sqrt( t1 )*exp( cmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.5 ) THEN
*
*        uniform distribution on the unit circle abs(z) = 1
*
         clarnd = exp( cmplx( zero, twopi*t2 ) )
      END IF
      return
*
*     End of CLARND
*
      END