zgeqpf.f

Go to the documentation of this file.

*> \brief \b ZGEQPF
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download ZGEQPF + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgeqpf.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgeqpf.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgeqpf.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGEQPF( M, N, A, LDA, JPVT, TAU, WORK, RWORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, M, N
*       ..
*       .. Array Arguments ..
*       INTEGER            JPVT( * )
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> This routine is deprecated and has been replaced by routine ZGEQP3.
*>
*> ZGEQPF computes a QR factorization with column pivoting of a
*> complex M-by-N matrix A: A*P = Q*R.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A. M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A. N >= 0
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit, the upper triangle of the array contains the
*>          min(M,N)-by-N upper triangular matrix R; the elements
*>          below the diagonal, together with the array TAU,
*>          represent the unitary matrix Q as a product of
*>          min(m,n) elementary reflectors.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] JPVT
*> \verbatim
*>          JPVT is INTEGER array, dimension (N)
*>          On entry, if JPVT(i) .ne. 0, the i-th column of A is permuted
*>          to the front of A*P (a leading column); if JPVT(i) = 0,
*>          the i-th column of A is a free column.
*>          On exit, if JPVT(i) = k, then the i-th column of A*P
*>          was the k-th column of A.
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is COMPLEX*16 array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (N)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16GEcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The matrix Q is represented as a product of elementary reflectors
*>
*>     Q = H(1) H(2) . . . H(n)
*>
*>  Each H(i) has the form
*>
*>     H = I - tau * v * v**H
*>
*>  where tau is a complex scalar, and v is a complex vector with
*>  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i).
*>
*>  The matrix P is represented in jpvt as follows: If
*>     jpvt(j) = i
*>  then the jth column of P is the ith canonical unit vector.
*>
*>  Partial column norm updating strategy modified by
*>    Z. Drmac and Z. Bujanovic, Dept. of Mathematics,
*>    University of Zagreb, Croatia.
*>  -- April 2011                                                      --
*>  For more details see LAPACK Working Note 176.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE zgeqpf( M, N, A, LDA, JPVT, TAU, WORK, RWORK, INFO )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, m, n
*     ..
*     .. Array Arguments ..
      INTEGER            jpvt( * )
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( lda, * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, itemp, j, ma, mn, pvt
      DOUBLE PRECISION   temp, temp2, tol3z
      COMPLEX*16         aii
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgeqr2, zlarf, zlarfg, zswap, zunm2r
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dcmplx, dconjg, max, min, sqrt
*     ..
*     .. External Functions ..
      INTEGER            idamax
      DOUBLE PRECISION   dlamch, dznrm2
      EXTERNAL           idamax, dlamch, dznrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGEQPF', -info )
         return
      END IF
*
      mn = min( m, n )
      tol3z = sqrt(dlamch('Epsilon'))
*
*     Move initial columns up front
*
      itemp = 1
      DO 10 i = 1, n
         IF( jpvt( i ).NE.0 ) THEN
            IF( i.NE.itemp ) THEN
               CALL zswap( m, a( 1, i ), 1, a( 1, itemp ), 1 )
               jpvt( i ) = jpvt( itemp )
               jpvt( itemp ) = i
            ELSE
               jpvt( i ) = i
            END IF
            itemp = itemp + 1
         ELSE
            jpvt( i ) = i
         END IF
   10 continue
      itemp = itemp - 1
*
*     Compute the QR factorization and update remaining columns
*
      IF( itemp.GT.0 ) THEN
         ma = min( itemp, m )
         CALL zgeqr2( m, ma, a, lda, tau, work, info )
         IF( ma.LT.n ) THEN
            CALL zunm2r( 'Left', 'Conjugate transpose', m, n-ma, ma, a,
     $                   lda, tau, a( 1, ma+1 ), lda, work, info )
         END IF
      END IF
*
      IF( itemp.LT.mn ) THEN
*
*        Initialize partial column norms. The first n elements of
*        work store the exact column norms.
*
         DO 20 i = itemp + 1, n
            rwork( i ) = dznrm2( m-itemp, a( itemp+1, i ), 1 )
            rwork( n+i ) = rwork( i )
   20    continue
*
*        Compute factorization
*
         DO 40 i = itemp + 1, mn
*
*           Determine ith pivot column and swap if necessary
*
            pvt = ( i-1 ) + idamax( n-i+1, rwork( i ), 1 )
*
            IF( pvt.NE.i ) THEN
               CALL zswap( m, a( 1, pvt ), 1, a( 1, i ), 1 )
               itemp = jpvt( pvt )
               jpvt( pvt ) = jpvt( i )
               jpvt( i ) = itemp
               rwork( pvt ) = rwork( i )
               rwork( n+pvt ) = rwork( n+i )
            END IF
*
*           Generate elementary reflector H(i)
*
            aii = a( i, i )
            CALL zlarfg( m-i+1, aii, a( min( i+1, m ), i ), 1,
     $                   tau( i ) )
            a( i, i ) = aii
*
            IF( i.LT.n ) THEN
*
*              Apply H(i) to A(i:m,i+1:n) from the left
*
               aii = a( i, i )
               a( i, i ) = dcmplx( one )
               CALL zlarf( 'Left', m-i+1, n-i, a( i, i ), 1,
     $                     dconjg( tau( i ) ), a( i, i+1 ), lda, work )
               a( i, i ) = aii
            END IF
*
*           Update partial column norms
*
            DO 30 j = i + 1, n
               IF( rwork( j ).NE.zero ) THEN
*
*                 NOTE: The following 4 lines follow from the analysis in
*                 Lapack Working Note 176.
*                 
                  temp = abs( a( i, j ) ) / rwork( j )
                  temp = max( zero, ( one+temp )*( one-temp ) )
                  temp2 = temp*( rwork( j ) / rwork( n+j ) )**2
                  IF( temp2 .LE. tol3z ) THEN 
                     IF( m-i.GT.0 ) THEN
                        rwork( j ) = dznrm2( m-i, a( i+1, j ), 1 )
                        rwork( n+j ) = rwork( j )
                     ELSE
                        rwork( j ) = zero
                        rwork( n+j ) = zero
                     END IF
                  ELSE
                     rwork( j ) = rwork( j )*sqrt( temp )
                  END IF
               END IF
   30       continue
*
   40    continue
      END IF
      return
*
*     End of ZGEQPF
*
      END