001:       SUBROUTINE ZUNGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, K, LDA, LWORK, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZUNGQR generates an M-by-N complex matrix Q with orthonormal columns,
019: *  which is defined as the first N columns of a product of K elementary
020: *  reflectors of order M
021: *
022: *        Q  =  H(1) H(2) . . . H(k)
023: *
024: *  as returned by ZGEQRF.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  M       (input) INTEGER
030: *          The number of rows of the matrix Q. M >= 0.
031: *
032: *  N       (input) INTEGER
033: *          The number of columns of the matrix Q. M >= N >= 0.
034: *
035: *  K       (input) INTEGER
036: *          The number of elementary reflectors whose product defines the
037: *          matrix Q. N >= K >= 0.
038: *
039: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
040: *          On entry, the i-th column must contain the vector which
041: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
042: *          returned by ZGEQRF in the first k columns of its array
043: *          argument A.
044: *          On exit, the M-by-N matrix Q.
045: *
046: *  LDA     (input) INTEGER
047: *          The first dimension of the array A. LDA >= max(1,M).
048: *
049: *  TAU     (input) COMPLEX*16 array, dimension (K)
050: *          TAU(i) must contain the scalar factor of the elementary
051: *          reflector H(i), as returned by ZGEQRF.
052: *
053: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
054: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
055: *
056: *  LWORK   (input) INTEGER
057: *          The dimension of the array WORK. LWORK >= max(1,N).
058: *          For optimum performance LWORK >= N*NB, where NB is the
059: *          optimal blocksize.
060: *
061: *          If LWORK = -1, then a workspace query is assumed; the routine
062: *          only calculates the optimal size of the WORK array, returns
063: *          this value as the first entry of the WORK array, and no error
064: *          message related to LWORK is issued by XERBLA.
065: *
066: *  INFO    (output) INTEGER
067: *          = 0:  successful exit
068: *          < 0:  if INFO = -i, the i-th argument has an illegal value
069: *
070: *  =====================================================================
071: *
072: *     .. Parameters ..
073:       COMPLEX*16         ZERO
074:       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ) )
075: *     ..
076: *     .. Local Scalars ..
077:       LOGICAL            LQUERY
078:       INTEGER            I, IB, IINFO, IWS, J, KI, KK, L, LDWORK,
079:      $                   LWKOPT, NB, NBMIN, NX
080: *     ..
081: *     .. External Subroutines ..
082:       EXTERNAL           XERBLA, ZLARFB, ZLARFT, ZUNG2R
083: *     ..
084: *     .. Intrinsic Functions ..
085:       INTRINSIC          MAX, MIN
086: *     ..
087: *     .. External Functions ..
088:       INTEGER            ILAENV
089:       EXTERNAL           ILAENV
090: *     ..
091: *     .. Executable Statements ..
092: *
093: *     Test the input arguments
094: *
095:       INFO = 0
096:       NB = ILAENV( 1, 'ZUNGQR', ' ', M, N, K, -1 )
097:       LWKOPT = MAX( 1, N )*NB
098:       WORK( 1 ) = LWKOPT
099:       LQUERY = ( LWORK.EQ.-1 )
100:       IF( M.LT.0 ) THEN
101:          INFO = -1
102:       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
103:          INFO = -2
104:       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
105:          INFO = -3
106:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
107:          INFO = -5
108:       ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
109:          INFO = -8
110:       END IF
111:       IF( INFO.NE.0 ) THEN
112:          CALL XERBLA( 'ZUNGQR', -INFO )
113:          RETURN
114:       ELSE IF( LQUERY ) THEN
115:          RETURN
116:       END IF
117: *
118: *     Quick return if possible
119: *
120:       IF( N.LE.0 ) THEN
121:          WORK( 1 ) = 1
122:          RETURN
123:       END IF
124: *
125:       NBMIN = 2
126:       NX = 0
127:       IWS = N
128:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
129: *
130: *        Determine when to cross over from blocked to unblocked code.
131: *
132:          NX = MAX( 0, ILAENV( 3, 'ZUNGQR', ' ', M, N, K, -1 ) )
133:          IF( NX.LT.K ) THEN
134: *
135: *           Determine if workspace is large enough for blocked code.
136: *
137:             LDWORK = N
138:             IWS = LDWORK*NB
139:             IF( LWORK.LT.IWS ) THEN
140: *
141: *              Not enough workspace to use optimal NB:  reduce NB and
142: *              determine the minimum value of NB.
143: *
144:                NB = LWORK / LDWORK
145:                NBMIN = MAX( 2, ILAENV( 2, 'ZUNGQR', ' ', M, N, K, -1 ) )
146:             END IF
147:          END IF
148:       END IF
149: *
150:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
151: *
152: *        Use blocked code after the last block.
153: *        The first kk columns are handled by the block method.
154: *
155:          KI = ( ( K-NX-1 ) / NB )*NB
156:          KK = MIN( K, KI+NB )
157: *
158: *        Set A(1:kk,kk+1:n) to zero.
159: *
160:          DO 20 J = KK + 1, N
161:             DO 10 I = 1, KK
162:                A( I, J ) = ZERO
163:    10       CONTINUE
164:    20    CONTINUE
165:       ELSE
166:          KK = 0
167:       END IF
168: *
169: *     Use unblocked code for the last or only block.
170: *
171:       IF( KK.LT.N )
172:      $   CALL ZUNG2R( M-KK, N-KK, K-KK, A( KK+1, KK+1 ), LDA,
173:      $                TAU( KK+1 ), WORK, IINFO )
174: *
175:       IF( KK.GT.0 ) THEN
176: *
177: *        Use blocked code
178: *
179:          DO 50 I = KI + 1, 1, -NB
180:             IB = MIN( NB, K-I+1 )
181:             IF( I+IB.LE.N ) THEN
182: *
183: *              Form the triangular factor of the block reflector
184: *              H = H(i) H(i+1) . . . H(i+ib-1)
185: *
186:                CALL ZLARFT( 'Forward', 'Columnwise', M-I+1, IB,
187:      $                      A( I, I ), LDA, TAU( I ), WORK, LDWORK )
188: *
189: *              Apply H to A(i:m,i+ib:n) from the left
190: *
191:                CALL ZLARFB( 'Left', 'No transpose', 'Forward',
192:      $                      'Columnwise', M-I+1, N-I-IB+1, IB,
193:      $                      A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ),
194:      $                      LDA, WORK( IB+1 ), LDWORK )
195:             END IF
196: *
197: *           Apply H to rows i:m of current block
198: *
199:             CALL ZUNG2R( M-I+1, IB, IB, A( I, I ), LDA, TAU( I ), WORK,
200:      $                   IINFO )
201: *
202: *           Set rows 1:i-1 of current block to zero
203: *
204:             DO 40 J = I, I + IB - 1
205:                DO 30 L = 1, I - 1
206:                   A( L, J ) = ZERO
207:    30          CONTINUE
208:    40       CONTINUE
209:    50    CONTINUE
210:       END IF
211: *
212:       WORK( 1 ) = IWS
213:       RETURN
214: *
215: *     End of ZUNGQR
216: *
217:       END
218: