schkgl.f

Go to the documentation of this file.

*> \brief \b SCHKGL
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKGL( NIN, NOUT )
* 
*       .. Scalar Arguments ..
*       INTEGER            NIN, NOUT
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKGL tests SGGBAL, a routine for balancing a matrix pair (A, B).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NIN
*> \verbatim
*>          NIN is INTEGER
*>          The logical unit number for input.  NIN > 0.
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The logical unit number for output.  NOUT > 0.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE schkgl( NIN, NOUT )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            nin, nout
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            lda, ldb, lwork
      parameter( lda = 20, ldb = 20, lwork = 6*lda )
      REAL               zero
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ihi, ihiin, ilo, iloin, info, j, knt, n,
     $                   ninfo
      REAL               anorm, bnorm, eps, rmax, vmax
*     ..
*     .. Local Arrays ..
      INTEGER            lmax( 5 )
      REAL               a( lda, lda ), ain( lda, lda ), b( ldb, ldb ),
     $                   bin( ldb, ldb ), lscale( lda ), lsclin( lda ),
     $                   rscale( lda ), rsclin( lda ), work( lwork )
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sggbal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
*
      eps = slamch( 'Precision' )
*
   10 continue
*
      READ( nin, fmt = * )n
      IF( n.EQ.0 )
     $   go to 90
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 continue
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( b( i, j ), j = 1, n )
   30 continue
*
      READ( nin, fmt = * )iloin, ihiin
      DO 40 i = 1, n
         READ( nin, fmt = * )( ain( i, j ), j = 1, n )
   40 continue
      DO 50 i = 1, n
         READ( nin, fmt = * )( bin( i, j ), j = 1, n )
   50 continue
*
      READ( nin, fmt = * )( lsclin( i ), i = 1, n )
      READ( nin, fmt = * )( rsclin( i ), i = 1, n )
*
      anorm = slange( 'M', n, n, a, lda, work )
      bnorm = slange( 'M', n, n, b, ldb, work )
*
      knt = knt + 1
*
      CALL sggbal( 'B', n, a, lda, b, ldb, ilo, ihi, lscale, rscale,
     $             work, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      IF( ilo.NE.iloin .OR. ihi.NE.ihiin ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      vmax = zero
      DO 70 i = 1, n
         DO 60 j = 1, n
            vmax = max( vmax, abs( a( i, j )-ain( i, j ) ) )
            vmax = max( vmax, abs( b( i, j )-bin( i, j ) ) )
   60    continue
   70 continue
*
      DO 80 i = 1, n
         vmax = max( vmax, abs( lscale( i )-lsclin( i ) ) )
         vmax = max( vmax, abs( rscale( i )-rsclin( i ) ) )
   80 continue
*
      vmax = vmax / ( eps*max( anorm, bnorm ) )
*
      IF( vmax.GT.rmax ) THEN
         lmax( 3 ) = knt
         rmax = vmax
      END IF
*
      go to 10
*
   90 continue
*
      WRITE( nout, fmt = 9999 )
 9999 format( 1x, '.. test output of SGGBAL .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 format( 1x, 'value of largest test error            = ', e12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 format( 1x, 'example number where info is not zero  = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 format( 1x, 'example number where ILO or IHI wrong  = ', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 format( 1x, 'example number having largest error    = ', i4 )
      WRITE( nout, fmt = 9994 )ninfo
 9994 format( 1x, 'number of examples where info is not 0 = ', i4 )
      WRITE( nout, fmt = 9993 )knt
 9993 format( 1x, 'total number of examples tested        = ', i4 )
*
      return
*
*     End of SCHKGL
*
      END