dla_syrpvgrw.f

Go to the documentation of this file.

*> \brief \b DLA_SYRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a symmetric indefinite matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download DLA_SYRPVGRW + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dla_syrpvgrw.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dla_syrpvgrw.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dla_syrpvgrw.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION DLA_SYRPVGRW( UPLO, N, INFO, A, LDA, AF,
*                                               LDAF, IPIV, WORK )
* 
*       .. Scalar Arguments ..
*       CHARACTER*1        UPLO
*       INTEGER            N, INFO, LDA, LDAF
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> 
*> DLA_SYRPVGRW computes the reciprocal pivot growth factor
*> norm(A)/norm(U). The "max absolute element" norm is used. If this is
*> much less than 1, the stability of the LU factorization of the
*> (equilibrated) matrix A could be poor. This also means that the
*> solution X, estimated condition numbers, and error bounds could be
*> unreliable.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>       = 'U':  Upper triangle of A is stored;
*>       = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>     The number of linear equations, i.e., the order of the
*>     matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] INFO
*> \verbatim
*>          INFO is INTEGER
*>     The value of INFO returned from DSYTRF, .i.e., the pivot in
*>     column INFO is exactly 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>     On entry, the N-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>     The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is DOUBLE PRECISION array, dimension (LDAF,N)
*>     The block diagonal matrix D and the multipliers used to
*>     obtain the factor U or L as computed by DSYTRF.
*> \endverbatim
*>
*> \param[in] LDAF
*> \verbatim
*>          LDAF is INTEGER
*>     The leading dimension of the array AF.  LDAF >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>     Details of the interchanges and the block structure of D
*>     as determined by DSYTRF.
*> \endverbatim
*>
*> \param[in] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (2*N)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup doubleSYcomputational
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION dla_syrpvgrw( UPLO, N, INFO, A, LDA, AF,
     $                                        ldaf, ipiv, work )
*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER*1        uplo
      INTEGER            n, info, lda, ldaf
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      DOUBLE PRECISION   a( lda, * ), af( ldaf, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            ncols, i, j, k, kp
      DOUBLE PRECISION   amax, umax, rpvgrw, tmp
      LOGICAL            upper
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. External Functions ..
      EXTERNAL           lsame, dlaset
      LOGICAL            lsame
*     ..
*     .. Executable Statements ..
*
      upper = lsame( 'Upper', uplo )
      IF ( info.EQ.0 ) THEN
         IF ( upper ) THEN
            ncols = 1
         ELSE
            ncols = n
         END IF
      ELSE
         ncols = info
      END IF

      rpvgrw = 1.0d+0
      DO i = 1, 2*n
         work( i ) = 0.0d+0
      END DO
*
*     Find the max magnitude entry of each column of A.  Compute the max
*     for all N columns so we can apply the pivot permutation while
*     looping below.  Assume a full factorization is the common case.
*
      IF ( upper ) THEN
         DO j = 1, n
            DO i = 1, j
               work( n+i ) = max( abs( a( i, j ) ), work( n+i ) )
               work( n+j ) = max( abs( a( i, j ) ), work( n+j ) )
            END DO
         END DO
      ELSE
         DO j = 1, n
            DO i = j, n
               work( n+i ) = max( abs( a( i, j ) ), work( n+i ) )
               work( n+j ) = max( abs( a( i, j ) ), work( n+j ) )
            END DO
         END DO
      END IF
*
*     Now find the max magnitude entry of each column of U or L.  Also
*     permute the magnitudes of A above so they're in the same order as
*     the factor.
*
*     The iteration orders and permutations were copied from dsytrs.
*     Calls to SSWAP would be severe overkill.
*
      IF ( upper ) THEN
         k = n
         DO WHILE ( k .LT. ncols .AND. k.GT.0 )
            IF ( ipiv( k ).GT.0 ) THEN
!              1x1 pivot
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               DO i = 1, k
                  work( k ) = max( abs( af( i, k ) ), work( k ) )
               END DO
               k = k - 1
            ELSE
!              2x2 pivot
               kp = -ipiv( k )
               tmp = work( n+k-1 )
               work( n+k-1 ) = work( n+kp )
               work( n+kp ) = tmp
               DO i = 1, k-1
                  work( k ) = max( abs( af( i, k ) ), work( k ) )
                  work( k-1 ) = max( abs( af( i, k-1 ) ), work( k-1 ) )
               END DO
               work( k ) = max( abs( af( k, k ) ), work( k ) )
               k = k - 2
            END IF
         END DO
         k = ncols
         DO WHILE ( k .LE. n )
            IF ( ipiv( k ).GT.0 ) THEN
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               k = k + 1
            ELSE
               kp = -ipiv( k )
               tmp = work( n+k )
               work( n+k ) = work( n+kp )
               work( n+kp ) = tmp
               k = k + 2
            END IF
         END DO
      ELSE
         k = 1
         DO WHILE ( k .LE. ncols )
            IF ( ipiv( k ).GT.0 ) THEN
!              1x1 pivot
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               DO i = k, n
                  work( k ) = max( abs( af( i, k ) ), work( k ) )
               END DO
               k = k + 1
            ELSE
!              2x2 pivot
               kp = -ipiv( k )
               tmp = work( n+k+1 )
               work( n+k+1 ) = work( n+kp )
               work( n+kp ) = tmp
               DO i = k+1, n
                  work( k ) = max( abs( af( i, k ) ), work( k ) )
                  work( k+1 ) = max( abs( af(i, k+1 ) ), work( k+1 ) )
               END DO
               work( k ) = max( abs( af( k, k ) ), work( k ) )
               k = k + 2
            END IF
         END DO
         k = ncols
         DO WHILE ( k .GE. 1 )
            IF ( ipiv( k ).GT.0 ) THEN
               kp = ipiv( k )
               IF ( kp .NE. k ) THEN
                  tmp = work( n+k )
                  work( n+k ) = work( n+kp )
                  work( n+kp ) = tmp
               END IF
               k = k - 1
            ELSE
               kp = -ipiv( k )
               tmp = work( n+k )
               work( n+k ) = work( n+kp )
               work( n+kp ) = tmp
               k = k - 2
            ENDIF
         END DO
      END IF
*
*     Compute the *inverse* of the max element growth factor.  Dividing
*     by zero would imply the largest entry of the factor's column is
*     zero.  Than can happen when either the column of A is zero or
*     massive pivots made the factor underflow to zero.  Neither counts
*     as growth in itself, so simply ignore terms with zero
*     denominators.
*
      IF ( upper ) THEN
         DO i = ncols, n
            umax = work( i )
            amax = work( n+i )
            IF ( umax /= 0.0d+0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      ELSE
         DO i = 1, ncols
            umax = work( i )
            amax = work( n+i )
            IF ( umax /= 0.0d+0 ) THEN
               rpvgrw = min( amax / umax, rpvgrw )
            END IF
         END DO
      END IF

      dla_syrpvgrw = rpvgrw
      END