dppt03.f

Go to the documentation of this file.

*> \brief \b DPPT03
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DPPT03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
*                          RESID )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            LDWORK, N
*       DOUBLE PRECISION   RCOND, RESID
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( * ), AINV( * ), RWORK( * ),
*      $                   WORK( LDWORK, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DPPT03 computes the residual for a symmetric packed matrix times its
*> inverse:
*>    norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
*> where EPS is the machine epsilon.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (N*(N+1)/2)
*>          The original symmetric matrix A, stored as a packed
*>          triangular matrix.
*> \endverbatim
*>
*> \param[in] AINV
*> \verbatim
*>          AINV is DOUBLE PRECISION array, dimension (N*(N+1)/2)
*>          The (symmetric) inverse of the matrix A, stored as a packed
*>          triangular matrix.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LDWORK,N)
*> \endverbatim
*>
*> \param[in] LDWORK
*> \verbatim
*>          LDWORK is INTEGER
*>          The leading dimension of the array WORK.  LDWORK >= max(1,N).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] RCOND
*> \verbatim
*>          RCOND is DOUBLE PRECISION
*>          The reciprocal of the condition number of A, computed as
*>          ( 1/norm(A) ) / norm(AINV).
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is DOUBLE PRECISION
*>          norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dppt03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
     $                   resid )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldwork, n
      DOUBLE PRECISION   rcond, resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( * ), ainv( * ), rwork( * ),
     $                   work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, jj
      DOUBLE PRECISION   ainvnm, anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, dlange, dlansp
      EXTERNAL           lsame, dlamch, dlange, dlansp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dspmv
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         return
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlansp( '1', uplo, n, a, rwork )
      ainvnm = dlansp( '1', uplo, n, ainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.EQ.zero ) THEN
         rcond = zero
         resid = one / eps
         return
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     UPLO = 'U':
*     Copy the leading N-1 x N-1 submatrix of AINV to WORK(1:N,2:N) and
*     expand it to a full matrix, then multiply by A one column at a
*     time, moving the result one column to the left.
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Copy AINV
*
         jj = 1
         DO 10 j = 1, n - 1
            CALL dcopy( j, ainv( jj ), 1, work( 1, j+1 ), 1 )
            CALL dcopy( j-1, ainv( jj ), 1, work( j, 2 ), ldwork )
            jj = jj + j
   10    continue
         jj = ( ( n-1 )*n ) / 2 + 1
         CALL dcopy( n-1, ainv( jj ), 1, work( n, 2 ), ldwork )
*
*        Multiply by A
*
         DO 20 j = 1, n - 1
            CALL dspmv( 'Upper', n, -one, a, work( 1, j+1 ), 1, zero,
     $                  work( 1, j ), 1 )
   20    continue
         CALL dspmv( 'Upper', n, -one, a, ainv( jj ), 1, zero,
     $               work( 1, n ), 1 )
*
*     UPLO = 'L':
*     Copy the trailing N-1 x N-1 submatrix of AINV to WORK(1:N,1:N-1)
*     and multiply by A, moving each column to the right.
*
      ELSE
*
*        Copy AINV
*
         CALL dcopy( n-1, ainv( 2 ), 1, work( 1, 1 ), ldwork )
         jj = n + 1
         DO 30 j = 2, n
            CALL dcopy( n-j+1, ainv( jj ), 1, work( j, j-1 ), 1 )
            CALL dcopy( n-j, ainv( jj+1 ), 1, work( j, j ), ldwork )
            jj = jj + n - j + 1
   30    continue
*
*        Multiply by A
*
         DO 40 j = n, 2, -1
            CALL dspmv( 'Lower', n, -one, a, work( 1, j-1 ), 1, zero,
     $                  work( 1, j ), 1 )
   40    continue
         CALL dspmv( 'Lower', n, -one, a, ainv( 1 ), 1, zero,
     $               work( 1, 1 ), 1 )
*
      END IF
*
*     Add the identity matrix to WORK .
*
      DO 50 i = 1, n
         work( i, i ) = work( i, i ) + one
   50 continue
*
*     Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = dlange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / dble( n )
*
      return
*
*     End of DPPT03
*
      END