LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
dsytd2.f
Go to the documentation of this file.
1 *> \brief \b DSYTD2 reduces a symmetric matrix to real symmetric tridiagonal form by an orthogonal similarity transformation (unblocked algorithm).
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DSYTD2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsytd2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsytd2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsytd2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DSYTD2( UPLO, N, A, LDA, D, E, TAU, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER INFO, LDA, N
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION A( LDA, * ), D( * ), E( * ), TAU( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> DSYTD2 reduces a real symmetric matrix A to symmetric tridiagonal
38 *> form T by an orthogonal similarity transformation: Q**T * A * Q = T.
39 *> \endverbatim
40 *
41 * Arguments:
42 * ==========
43 *
44 *> \param[in] UPLO
45 *> \verbatim
46 *> UPLO is CHARACTER*1
47 *> Specifies whether the upper or lower triangular part of the
48 *> symmetric matrix A is stored:
49 *> = 'U': Upper triangular
50 *> = 'L': Lower triangular
51 *> \endverbatim
52 *>
53 *> \param[in] N
54 *> \verbatim
55 *> N is INTEGER
56 *> The order of the matrix A. N >= 0.
57 *> \endverbatim
58 *>
59 *> \param[in,out] A
60 *> \verbatim
61 *> A is DOUBLE PRECISION array, dimension (LDA,N)
62 *> On entry, the symmetric matrix A. If UPLO = 'U', the leading
63 *> n-by-n upper triangular part of A contains the upper
64 *> triangular part of the matrix A, and the strictly lower
65 *> triangular part of A is not referenced. If UPLO = 'L', the
66 *> leading n-by-n lower triangular part of A contains the lower
67 *> triangular part of the matrix A, and the strictly upper
68 *> triangular part of A is not referenced.
69 *> On exit, if UPLO = 'U', the diagonal and first superdiagonal
70 *> of A are overwritten by the corresponding elements of the
71 *> tridiagonal matrix T, and the elements above the first
72 *> superdiagonal, with the array TAU, represent the orthogonal
73 *> matrix Q as a product of elementary reflectors; if UPLO
74 *> = 'L', the diagonal and first subdiagonal of A are over-
75 *> written by the corresponding elements of the tridiagonal
76 *> matrix T, and the elements below the first subdiagonal, with
77 *> the array TAU, represent the orthogonal matrix Q as a product
78 *> of elementary reflectors. See Further Details.
79 *> \endverbatim
80 *>
81 *> \param[in] LDA
82 *> \verbatim
83 *> LDA is INTEGER
84 *> The leading dimension of the array A. LDA >= max(1,N).
85 *> \endverbatim
86 *>
87 *> \param[out] D
88 *> \verbatim
89 *> D is DOUBLE PRECISION array, dimension (N)
90 *> The diagonal elements of the tridiagonal matrix T:
91 *> D(i) = A(i,i).
92 *> \endverbatim
93 *>
94 *> \param[out] E
95 *> \verbatim
96 *> E is DOUBLE PRECISION array, dimension (N-1)
97 *> The off-diagonal elements of the tridiagonal matrix T:
98 *> E(i) = A(i,i+1) if UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'.
99 *> \endverbatim
100 *>
101 *> \param[out] TAU
102 *> \verbatim
103 *> TAU is DOUBLE PRECISION array, dimension (N-1)
104 *> The scalar factors of the elementary reflectors (see Further
105 *> Details).
106 *> \endverbatim
107 *>
108 *> \param[out] INFO
109 *> \verbatim
110 *> INFO is INTEGER
111 *> = 0: successful exit
112 *> < 0: if INFO = -i, the i-th argument had an illegal value.
113 *> \endverbatim
114 *
115 * Authors:
116 * ========
117 *
118 *> \author Univ. of Tennessee
119 *> \author Univ. of California Berkeley
120 *> \author Univ. of Colorado Denver
121 *> \author NAG Ltd.
122 *
123 *> \date September 2012
124 *
125 *> \ingroup doubleSYcomputational
126 *
127 *> \par Further Details:
128 * =====================
129 *>
130 *> \verbatim
131 *>
132 *> If UPLO = 'U', the matrix Q is represented as a product of elementary
133 *> reflectors
134 *>
135 *> Q = H(n-1) . . . H(2) H(1).
136 *>
137 *> Each H(i) has the form
138 *>
139 *> H(i) = I - tau * v * v**T
140 *>
141 *> where tau is a real scalar, and v is a real vector with
142 *> v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
143 *> A(1:i-1,i+1), and tau in TAU(i).
144 *>
145 *> If UPLO = 'L', the matrix Q is represented as a product of elementary
146 *> reflectors
147 *>
148 *> Q = H(1) H(2) . . . H(n-1).
149 *>
150 *> Each H(i) has the form
151 *>
152 *> H(i) = I - tau * v * v**T
153 *>
154 *> where tau is a real scalar, and v is a real vector with
155 *> v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in A(i+2:n,i),
156 *> and tau in TAU(i).
157 *>
158 *> The contents of A on exit are illustrated by the following examples
159 *> with n = 5:
160 *>
161 *> if UPLO = 'U': if UPLO = 'L':
162 *>
163 *> ( d e v2 v3 v4 ) ( d )
164 *> ( d e v3 v4 ) ( e d )
165 *> ( d e v4 ) ( v1 e d )
166 *> ( d e ) ( v1 v2 e d )
167 *> ( d ) ( v1 v2 v3 e d )
168 *>
169 *> where d and e denote diagonal and off-diagonal elements of T, and vi
170 *> denotes an element of the vector defining H(i).
171 *> \endverbatim
172 *>
173 * =====================================================================
174  SUBROUTINE dsytd2( UPLO, N, A, LDA, D, E, TAU, INFO )
175 *
176 * -- LAPACK computational routine (version 3.4.2) --
177 * -- LAPACK is a software package provided by Univ. of Tennessee, --
178 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
179 * September 2012
180 *
181 * .. Scalar Arguments ..
182  CHARACTER uplo
183  INTEGER info, lda, n
184 * ..
185 * .. Array Arguments ..
186  DOUBLE PRECISION a( lda, * ), d( * ), e( * ), tau( * )
187 * ..
188 *
189 * =====================================================================
190 *
191 * .. Parameters ..
192  DOUBLE PRECISION one, zero, half
193  parameter( one = 1.0d0, zero = 0.0d0,
194  $ half = 1.0d0 / 2.0d0 )
195 * ..
196 * .. Local Scalars ..
197  LOGICAL upper
198  INTEGER i
199  DOUBLE PRECISION alpha, taui
200 * ..
201 * .. External Subroutines ..
202  EXTERNAL daxpy, dlarfg, dsymv, dsyr2, xerbla
203 * ..
204 * .. External Functions ..
205  LOGICAL lsame
206  DOUBLE PRECISION ddot
207  EXTERNAL lsame, ddot
208 * ..
209 * .. Intrinsic Functions ..
210  INTRINSIC max, min
211 * ..
212 * .. Executable Statements ..
213 *
214 * Test the input parameters
215 *
216  info = 0
217  upper = lsame( uplo, 'U' )
218  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
219  info = -1
220  ELSE IF( n.LT.0 ) THEN
221  info = -2
222  ELSE IF( lda.LT.max( 1, n ) ) THEN
223  info = -4
224  END IF
225  IF( info.NE.0 ) THEN
226  CALL xerbla( 'DSYTD2', -info )
227  return
228  END IF
229 *
230 * Quick return if possible
231 *
232  IF( n.LE.0 )
233  $ return
234 *
235  IF( upper ) THEN
236 *
237 * Reduce the upper triangle of A
238 *
239  DO 10 i = n - 1, 1, -1
240 *
241 * Generate elementary reflector H(i) = I - tau * v * v**T
242 * to annihilate A(1:i-1,i+1)
243 *
244  CALL dlarfg( i, a( i, i+1 ), a( 1, i+1 ), 1, taui )
245  e( i ) = a( i, i+1 )
246 *
247  IF( taui.NE.zero ) THEN
248 *
249 * Apply H(i) from both sides to A(1:i,1:i)
250 *
251  a( i, i+1 ) = one
252 *
253 * Compute x := tau * A * v storing x in TAU(1:i)
254 *
255  CALL dsymv( uplo, i, taui, a, lda, a( 1, i+1 ), 1, zero,
256  $ tau, 1 )
257 *
258 * Compute w := x - 1/2 * tau * (x**T * v) * v
259 *
260  alpha = -half*taui*ddot( i, tau, 1, a( 1, i+1 ), 1 )
261  CALL daxpy( i, alpha, a( 1, i+1 ), 1, tau, 1 )
262 *
263 * Apply the transformation as a rank-2 update:
264 * A := A - v * w**T - w * v**T
265 *
266  CALL dsyr2( uplo, i, -one, a( 1, i+1 ), 1, tau, 1, a,
267  $ lda )
268 *
269  a( i, i+1 ) = e( i )
270  END IF
271  d( i+1 ) = a( i+1, i+1 )
272  tau( i ) = taui
273  10 continue
274  d( 1 ) = a( 1, 1 )
275  ELSE
276 *
277 * Reduce the lower triangle of A
278 *
279  DO 20 i = 1, n - 1
280 *
281 * Generate elementary reflector H(i) = I - tau * v * v**T
282 * to annihilate A(i+2:n,i)
283 *
284  CALL dlarfg( n-i, a( i+1, i ), a( min( i+2, n ), i ), 1,
285  $ taui )
286  e( i ) = a( i+1, i )
287 *
288  IF( taui.NE.zero ) THEN
289 *
290 * Apply H(i) from both sides to A(i+1:n,i+1:n)
291 *
292  a( i+1, i ) = one
293 *
294 * Compute x := tau * A * v storing y in TAU(i:n-1)
295 *
296  CALL dsymv( uplo, n-i, taui, a( i+1, i+1 ), lda,
297  $ a( i+1, i ), 1, zero, tau( i ), 1 )
298 *
299 * Compute w := x - 1/2 * tau * (x**T * v) * v
300 *
301  alpha = -half*taui*ddot( n-i, tau( i ), 1, a( i+1, i ),
302  $ 1 )
303  CALL daxpy( n-i, alpha, a( i+1, i ), 1, tau( i ), 1 )
304 *
305 * Apply the transformation as a rank-2 update:
306 * A := A - v * w**T - w * v**T
307 *
308  CALL dsyr2( uplo, n-i, -one, a( i+1, i ), 1, tau( i ), 1,
309  $ a( i+1, i+1 ), lda )
310 *
311  a( i+1, i ) = e( i )
312  END IF
313  d( i ) = a( i, i )
314  tau( i ) = taui
315  20 continue
316  d( n ) = a( n, n )
317  END IF
318 *
319  return
320 *
321 * End of DSYTD2
322 *
323  END