LAPACK 3.3.0

zungl2.f

Go to the documentation of this file.
00001       SUBROUTINE ZUNGL2( M, N, K, A, LDA, TAU, WORK, INFO )
00002 *
00003 *  -- LAPACK routine (version 3.2) --
00004 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00005 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            INFO, K, LDA, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
00013 *     ..
00014 *
00015 *  Purpose
00016 *  =======
00017 *
00018 *  ZUNGL2 generates an m-by-n complex matrix Q with orthonormal rows,
00019 *  which is defined as the first m rows of a product of k elementary
00020 *  reflectors of order n
00021 *
00022 *        Q  =  H(k)' . . . H(2)' H(1)'
00023 *
00024 *  as returned by ZGELQF.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix Q. M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix Q. N >= M.
00034 *
00035 *  K       (input) INTEGER
00036 *          The number of elementary reflectors whose product defines the
00037 *          matrix Q. M >= K >= 0.
00038 *
00039 *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
00040 *          On entry, the i-th row must contain the vector which defines
00041 *          the elementary reflector H(i), for i = 1,2,...,k, as returned
00042 *          by ZGELQF in the first k rows of its array argument A.
00043 *          On exit, the m by n matrix Q.
00044 *
00045 *  LDA     (input) INTEGER
00046 *          The first dimension of the array A. LDA >= max(1,M).
00047 *
00048 *  TAU     (input) COMPLEX*16 array, dimension (K)
00049 *          TAU(i) must contain the scalar factor of the elementary
00050 *          reflector H(i), as returned by ZGELQF.
00051 *
00052 *  WORK    (workspace) COMPLEX*16 array, dimension (M)
00053 *
00054 *  INFO    (output) INTEGER
00055 *          = 0: successful exit
00056 *          < 0: if INFO = -i, the i-th argument has an illegal value
00057 *
00058 *  =====================================================================
00059 *
00060 *     .. Parameters ..
00061       COMPLEX*16         ONE, ZERO
00062       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ),
00063      $                   ZERO = ( 0.0D+0, 0.0D+0 ) )
00064 *     ..
00065 *     .. Local Scalars ..
00066       INTEGER            I, J, L
00067 *     ..
00068 *     .. External Subroutines ..
00069       EXTERNAL           XERBLA, ZLACGV, ZLARF, ZSCAL
00070 *     ..
00071 *     .. Intrinsic Functions ..
00072       INTRINSIC          DCONJG, MAX
00073 *     ..
00074 *     .. Executable Statements ..
00075 *
00076 *     Test the input arguments
00077 *
00078       INFO = 0
00079       IF( M.LT.0 ) THEN
00080          INFO = -1
00081       ELSE IF( N.LT.M ) THEN
00082          INFO = -2
00083       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
00084          INFO = -3
00085       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
00086          INFO = -5
00087       END IF
00088       IF( INFO.NE.0 ) THEN
00089          CALL XERBLA( 'ZUNGL2', -INFO )
00090          RETURN
00091       END IF
00092 *
00093 *     Quick return if possible
00094 *
00095       IF( M.LE.0 )
00096      $   RETURN
00097 *
00098       IF( K.LT.M ) THEN
00099 *
00100 *        Initialise rows k+1:m to rows of the unit matrix
00101 *
00102          DO 20 J = 1, N
00103             DO 10 L = K + 1, M
00104                A( L, J ) = ZERO
00105    10       CONTINUE
00106             IF( J.GT.K .AND. J.LE.M )
00107      $         A( J, J ) = ONE
00108    20    CONTINUE
00109       END IF
00110 *
00111       DO 40 I = K, 1, -1
00112 *
00113 *        Apply H(i)' to A(i:m,i:n) from the right
00114 *
00115          IF( I.LT.N ) THEN
00116             CALL ZLACGV( N-I, A( I, I+1 ), LDA )
00117             IF( I.LT.M ) THEN
00118                A( I, I ) = ONE
00119                CALL ZLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
00120      $                     DCONJG( TAU( I ) ), A( I+1, I ), LDA, WORK )
00121             END IF
00122             CALL ZSCAL( N-I, -TAU( I ), A( I, I+1 ), LDA )
00123             CALL ZLACGV( N-I, A( I, I+1 ), LDA )
00124          END IF
00125          A( I, I ) = ONE - DCONJG( TAU( I ) )
00126 *
00127 *        Set A(i,1:i-1) to zero
00128 *
00129          DO 30 L = 1, I - 1
00130             A( I, L ) = ZERO
00131    30    CONTINUE
00132    40 CONTINUE
00133       RETURN
00134 *
00135 *     End of ZUNGL2
00136 *
00137       END
 All Files Functions