slaed5.f

Go to the documentation of this file.

*> \brief \b SLAED5 used by sstedc. Solves the 2-by-2 secular equation.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download SLAED5 + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slaed5.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slaed5.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slaed5.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAED5( I, D, Z, DELTA, RHO, DLAM )
* 
*       .. Scalar Arguments ..
*       INTEGER            I
*       REAL               DLAM, RHO
*       ..
*       .. Array Arguments ..
*       REAL               D( 2 ), DELTA( 2 ), Z( 2 )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> This subroutine computes the I-th eigenvalue of a symmetric rank-one
*> modification of a 2-by-2 diagonal matrix
*>
*>            diag( D )  +  RHO * Z * transpose(Z) .
*>
*> The diagonal elements in the array D are assumed to satisfy
*>
*>            D(i) < D(j)  for  i < j .
*>
*> We also assume RHO > 0 and that the Euclidean norm of the vector
*> Z is one.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] I
*> \verbatim
*>          I is INTEGER
*>         The index of the eigenvalue to be computed.  I = 1 or I = 2.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (2)
*>         The original eigenvalues.  We assume D(1) < D(2).
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is REAL array, dimension (2)
*>         The components of the updating vector.
*> \endverbatim
*>
*> \param[out] DELTA
*> \verbatim
*>          DELTA is REAL array, dimension (2)
*>         The vector DELTA contains the information necessary
*>         to construct the eigenvectors.
*> \endverbatim
*>
*> \param[in] RHO
*> \verbatim
*>          RHO is REAL
*>         The scalar in the symmetric updating formula.
*> \endverbatim
*>
*> \param[out] DLAM
*> \verbatim
*>          DLAM is REAL
*>         The computed lambda_I, the I-th updated eigenvalue.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup auxOTHERcomputational
*
*> \par Contributors:
*  ==================
*>
*>     Ren-Cang Li, Computer Science Division, University of California
*>     at Berkeley, USA
*>
*  =====================================================================
      SUBROUTINE slaed5( I, D, Z, DELTA, RHO, DLAM )
*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            i
      REAL               dlam, rho
*     ..
*     .. Array Arguments ..
      REAL               d( 2 ), delta( 2 ), z( 2 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one, two, four
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0,
     $                   four = 4.0e0 )
*     ..
*     .. Local Scalars ..
      REAL               b, c, del, tau, temp, w
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      del = d( 2 ) - d( 1 )
      IF( i.EQ.1 ) THEN
         w = one + two*rho*( z( 2 )*z( 2 )-z( 1 )*z( 1 ) ) / del
         IF( w.GT.zero ) THEN
            b = del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 1 )*z( 1 )*del
*
*           B > ZERO, always
*
            tau = two*c / ( b+sqrt( abs( b*b-four*c ) ) )
            dlam = d( 1 ) + tau
            delta( 1 ) = -z( 1 ) / tau
            delta( 2 ) = z( 2 ) / ( del-tau )
         ELSE
            b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 2 )*z( 2 )*del
            IF( b.GT.zero ) THEN
               tau = -two*c / ( b+sqrt( b*b+four*c ) )
            ELSE
               tau = ( b-sqrt( b*b+four*c ) ) / two
            END IF
            dlam = d( 2 ) + tau
            delta( 1 ) = -z( 1 ) / ( del+tau )
            delta( 2 ) = -z( 2 ) / tau
         END IF
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      ELSE
*
*     Now I=2
*
         b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
         c = rho*z( 2 )*z( 2 )*del
         IF( b.GT.zero ) THEN
            tau = ( b+sqrt( b*b+four*c ) ) / two
         ELSE
            tau = two*c / ( -b+sqrt( b*b+four*c ) )
         END IF
         dlam = d( 2 ) + tau
         delta( 1 ) = -z( 1 ) / ( del+tau )
         delta( 2 ) = -z( 2 ) / tau
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      END IF
      return
*
*     End OF SLAED5
*
      END