LAPACK 3.3.1
Linear Algebra PACKage

dqrt03.f

Go to the documentation of this file.
00001       SUBROUTINE DQRT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
00002      $                   RWORK, RESULT )
00003 *
00004 *  -- LAPACK test routine (version 3.1) --
00005 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            K, LDA, LWORK, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       DOUBLE PRECISION   AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
00013      $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
00014      $                   WORK( LWORK )
00015 *     ..
00016 *
00017 *  Purpose
00018 *  =======
00019 *
00020 *  DQRT03 tests DORMQR, which computes Q*C, Q'*C, C*Q or C*Q'.
00021 *
00022 *  DQRT03 compares the results of a call to DORMQR with the results of
00023 *  forming Q explicitly by a call to DORGQR and then performing matrix
00024 *  multiplication by a call to DGEMM.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The order of the orthogonal matrix Q.  M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of rows or columns of the matrix C; C is m-by-n if
00034 *          Q is applied from the left, or n-by-m if Q is applied from
00035 *          the right.  N >= 0.
00036 *
00037 *  K       (input) INTEGER
00038 *          The number of elementary reflectors whose product defines the
00039 *          orthogonal matrix Q.  M >= K >= 0.
00040 *
00041 *  AF      (input) DOUBLE PRECISION array, dimension (LDA,N)
00042 *          Details of the QR factorization of an m-by-n matrix, as
00043 *          returnedby DGEQRF. See SGEQRF for further details.
00044 *
00045 *  C       (workspace) DOUBLE PRECISION array, dimension (LDA,N)
00046 *
00047 *  CC      (workspace) DOUBLE PRECISION array, dimension (LDA,N)
00048 *
00049 *  Q       (workspace) DOUBLE PRECISION array, dimension (LDA,M)
00050 *
00051 *  LDA     (input) INTEGER
00052 *          The leading dimension of the arrays AF, C, CC, and Q.
00053 *
00054 *  TAU     (input) DOUBLE PRECISION array, dimension (min(M,N))
00055 *          The scalar factors of the elementary reflectors corresponding
00056 *          to the QR factorization in AF.
00057 *
00058 *  WORK    (workspace) DOUBLE PRECISION array, dimension (LWORK)
00059 *
00060 *  LWORK   (input) INTEGER
00061 *          The length of WORK.  LWORK must be at least M, and should be
00062 *          M*NB, where NB is the blocksize for this environment.
00063 *
00064 *  RWORK   (workspace) DOUBLE PRECISION array, dimension (M)
00065 *
00066 *  RESULT  (output) DOUBLE PRECISION array, dimension (4)
00067 *          The test ratios compare two techniques for multiplying a
00068 *          random matrix C by an m-by-m orthogonal matrix Q.
00069 *          RESULT(1) = norm( Q*C - Q*C )  / ( M * norm(C) * EPS )
00070 *          RESULT(2) = norm( C*Q - C*Q )  / ( M * norm(C) * EPS )
00071 *          RESULT(3) = norm( Q'*C - Q'*C )/ ( M * norm(C) * EPS )
00072 *          RESULT(4) = norm( C*Q' - C*Q' )/ ( M * norm(C) * EPS )
00073 *
00074 *  =====================================================================
00075 *
00076 *     .. Parameters ..
00077       DOUBLE PRECISION   ONE
00078       PARAMETER          ( ONE = 1.0D0 )
00079       DOUBLE PRECISION   ROGUE
00080       PARAMETER          ( ROGUE = -1.0D+10 )
00081 *     ..
00082 *     .. Local Scalars ..
00083       CHARACTER          SIDE, TRANS
00084       INTEGER            INFO, ISIDE, ITRANS, J, MC, NC
00085       DOUBLE PRECISION   CNORM, EPS, RESID
00086 *     ..
00087 *     .. External Functions ..
00088       LOGICAL            LSAME
00089       DOUBLE PRECISION   DLAMCH, DLANGE
00090       EXTERNAL           LSAME, DLAMCH, DLANGE
00091 *     ..
00092 *     .. External Subroutines ..
00093       EXTERNAL           DGEMM, DLACPY, DLARNV, DLASET, DORGQR, DORMQR
00094 *     ..
00095 *     .. Local Arrays ..
00096       INTEGER            ISEED( 4 )
00097 *     ..
00098 *     .. Intrinsic Functions ..
00099       INTRINSIC          DBLE, MAX
00100 *     ..
00101 *     .. Scalars in Common ..
00102       CHARACTER*32       SRNAMT
00103 *     ..
00104 *     .. Common blocks ..
00105       COMMON             / SRNAMC / SRNAMT
00106 *     ..
00107 *     .. Data statements ..
00108       DATA               ISEED / 1988, 1989, 1990, 1991 /
00109 *     ..
00110 *     .. Executable Statements ..
00111 *
00112       EPS = DLAMCH( 'Epsilon' )
00113 *
00114 *     Copy the first k columns of the factorization to the array Q
00115 *
00116       CALL DLASET( 'Full', M, M, ROGUE, ROGUE, Q, LDA )
00117       CALL DLACPY( 'Lower', M-1, K, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
00118 *
00119 *     Generate the m-by-m matrix Q
00120 *
00121       SRNAMT = 'DORGQR'
00122       CALL DORGQR( M, M, K, Q, LDA, TAU, WORK, LWORK, INFO )
00123 *
00124       DO 30 ISIDE = 1, 2
00125          IF( ISIDE.EQ.1 ) THEN
00126             SIDE = 'L'
00127             MC = M
00128             NC = N
00129          ELSE
00130             SIDE = 'R'
00131             MC = N
00132             NC = M
00133          END IF
00134 *
00135 *        Generate MC by NC matrix C
00136 *
00137          DO 10 J = 1, NC
00138             CALL DLARNV( 2, ISEED, MC, C( 1, J ) )
00139    10    CONTINUE
00140          CNORM = DLANGE( '1', MC, NC, C, LDA, RWORK )
00141          IF( CNORM.EQ.0.0D0 )
00142      $      CNORM = ONE
00143 *
00144          DO 20 ITRANS = 1, 2
00145             IF( ITRANS.EQ.1 ) THEN
00146                TRANS = 'N'
00147             ELSE
00148                TRANS = 'T'
00149             END IF
00150 *
00151 *           Copy C
00152 *
00153             CALL DLACPY( 'Full', MC, NC, C, LDA, CC, LDA )
00154 *
00155 *           Apply Q or Q' to C
00156 *
00157             SRNAMT = 'DORMQR'
00158             CALL DORMQR( SIDE, TRANS, MC, NC, K, AF, LDA, TAU, CC, LDA,
00159      $                   WORK, LWORK, INFO )
00160 *
00161 *           Form explicit product and subtract
00162 *
00163             IF( LSAME( SIDE, 'L' ) ) THEN
00164                CALL DGEMM( TRANS, 'No transpose', MC, NC, MC, -ONE, Q,
00165      $                     LDA, C, LDA, ONE, CC, LDA )
00166             ELSE
00167                CALL DGEMM( 'No transpose', TRANS, MC, NC, NC, -ONE, C,
00168      $                     LDA, Q, LDA, ONE, CC, LDA )
00169             END IF
00170 *
00171 *           Compute error in the difference
00172 *
00173             RESID = DLANGE( '1', MC, NC, CC, LDA, RWORK )
00174             RESULT( ( ISIDE-1 )*2+ITRANS ) = RESID /
00175      $         ( DBLE( MAX( 1, M ) )*CNORM*EPS )
00176 *
00177    20    CONTINUE
00178    30 CONTINUE
00179 *
00180       RETURN
00181 *
00182 *     End of DQRT03
00183 *
00184       END
 All Files Functions