d5/d0a/cgeqls_8f_source.html

00001       SUBROUTINE CGEQLS( M, N, NRHS, A, LDA, TAU, B, LDB, WORK, LWORK,
00002      $                   INFO )
00003 *
00004 *  -- LAPACK routine (version 3.1) --
00005 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
00010 *     ..
00011 *     .. Array Arguments ..
00012       COMPLEX            A( LDA, * ), B( LDB, * ), TAU( * ),
00013      $                   WORK( LWORK )
00014 *     ..
00015 *
00016 *  Purpose
00017 *  =======
00018 *
00019 *  Solve the least squares problem
00020 *      min || A*X - B ||
00021 *  using the QL factorization
00022 *      A = Q*L
00023 *  computed by CGEQLF.
00024 *
00025 *  Arguments
00026 *  =========
00027 *
00028 *  M       (input) INTEGER
00029 *          The number of rows of the matrix A.  M >= 0.
00030 *
00031 *  N       (input) INTEGER
00032 *          The number of columns of the matrix A.  M >= N >= 0.
00033 *
00034 *  NRHS    (input) INTEGER
00035 *          The number of columns of B.  NRHS >= 0.
00036 *
00037 *  A       (input) COMPLEX array, dimension (LDA,N)
00038 *          Details of the QL factorization of the original matrix A as
00039 *          returned by CGEQLF.
00040 *
00041 *  LDA     (input) INTEGER
00042 *          The leading dimension of the array A.  LDA >= M.
00043 *
00044 *  TAU     (input) COMPLEX array, dimension (N)
00045 *          Details of the orthogonal matrix Q.
00046 *
00047 *  B       (input/output) COMPLEX array, dimension (LDB,NRHS)
00048 *          On entry, the m-by-nrhs right hand side matrix B.
00049 *          On exit, the n-by-nrhs solution matrix X, stored in rows
00050 *          m-n+1:m.
00051 *
00052 *  LDB     (input) INTEGER
00053 *          The leading dimension of the array B. LDB >= M.
00054 *
00055 *  WORK    (workspace) COMPLEX array, dimension (LWORK)
00056 *
00057 *  LWORK   (input) INTEGER
00058 *          The length of the array WORK.  LWORK must be at least NRHS,
00059 *          and should be at least NRHS*NB, where NB is the block size
00060 *          for this environment.
00061 *
00062 *  INFO    (output) INTEGER
00063 *          = 0: successful exit
00064 *          < 0: if INFO = -i, the i-th argument had an illegal value
00065 *
00066 *  =====================================================================
00067 *
00068 *     .. Parameters ..
00069       COMPLEX            ONE
00070       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
00071 *     ..
00072 *     .. External Subroutines ..
00073       EXTERNAL           CTRSM, CUNMQL, XERBLA
00074 *     ..
00075 *     .. Intrinsic Functions ..
00076       INTRINSIC          MAX
00077 *     ..
00078 *     .. Executable Statements ..
00079 *
00080 *     Test the input arguments.
00081 *
00082       INFO = 0
00083       IF( M.LT.0 ) THEN
00084          INFO = -1
00085       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
00086          INFO = -2
00087       ELSE IF( NRHS.LT.0 ) THEN
00088          INFO = -3
00089       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
00090          INFO = -5
00091       ELSE IF( LDB.LT.MAX( 1, M ) ) THEN
00092          INFO = -8
00093       ELSE IF( LWORK.LT.1 .OR. LWORK.LT.NRHS .AND. M.GT.0 .AND. N.GT.0 )
00094      $          THEN
00095          INFO = -10
00096       END IF
00097       IF( INFO.NE.0 ) THEN
00098          CALL XERBLA( 'CGEQLS', -INFO )
00099          RETURN
00100       END IF
00101 *
00102 *     Quick return if possible
00103 *
00104       IF( N.EQ.0 .OR. NRHS.EQ.0 .OR. M.EQ.0 )
00105      $   RETURN
00106 *
00107 *     B := Q' * B
00108 *
00109       CALL CUNMQL( 'Left', 'Conjugate transpose', M, NRHS, N, A, LDA,
00110      $             TAU, B, LDB, WORK, LWORK, INFO )
00111 *
00112 *     Solve L*X = B(m-n+1:m,:)
00113 *
00114       CALL CTRSM( 'Left', 'Lower', 'No transpose', 'Non-unit', N, NRHS,
00115      $            ONE, A( M-N+1, 1 ), LDA, B( M-N+1, 1 ), LDB )
00116 *
00117       RETURN
00118 *
00119 *     End of CGEQLS
00120 *
00121       END