dqrt05.f

Go to the documentation of this file.

*> \brief \b DQRT05
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DQRT05(M,N,L,NB,RESULT)
* 
*       .. Scalar Arguments ..
*       INTEGER LWORK, M, N, L, NB, LDT
*       .. Return values ..
*       DOUBLE PRECISION RESULT(6)
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DQRT05 tests DTPQRT and DTPMQRT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in lower part of the test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*>          L is INTEGER
*>          The number of rows of the upper trapezoidal part the
*>          lower test matrix.  0 <= L <= M.
*> \endverbatim
*>          
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= N.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R |
*>          RESULT(2) = | I - Q^H Q |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q | 
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date April 2012
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dqrt05(M,N,L,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine (version 3.4.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     April 2012
*
*     .. Scalar Arguments ..
      INTEGER lwork, m, n, l, nb, ldt
*     .. Return values ..
      DOUBLE PRECISION result(6)
*
*  =====================================================================
*      
*     ..
*     .. Local allocatable arrays 
      DOUBLE PRECISION, ALLOCATABLE :: af(:,:), q(:,:),
     $  r(:,:), rwork(:), work( : ), t(:,:), 
     $  cf(:,:), df(:,:), a(:,:), c(:,:), d(:,:)
*
*     .. Parameters ..
      DOUBLE PRECISION one, zero
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      INTEGER info, j, k, m2, np1
      DOUBLE PRECISION   anorm, eps, resid, cnorm, dnorm
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION dlamch, dlange, dlansy
      LOGICAL  lsame
      EXTERNAL dlamch, dlange, dlansy, lsame
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*      
      eps = dlamch( 'Epsilon' )
      k = n
      m2 = m+n
      IF( m.GT.0 ) THEN
         np1 = n+1
      ELSE
         np1 = 1
      END IF
      lwork = m2*m2*nb
*
*     Dynamically allocate all arrays
*
      ALLOCATE(a(m2,n),af(m2,n),q(m2,m2),r(m2,m2),rwork(m2),
     $           work(lwork),t(nb,n),c(m2,n),cf(m2,n), 
     $           d(n,m2),df(n,m2) )
*
*     Put random stuff into A
*
      ldt=nb
      CALL dlaset( 'Full', m2, n, zero, zero, a, m2 )
      CALL dlaset( 'Full', nb, n, zero, zero, t, nb )
      DO j=1,n
         CALL dlarnv( 2, iseed, j, a( 1, j ) )
      END DO
      IF( m.GT.0 ) THEN
         DO j=1,n
            CALL dlarnv( 2, iseed, m-l, a( min(n+m,n+1), j ) )
         END DO
      END IF
      IF( l.GT.0 ) THEN
         DO j=1,n
            CALL dlarnv( 2, iseed, min(j,l), a( min(n+m,n+m-l+1), j ) )
         END DO
      END IF
*
*     Copy the matrix A to the array AF.
*
      CALL dlacpy( 'Full', m2, n, a, m2, af, m2 )
*
*     Factor the matrix A in the array AF.
*
      CALL dtpqrt( m,n,l,nb,af,m2,af(np1,1),m2,t,ldt,work,info)
*
*     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
*
      CALL dlaset( 'Full', m2, m2, zero, one, q, m2 )
      CALL dgemqrt( 'R', 'N', m2, m2, k, nb, af, m2, t, ldt, q, m2,
     $              work, info )
*
*     Copy R
*
      CALL dlaset( 'Full', m2, n, zero, zero, r, m2 )
      CALL dlacpy( 'Upper', m2, n, af, m2, r, m2 )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL dgemm( 'T', 'N', m2, n, m2, -one, q, m2, a, m2, one, r, m2 )
      anorm = dlange( '1', m2, n, a, m2, rwork )
      resid = dlange( '1', m2, n, r, m2, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*anorm*max(1,m2))
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL dlaset( 'Full', m2, m2, zero, one, r, m2 )
      CALL dsyrk( 'U', 'C', m2, m2, -one, q, m2, one, r, m2 )
      resid = dlansy( '1', 'Upper', m2, r, m2, rwork )
      result( 2 ) = resid / (eps*max(1,m2))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL dlarnv( 2, iseed, m2, c( 1, j ) )
      END DO
      cnorm = dlange( '1', m2, n, c, m2, rwork)
      CALL dlacpy( 'Full', m2, n, c, m2, cf, m2 )
*
*     Apply Q to C as Q*C
*
      CALL dtpmqrt( 'L','N', m,n,k,l,nb,af(np1,1),m2,t,ldt,cf,m2,
     $               cf(np1,1),m2,work,info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL dgemm( 'N', 'N', m2, n, m2, -one, q, m2, c, m2, one, cf, m2 )
      resid = dlange( '1', m2, n, cf, m2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m2)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL dlacpy( 'Full', m2, n, c, m2, cf, m2 )
*
*     Apply Q to C as QT*C
*
      CALL dtpmqrt( 'L','T',m,n,k,l,nb,af(np1,1),m2,t,ldt,cf,m2,
     $              cf(np1,1),m2,work,info) 
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL dgemm('T','N',m2,n,m2,-one,q,m2,c,m2,one,cf,m2)
      resid = dlange( '1', m2, n, cf, m2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m2)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF     
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m2
         CALL dlarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = dlange( '1', n, m2, d, n, rwork)
      CALL dlacpy( 'Full', n, m2, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      CALL dtpmqrt('R','N',n,m,n,l,nb,af(np1,1),m2,t,ldt,df,n,
     $             df(1,np1),n,work,info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL dgemm('N','N',n,m2,m2,-one,d,n,q,m2,one,df,n)
      resid = dlange('1',n, m2,df,n,rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL dlacpy('Full',n,m2,d,n,df,n )
*
*     Apply Q to D as D*QT
*
      CALL dtpmqrt('R','T',n,m,n,l,nb,af(np1,1),m2,t,ldt,df,n,
     $             df(1,np1),n,work,info)     
       
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL dgemm( 'N', 'T', n, m2, m2, -one, d, n, q, m2, one, df, n )
      resid = dlange( '1', n, m2, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
      return
      END