LAPACK: SRC/dormlq.f Source File

Go to the documentation of this file.
00001       SUBROUTINE DORMLQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
00002      $                   WORK, LWORK, INFO )
00003 *
00004 *  -- LAPACK routine (version 3.2) --
00005 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00006 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00007 *     November 2006
00008 *
00009 *     .. Scalar Arguments ..
00010       CHARACTER          SIDE, TRANS
00011       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
00012 *     ..
00013 *     .. Array Arguments ..
00014       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
00015 *     ..
00016 *
00017 *  Purpose
00018 *  =======
00019 *
00020 *  DORMLQ overwrites the general real M-by-N matrix C with
00021 *
00022 *                  SIDE = 'L'     SIDE = 'R'
00023 *  TRANS = 'N':      Q * C          C * Q
00024 *  TRANS = 'T':      Q**T * C       C * Q**T
00025 *
00026 *  where Q is a real orthogonal matrix defined as the product of k
00027 *  elementary reflectors
00028 *
00029 *        Q = H(k) . . . H(2) H(1)
00030 *
00031 *  as returned by DGELQF. Q is of order M if SIDE = 'L' and of order N
00032 *  if SIDE = 'R'.
00033 *
00034 *  Arguments
00035 *  =========
00036 *
00037 *  SIDE    (input) CHARACTER*1
00038 *          = 'L': apply Q or Q**T from the Left;
00039 *          = 'R': apply Q or Q**T from the Right.
00040 *
00041 *  TRANS   (input) CHARACTER*1
00042 *          = 'N':  No transpose, apply Q;
00043 *          = 'T':  Transpose, apply Q**T.
00044 *
00045 *  M       (input) INTEGER
00046 *          The number of rows of the matrix C. M >= 0.
00047 *
00048 *  N       (input) INTEGER
00049 *          The number of columns of the matrix C. N >= 0.
00050 *
00051 *  K       (input) INTEGER
00052 *          The number of elementary reflectors whose product defines
00053 *          the matrix Q.
00054 *          If SIDE = 'L', M >= K >= 0;
00055 *          if SIDE = 'R', N >= K >= 0.
00056 *
00057 *  A       (input) DOUBLE PRECISION array, dimension
00058 *                               (LDA,M) if SIDE = 'L',
00059 *                               (LDA,N) if SIDE = 'R'
00060 *          The i-th row must contain the vector which defines the
00061 *          elementary reflector H(i), for i = 1,2,...,k, as returned by
00062 *          DGELQF in the first k rows of its array argument A.
00063 *          A is modified by the routine but restored on exit.
00064 *
00065 *  LDA     (input) INTEGER
00066 *          The leading dimension of the array A. LDA >= max(1,K).
00067 *
00068 *  TAU     (input) DOUBLE PRECISION array, dimension (K)
00069 *          TAU(i) must contain the scalar factor of the elementary
00070 *          reflector H(i), as returned by DGELQF.
00071 *
00072 *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
00073 *          On entry, the M-by-N matrix C.
00074 *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
00075 *
00076 *  LDC     (input) INTEGER
00077 *          The leading dimension of the array C. LDC >= max(1,M).
00078 *
00079 *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
00080 *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
00081 *
00082 *  LWORK   (input) INTEGER
00083 *          The dimension of the array WORK.
00084 *          If SIDE = 'L', LWORK >= max(1,N);
00085 *          if SIDE = 'R', LWORK >= max(1,M).
00086 *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
00087 *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
00088 *          blocksize.
00089 *
00090 *          If LWORK = -1, then a workspace query is assumed; the routine
00091 *          only calculates the optimal size of the WORK array, returns
00092 *          this value as the first entry of the WORK array, and no error
00093 *          message related to LWORK is issued by XERBLA.
00094 *
00095 *  INFO    (output) INTEGER
00096 *          = 0:  successful exit
00097 *          < 0:  if INFO = -i, the i-th argument had an illegal value
00098 *
00099 *  =====================================================================
00100 *
00101 *     .. Parameters ..
00102       INTEGER            NBMAX, LDT
00103       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
00104 *     ..
00105 *     .. Local Scalars ..
00106       LOGICAL            LEFT, LQUERY, NOTRAN
00107       CHARACTER          TRANST
00108       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK,
00109      $                   LWKOPT, MI, NB, NBMIN, NI, NQ, NW
00110 *     ..
00111 *     .. Local Arrays ..
00112       DOUBLE PRECISION   T( LDT, NBMAX )
00113 *     ..
00114 *     .. External Functions ..
00115       LOGICAL            LSAME
00116       INTEGER            ILAENV
00117       EXTERNAL           LSAME, ILAENV
00118 *     ..
00119 *     .. External Subroutines ..
00120       EXTERNAL           DLARFB, DLARFT, DORML2, XERBLA
00121 *     ..
00122 *     .. Intrinsic Functions ..
00123       INTRINSIC          MAX, MIN
00124 *     ..
00125 *     .. Executable Statements ..
00126 *
00127 *     Test the input arguments
00128 *
00129       INFO = 0
00130       LEFT = LSAME( SIDE, 'L' )
00131       NOTRAN = LSAME( TRANS, 'N' )
00132       LQUERY = ( LWORK.EQ.-1 )
00133 *
00134 *     NQ is the order of Q and NW is the minimum dimension of WORK
00135 *
00136       IF( LEFT ) THEN
00137          NQ = M
00138          NW = N
00139       ELSE
00140          NQ = N
00141          NW = M
00142       END IF
00143       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
00144          INFO = -1
00145       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
00146          INFO = -2
00147       ELSE IF( M.LT.0 ) THEN
00148          INFO = -3
00149       ELSE IF( N.LT.0 ) THEN
00150          INFO = -4
00151       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
00152          INFO = -5
00153       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
00154          INFO = -7
00155       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
00156          INFO = -10
00157       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
00158          INFO = -12
00159       END IF
00160 *
00161       IF( INFO.EQ.0 ) THEN
00162 *
00163 *        Determine the block size.  NB may be at most NBMAX, where NBMAX
00164 *        is used to define the local array T.
00165 *
00166          NB = MIN( NBMAX, ILAENV( 1, 'DORMLQ', SIDE // TRANS, M, N, K,
00167      $        -1 ) )
00168          LWKOPT = MAX( 1, NW )*NB
00169          WORK( 1 ) = LWKOPT
00170       END IF
00171 *
00172       IF( INFO.NE.0 ) THEN
00173          CALL XERBLA( 'DORMLQ', -INFO )
00174          RETURN
00175       ELSE IF( LQUERY ) THEN
00176          RETURN
00177       END IF
00178 *
00179 *     Quick return if possible
00180 *
00181       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
00182          WORK( 1 ) = 1
00183          RETURN
00184       END IF
00185 *
00186       NBMIN = 2
00187       LDWORK = NW
00188       IF( NB.GT.1 .AND. NB.LT.K ) THEN
00189          IWS = NW*NB
00190          IF( LWORK.LT.IWS ) THEN
00191             NB = LWORK / LDWORK
00192             NBMIN = MAX( 2, ILAENV( 2, 'DORMLQ', SIDE // TRANS, M, N, K,
00193      $              -1 ) )
00194          END IF
00195       ELSE
00196          IWS = NW
00197       END IF
00198 *
00199       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
00200 *
00201 *        Use unblocked code
00202 *
00203          CALL DORML2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
00204      $                IINFO )
00205       ELSE
00206 *
00207 *        Use blocked code
00208 *
00209          IF( ( LEFT .AND. NOTRAN ) .OR.
00210      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
00211             I1 = 1
00212             I2 = K
00213             I3 = NB
00214          ELSE
00215             I1 = ( ( K-1 ) / NB )*NB + 1
00216             I2 = 1
00217             I3 = -NB
00218          END IF
00219 *
00220          IF( LEFT ) THEN
00221             NI = N
00222             JC = 1
00223          ELSE
00224             MI = M
00225             IC = 1
00226          END IF
00227 *
00228          IF( NOTRAN ) THEN
00229             TRANST = 'T'
00230          ELSE
00231             TRANST = 'N'
00232          END IF
00233 *
00234          DO 10 I = I1, I2, I3
00235             IB = MIN( NB, K-I+1 )
00236 *
00237 *           Form the triangular factor of the block reflector
00238 *           H = H(i) H(i+1) . . . H(i+ib-1)
00239 *
00240             CALL DLARFT( 'Forward', 'Rowwise', NQ-I+1, IB, A( I, I ),
00241      $                   LDA, TAU( I ), T, LDT )
00242             IF( LEFT ) THEN
00243 *
00244 *              H or H' is applied to C(i:m,1:n)
00245 *
00246                MI = M - I + 1
00247                IC = I
00248             ELSE
00249 *
00250 *              H or H' is applied to C(1:m,i:n)
00251 *
00252                NI = N - I + 1
00253                JC = I
00254             END IF
00255 *
00256 *           Apply H or H'
00257 *
00258             CALL DLARFB( SIDE, TRANST, 'Forward', 'Rowwise', MI, NI, IB,
00259      $                   A( I, I ), LDA, T, LDT, C( IC, JC ), LDC, WORK,
00260      $                   LDWORK )
00261    10    CONTINUE
00262       END IF
00263       WORK( 1 ) = LWKOPT
00264       RETURN
00265 *
00266 *     End of DORMLQ
00267 *
00268       END