LAPACK: TESTING/LIN/dqrt01.f Source File

Go to the documentation of this file.
00001       SUBROUTINE DQRT01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
00002      $                   RWORK, RESULT )
00003 *
00004 *  -- LAPACK test routine (version 3.1) --
00005 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            LDA, LWORK, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
00013      $                   R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
00014      $                   WORK( LWORK )
00015 *     ..
00016 *
00017 *  Purpose
00018 *  =======
00019 *
00020 *  DQRT01 tests DGEQRF, which computes the QR factorization of an m-by-n
00021 *  matrix A, and partially tests DORGQR which forms the m-by-m
00022 *  orthogonal matrix Q.
00023 *
00024 *  DQRT01 compares R with Q'*A, and checks that Q is orthogonal.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix A.  M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix A.  N >= 0.
00034 *
00035 *  A       (input) DOUBLE PRECISION array, dimension (LDA,N)
00036 *          The m-by-n matrix A.
00037 *
00038 *  AF      (output) DOUBLE PRECISION array, dimension (LDA,N)
00039 *          Details of the QR factorization of A, as returned by DGEQRF.
00040 *          See DGEQRF for further details.
00041 *
00042 *  Q       (output) DOUBLE PRECISION array, dimension (LDA,M)
00043 *          The m-by-m orthogonal matrix Q.
00044 *
00045 *  R       (workspace) DOUBLE PRECISION array, dimension (LDA,max(M,N))
00046 *
00047 *  LDA     (input) INTEGER
00048 *          The leading dimension of the arrays A, AF, Q and R.
00049 *          LDA >= max(M,N).
00050 *
00051 *  TAU     (output) DOUBLE PRECISION array, dimension (min(M,N))
00052 *          The scalar factors of the elementary reflectors, as returned
00053 *          by DGEQRF.
00054 *
00055 *  WORK    (workspace) DOUBLE PRECISION array, dimension (LWORK)
00056 *
00057 *  LWORK   (input) INTEGER
00058 *          The dimension of the array WORK.
00059 *
00060 *  RWORK   (workspace) DOUBLE PRECISION array, dimension (M)
00061 *
00062 *  RESULT  (output) DOUBLE PRECISION array, dimension (2)
00063 *          The test ratios:
00064 *          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
00065 *          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
00066 *
00067 *  =====================================================================
00068 *
00069 *     .. Parameters ..
00070       DOUBLE PRECISION   ZERO, ONE
00071       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
00072       DOUBLE PRECISION   ROGUE
00073       PARAMETER          ( ROGUE = -1.0D+10 )
00074 *     ..
00075 *     .. Local Scalars ..
00076       INTEGER            INFO, MINMN
00077       DOUBLE PRECISION   ANORM, EPS, RESID
00078 *     ..
00079 *     .. External Functions ..
00080       DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
00081       EXTERNAL           DLAMCH, DLANGE, DLANSY
00082 *     ..
00083 *     .. External Subroutines ..
00084       EXTERNAL           DGEMM, DGEQRF, DLACPY, DLASET, DORGQR, DSYRK
00085 *     ..
00086 *     .. Intrinsic Functions ..
00087       INTRINSIC          DBLE, MAX, MIN
00088 *     ..
00089 *     .. Scalars in Common ..
00090       CHARACTER*32       SRNAMT
00091 *     ..
00092 *     .. Common blocks ..
00093       COMMON             / SRNAMC / SRNAMT
00094 *     ..
00095 *     .. Executable Statements ..
00096 *
00097       MINMN = MIN( M, N )
00098       EPS = DLAMCH( 'Epsilon' )
00099 *
00100 *     Copy the matrix A to the array AF.
00101 *
00102       CALL DLACPY( 'Full', M, N, A, LDA, AF, LDA )
00103 *
00104 *     Factorize the matrix A in the array AF.
00105 *
00106       SRNAMT = 'DGEQRF'
00107       CALL DGEQRF( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
00108 *
00109 *     Copy details of Q
00110 *
00111       CALL DLASET( 'Full', M, M, ROGUE, ROGUE, Q, LDA )
00112       CALL DLACPY( 'Lower', M-1, N, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
00113 *
00114 *     Generate the m-by-m matrix Q
00115 *
00116       SRNAMT = 'DORGQR'
00117       CALL DORGQR( M, M, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
00118 *
00119 *     Copy R
00120 *
00121       CALL DLASET( 'Full', M, N, ZERO, ZERO, R, LDA )
00122       CALL DLACPY( 'Upper', M, N, AF, LDA, R, LDA )
00123 *
00124 *     Compute R - Q'*A
00125 *
00126       CALL DGEMM( 'Transpose', 'No transpose', M, N, M, -ONE, Q, LDA, A,
00127      $            LDA, ONE, R, LDA )
00128 *
00129 *     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
00130 *
00131       ANORM = DLANGE( '1', M, N, A, LDA, RWORK )
00132       RESID = DLANGE( '1', M, N, R, LDA, RWORK )
00133       IF( ANORM.GT.ZERO ) THEN
00134          RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, M ) ) ) / ANORM ) / EPS
00135       ELSE
00136          RESULT( 1 ) = ZERO
00137       END IF
00138 *
00139 *     Compute I - Q'*Q
00140 *
00141       CALL DLASET( 'Full', M, M, ZERO, ONE, R, LDA )
00142       CALL DSYRK( 'Upper', 'Transpose', M, M, -ONE, Q, LDA, ONE, R,
00143      $            LDA )
00144 *
00145 *     Compute norm( I - Q'*Q ) / ( M * EPS ) .
00146 *
00147       RESID = DLANSY( '1', 'Upper', M, R, LDA, RWORK )
00148 *
00149       RESULT( 2 ) = ( RESID / DBLE( MAX( 1, M ) ) ) / EPS
00150 *
00151       RETURN
00152 *
00153 *     End of DQRT01
00154 *
00155       END