sget54.f

Go to the documentation of this file.

*> \brief \b SGET54
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SGET54( N, A, LDA, B, LDB, S, LDS, T, LDT, U, LDU, V,
*                          LDV, WORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LDS, LDT, LDU, LDV, N
*       REAL               RESULT
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), B( LDB, * ), S( LDS, * ),
*      $                   T( LDT, * ), U( LDU, * ), V( LDV, * ),
*      $                   WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SGET54 checks a generalized decomposition of the form
*>
*>          A = U*S*V'  and B = U*T* V'
*>
*> where ' means transpose and U and V are orthogonal.
*>
*> Specifically,
*>
*>  RESULT = ||( A - U*S*V', B - U*T*V' )|| / (||( A, B )||*n*ulp )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrix.  If it is zero, SGET54 does nothing.
*>          It must be at least zero.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA, N)
*>          The original (unfactored) matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is REAL array, dimension (LDB, N)
*>          The original (unfactored) matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of B.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] S
*> \verbatim
*>          S is REAL array, dimension (LDS, N)
*>          The factored matrix S.
*> \endverbatim
*>
*> \param[in] LDS
*> \verbatim
*>          LDS is INTEGER
*>          The leading dimension of S.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] T
*> \verbatim
*>          T is REAL array, dimension (LDT, N)
*>          The factored matrix T.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of T.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is REAL array, dimension (LDU, N)
*>          The orthogonal matrix on the left-hand side in the
*>          decomposition.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U.  LDU must be at least N and
*>          at least 1.
*> \endverbatim
*>
*> \param[in] V
*> \verbatim
*>          V is REAL array, dimension (LDV, N)
*>          The orthogonal matrix on the left-hand side in the
*>          decomposition.
*> \endverbatim
*>
*> \param[in] LDV
*> \verbatim
*>          LDV is INTEGER
*>          The leading dimension of V.  LDV must be at least N and
*>          at least 1.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (3*N**2)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL
*>          The value RESULT, It is currently limited to 1/ulp, to
*>          avoid overflow. Errors are flagged by RESULT=10/ulp.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE sget54( N, A, LDA, B, LDB, S, LDS, T, LDT, U, LDU, V,
     $                   ldv, work, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldb, lds, ldt, ldu, ldv, n
      REAL               result
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), b( ldb, * ), s( lds, * ),
     $                   t( ldt, * ), u( ldu, * ), v( ldv, * ),
     $                   work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               abnorm, ulp, unfl, wnorm
*     ..
*     .. Local Arrays ..
      REAL               dum( 1 )
*     ..
*     .. External Functions ..
      REAL               slamch, slange
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      result = zero
      IF( n.LE.0 )
     $   return
*
*     Constants
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
*
*     compute the norm of (A,B)
*
      CALL slacpy( 'Full', n, n, a, lda, work, n )
      CALL slacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
      abnorm = max( slange( '1', n, 2*n, work, n, dum ), unfl )
*
*     Compute W1 = A - U*S*V', and put in the array WORK(1:N*N)
*
      CALL slacpy( ' ', n, n, a, lda, work, n )
      CALL sgemm( 'N', 'N', n, n, n, one, u, ldu, s, lds, zero,
     $            work( n*n+1 ), n )
*
      CALL sgemm( 'N', 'C', n, n, n, -one, work( n*n+1 ), n, v, ldv,
     $            one, work, n )
*
*     Compute W2 = B - U*T*V', and put in the workarray W(N*N+1:2*N*N)
*
      CALL slacpy( ' ', n, n, b, ldb, work( n*n+1 ), n )
      CALL sgemm( 'N', 'N', n, n, n, one, u, ldu, t, ldt, zero,
     $            work( 2*n*n+1 ), n )
*
      CALL sgemm( 'N', 'C', n, n, n, -one, work( 2*n*n+1 ), n, v, ldv,
     $            one, work( n*n+1 ), n )
*
*     Compute norm(W)/ ( ulp*norm((A,B)) )
*
      wnorm = slange( '1', n, 2*n, work, n, dum )
*
      IF( abnorm.GT.wnorm ) THEN
         result = ( wnorm / abnorm ) / ( 2*n*ulp )
      ELSE
         IF( abnorm.LT.one ) THEN
            result = ( min( wnorm, 2*n*abnorm ) / abnorm ) / ( 2*n*ulp )
         ELSE
            result = min( wnorm / abnorm, REAL( 2*N ) ) / ( 2*n*ulp )
         END IF
      END IF
*
      return
*
*     End of SGET54
*
      END