sqrt11.f

Go to the documentation of this file.

*> \brief \b SQRT11
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION SQRT11( M, K, A, LDA, TAU, WORK, LWORK )
* 
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LWORK, M
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SQRT11 computes the test ratio
*>
*>       || Q'*Q - I || / (eps * m)
*>
*> where the orthogonal matrix Q is represented as a product of
*> elementary transformations.  Each transformation has the form
*>
*>    H(k) = I - tau(k) v(k) v(k)'
*>
*> where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
*> [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
*> in A(k+1:m,k).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of columns of A whose subdiagonal entries
*>          contain information about orthogonal transformations.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,K)
*>          The (possibly partial) output of a QR reduction routine.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is REAL array, dimension (K)
*>          The scaling factors tau for the elementary transformations as
*>          computed by the QR factorization routine.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of the array WORK.  LWORK >= M*M + M.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_lin
*
*  =====================================================================
      REAL             FUNCTION sqrt11( M, K, A, LDA, TAU, WORK, LWORK )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, sorm2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Local Arrays ..
      REAL               rdummy( 1 )
*     ..
*     .. Executable Statements ..
*
      sqrt11 = zero
*
*     Test for sufficient workspace
*
      IF( lwork.LT.m*m+m ) THEN
         CALL xerbla( 'SQRT11', 7 )
         return
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   return
*
      CALL slaset( 'Full', m, m, zero, one, work, m )
*
*     Form Q
*
      CALL sorm2r( 'Left', 'No transpose', m, m, k, a, lda, tau, work,
     $             m, work( m*m+1 ), info )
*
*     Form Q'*Q
*
      CALL sorm2r( 'Left', 'Transpose', m, m, k, a, lda, tau, work, m,
     $             work( m*m+1 ), info )
*
      DO 10 j = 1, m
         work( ( j-1 )*m+j ) = work( ( j-1 )*m+j ) - one
   10 continue
*
      sqrt11 = slange( 'One-norm', m, m, work, m, rdummy ) /
     $         ( REAL( m )*slamch( 'Epsilon' ) )
*
      return
*
*     End of SQRT11
*
      END