LAPACK 3.3.1
Linear Algebra PACKage

sormql.f

Go to the documentation of this file.
00001       SUBROUTINE SORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
00002      $                   WORK, LWORK, INFO )
00003 *
00004 *  -- LAPACK routine (version 3.3.1) --
00005 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00006 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00007 *  -- April 2011                                                      --
00008 *
00009 *     .. Scalar Arguments ..
00010       CHARACTER          SIDE, TRANS
00011       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
00012 *     ..
00013 *     .. Array Arguments ..
00014       REAL               A( LDA, * ), C( LDC, * ), TAU( * ),
00015      $                   WORK( * )
00016 *     ..
00017 *
00018 *  Purpose
00019 *  =======
00020 *
00021 *  SORMQL overwrites the general real M-by-N matrix C with
00022 *
00023 *                  SIDE = 'L'     SIDE = 'R'
00024 *  TRANS = 'N':      Q * C          C * Q
00025 *  TRANS = 'T':      Q**T * C       C * Q**T
00026 *
00027 *  where Q is a real orthogonal matrix defined as the product of k
00028 *  elementary reflectors
00029 *
00030 *        Q = H(k) . . . H(2) H(1)
00031 *
00032 *  as returned by SGEQLF. Q is of order M if SIDE = 'L' and of order N
00033 *  if SIDE = 'R'.
00034 *
00035 *  Arguments
00036 *  =========
00037 *
00038 *  SIDE    (input) CHARACTER*1
00039 *          = 'L': apply Q or Q**T from the Left;
00040 *          = 'R': apply Q or Q**T from the Right.
00041 *
00042 *  TRANS   (input) CHARACTER*1
00043 *          = 'N':  No transpose, apply Q;
00044 *          = 'T':  Transpose, apply Q**T.
00045 *
00046 *  M       (input) INTEGER
00047 *          The number of rows of the matrix C. M >= 0.
00048 *
00049 *  N       (input) INTEGER
00050 *          The number of columns of the matrix C. N >= 0.
00051 *
00052 *  K       (input) INTEGER
00053 *          The number of elementary reflectors whose product defines
00054 *          the matrix Q.
00055 *          If SIDE = 'L', M >= K >= 0;
00056 *          if SIDE = 'R', N >= K >= 0.
00057 *
00058 *  A       (input) REAL array, dimension (LDA,K)
00059 *          The i-th column must contain the vector which defines the
00060 *          elementary reflector H(i), for i = 1,2,...,k, as returned by
00061 *          SGEQLF in the last k columns of its array argument A.
00062 *          A is modified by the routine but restored on exit.
00063 *
00064 *  LDA     (input) INTEGER
00065 *          The leading dimension of the array A.
00066 *          If SIDE = 'L', LDA >= max(1,M);
00067 *          if SIDE = 'R', LDA >= max(1,N).
00068 *
00069 *  TAU     (input) REAL array, dimension (K)
00070 *          TAU(i) must contain the scalar factor of the elementary
00071 *          reflector H(i), as returned by SGEQLF.
00072 *
00073 *  C       (input/output) REAL array, dimension (LDC,N)
00074 *          On entry, the M-by-N matrix C.
00075 *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
00076 *
00077 *  LDC     (input) INTEGER
00078 *          The leading dimension of the array C. LDC >= max(1,M).
00079 *
00080 *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
00081 *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
00082 *
00083 *  LWORK   (input) INTEGER
00084 *          The dimension of the array WORK.
00085 *          If SIDE = 'L', LWORK >= max(1,N);
00086 *          if SIDE = 'R', LWORK >= max(1,M).
00087 *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
00088 *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
00089 *          blocksize.
00090 *
00091 *          If LWORK = -1, then a workspace query is assumed; the routine
00092 *          only calculates the optimal size of the WORK array, returns
00093 *          this value as the first entry of the WORK array, and no error
00094 *          message related to LWORK is issued by XERBLA.
00095 *
00096 *  INFO    (output) INTEGER
00097 *          = 0:  successful exit
00098 *          < 0:  if INFO = -i, the i-th argument had an illegal value
00099 *
00100 *  =====================================================================
00101 *
00102 *     .. Parameters ..
00103       INTEGER            NBMAX, LDT
00104       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
00105 *     ..
00106 *     .. Local Scalars ..
00107       LOGICAL            LEFT, LQUERY, NOTRAN
00108       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
00109      $                   MI, NB, NBMIN, NI, NQ, NW
00110 *     ..
00111 *     .. Local Arrays ..
00112       REAL               T( LDT, NBMAX )
00113 *     ..
00114 *     .. External Functions ..
00115       LOGICAL            LSAME
00116       INTEGER            ILAENV
00117       EXTERNAL           LSAME, ILAENV
00118 *     ..
00119 *     .. External Subroutines ..
00120       EXTERNAL           SLARFB, SLARFT, SORM2L, XERBLA
00121 *     ..
00122 *     .. Intrinsic Functions ..
00123       INTRINSIC          MAX, MIN
00124 *     ..
00125 *     .. Executable Statements ..
00126 *
00127 *     Test the input arguments
00128 *
00129       INFO = 0
00130       LEFT = LSAME( SIDE, 'L' )
00131       NOTRAN = LSAME( TRANS, 'N' )
00132       LQUERY = ( LWORK.EQ.-1 )
00133 *
00134 *     NQ is the order of Q and NW is the minimum dimension of WORK
00135 *
00136       IF( LEFT ) THEN
00137          NQ = M
00138          NW = MAX( 1, N )
00139       ELSE
00140          NQ = N
00141          NW = MAX( 1, M )
00142       END IF
00143       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
00144          INFO = -1
00145       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
00146          INFO = -2
00147       ELSE IF( M.LT.0 ) THEN
00148          INFO = -3
00149       ELSE IF( N.LT.0 ) THEN
00150          INFO = -4
00151       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
00152          INFO = -5
00153       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
00154          INFO = -7
00155       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
00156          INFO = -10
00157       END IF
00158 *
00159       IF( INFO.EQ.0 ) THEN
00160          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
00161             LWKOPT = 1
00162          ELSE
00163 *
00164 *           Determine the block size.  NB may be at most NBMAX, where
00165 *           NBMAX is used to define the local array T.
00166 *
00167 *
00168             NB = MIN( NBMAX, ILAENV( 1, 'SORMQL', SIDE // TRANS, M, N,
00169      $                               K, -1 ) )
00170             LWKOPT = NW*NB
00171          END IF
00172          WORK( 1 ) = LWKOPT
00173 *
00174          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
00175             INFO = -12
00176          END IF
00177       END IF
00178 *
00179       IF( INFO.NE.0 ) THEN
00180          CALL XERBLA( 'SORMQL', -INFO )
00181          RETURN
00182       ELSE IF( LQUERY ) THEN
00183          RETURN
00184       END IF
00185 *
00186 *     Quick return if possible
00187 *
00188       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
00189          RETURN
00190       END IF
00191 *
00192       NBMIN = 2
00193       LDWORK = NW
00194       IF( NB.GT.1 .AND. NB.LT.K ) THEN
00195          IWS = NW*NB
00196          IF( LWORK.LT.IWS ) THEN
00197             NB = LWORK / LDWORK
00198             NBMIN = MAX( 2, ILAENV( 2, 'SORMQL', SIDE // TRANS, M, N, K,
00199      $              -1 ) )
00200          END IF
00201       ELSE
00202          IWS = NW
00203       END IF
00204 *
00205       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
00206 *
00207 *        Use unblocked code
00208 *
00209          CALL SORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
00210      $                IINFO )
00211       ELSE
00212 *
00213 *        Use blocked code
00214 *
00215          IF( ( LEFT .AND. NOTRAN ) .OR.
00216      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
00217             I1 = 1
00218             I2 = K
00219             I3 = NB
00220          ELSE
00221             I1 = ( ( K-1 ) / NB )*NB + 1
00222             I2 = 1
00223             I3 = -NB
00224          END IF
00225 *
00226          IF( LEFT ) THEN
00227             NI = N
00228          ELSE
00229             MI = M
00230          END IF
00231 *
00232          DO 10 I = I1, I2, I3
00233             IB = MIN( NB, K-I+1 )
00234 *
00235 *           Form the triangular factor of the block reflector
00236 *           H = H(i+ib-1) . . . H(i+1) H(i)
00237 *
00238             CALL SLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
00239      $                   A( 1, I ), LDA, TAU( I ), T, LDT )
00240             IF( LEFT ) THEN
00241 *
00242 *              H or H**T is applied to C(1:m-k+i+ib-1,1:n)
00243 *
00244                MI = M - K + I + IB - 1
00245             ELSE
00246 *
00247 *              H or H**T is applied to C(1:m,1:n-k+i+ib-1)
00248 *
00249                NI = N - K + I + IB - 1
00250             END IF
00251 *
00252 *           Apply H or H**T
00253 *
00254             CALL SLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
00255      $                   IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
00256      $                   LDWORK )
00257    10    CONTINUE
00258       END IF
00259       WORK( 1 ) = LWKOPT
00260       RETURN
00261 *
00262 *     End of SORMQL
00263 *
00264       END
 All Files Functions