001:       SUBROUTINE SSBMV(UPLO,N,K,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
002: *     .. Scalar Arguments ..
003:       REAL ALPHA,BETA
004:       INTEGER INCX,INCY,K,LDA,N
005:       CHARACTER UPLO
006: *     ..
007: *     .. Array Arguments ..
008:       REAL A(LDA,*),X(*),Y(*)
009: *     ..
010: *
011: *  Purpose
012: *  =======
013: *
014: *  SSBMV  performs the matrix-vector  operation
015: *
016: *     y := alpha*A*x + beta*y,
017: *
018: *  where alpha and beta are scalars, x and y are n element vectors and
019: *  A is an n by n symmetric band matrix, with k super-diagonals.
020: *
021: *  Arguments
022: *  ==========
023: *
024: *  UPLO   - CHARACTER*1.
025: *           On entry, UPLO specifies whether the upper or lower
026: *           triangular part of the band matrix A is being supplied as
027: *           follows:
028: *
029: *              UPLO = 'U' or 'u'   The upper triangular part of A is
030: *                                  being supplied.
031: *
032: *              UPLO = 'L' or 'l'   The lower triangular part of A is
033: *                                  being supplied.
034: *
035: *           Unchanged on exit.
036: *
037: *  N      - INTEGER.
038: *           On entry, N specifies the order of the matrix A.
039: *           N must be at least zero.
040: *           Unchanged on exit.
041: *
042: *  K      - INTEGER.
043: *           On entry, K specifies the number of super-diagonals of the
044: *           matrix A. K must satisfy  0 .le. K.
045: *           Unchanged on exit.
046: *
047: *  ALPHA  - REAL            .
048: *           On entry, ALPHA specifies the scalar alpha.
049: *           Unchanged on exit.
050: *
051: *  A      - REAL             array of DIMENSION ( LDA, n ).
052: *           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
053: *           by n part of the array A must contain the upper triangular
054: *           band part of the symmetric matrix, supplied column by
055: *           column, with the leading diagonal of the matrix in row
056: *           ( k + 1 ) of the array, the first super-diagonal starting at
057: *           position 2 in row k, and so on. The top left k by k triangle
058: *           of the array A is not referenced.
059: *           The following program segment will transfer the upper
060: *           triangular part of a symmetric band matrix from conventional
061: *           full matrix storage to band storage:
062: *
063: *                 DO 20, J = 1, N
064: *                    M = K + 1 - J
065: *                    DO 10, I = MAX( 1, J - K ), J
066: *                       A( M + I, J ) = matrix( I, J )
067: *              10    CONTINUE
068: *              20 CONTINUE
069: *
070: *           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
071: *           by n part of the array A must contain the lower triangular
072: *           band part of the symmetric matrix, supplied column by
073: *           column, with the leading diagonal of the matrix in row 1 of
074: *           the array, the first sub-diagonal starting at position 1 in
075: *           row 2, and so on. The bottom right k by k triangle of the
076: *           array A is not referenced.
077: *           The following program segment will transfer the lower
078: *           triangular part of a symmetric band matrix from conventional
079: *           full matrix storage to band storage:
080: *
081: *                 DO 20, J = 1, N
082: *                    M = 1 - J
083: *                    DO 10, I = J, MIN( N, J + K )
084: *                       A( M + I, J ) = matrix( I, J )
085: *              10    CONTINUE
086: *              20 CONTINUE
087: *
088: *           Unchanged on exit.
089: *
090: *  LDA    - INTEGER.
091: *           On entry, LDA specifies the first dimension of A as declared
092: *           in the calling (sub) program. LDA must be at least
093: *           ( k + 1 ).
094: *           Unchanged on exit.
095: *
096: *  X      - REAL             array of DIMENSION at least
097: *           ( 1 + ( n - 1 )*abs( INCX ) ).
098: *           Before entry, the incremented array X must contain the
099: *           vector x.
100: *           Unchanged on exit.
101: *
102: *  INCX   - INTEGER.
103: *           On entry, INCX specifies the increment for the elements of
104: *           X. INCX must not be zero.
105: *           Unchanged on exit.
106: *
107: *  BETA   - REAL            .
108: *           On entry, BETA specifies the scalar beta.
109: *           Unchanged on exit.
110: *
111: *  Y      - REAL             array of DIMENSION at least
112: *           ( 1 + ( n - 1 )*abs( INCY ) ).
113: *           Before entry, the incremented array Y must contain the
114: *           vector y. On exit, Y is overwritten by the updated vector y.
115: *
116: *  INCY   - INTEGER.
117: *           On entry, INCY specifies the increment for the elements of
118: *           Y. INCY must not be zero.
119: *           Unchanged on exit.
120: *
121: *  Further Details
122: *  ===============
123: *
124: *  Level 2 Blas routine.
125: *
126: *  -- Written on 22-October-1986.
127: *     Jack Dongarra, Argonne National Lab.
128: *     Jeremy Du Croz, Nag Central Office.
129: *     Sven Hammarling, Nag Central Office.
130: *     Richard Hanson, Sandia National Labs.
131: *
132: *  =====================================================================
133: *
134: *     .. Parameters ..
135:       REAL ONE,ZERO
136:       PARAMETER (ONE=1.0E+0,ZERO=0.0E+0)
137: *     ..
138: *     .. Local Scalars ..
139:       REAL TEMP1,TEMP2
140:       INTEGER I,INFO,IX,IY,J,JX,JY,KPLUS1,KX,KY,L
141: *     ..
142: *     .. External Functions ..
143:       LOGICAL LSAME
144:       EXTERNAL LSAME
145: *     ..
146: *     .. External Subroutines ..
147:       EXTERNAL XERBLA
148: *     ..
149: *     .. Intrinsic Functions ..
150:       INTRINSIC MAX,MIN
151: *     ..
152: *
153: *     Test the input parameters.
154: *
155:       INFO = 0
156:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
157:           INFO = 1
158:       ELSE IF (N.LT.0) THEN
159:           INFO = 2
160:       ELSE IF (K.LT.0) THEN
161:           INFO = 3
162:       ELSE IF (LDA.LT. (K+1)) THEN
163:           INFO = 6
164:       ELSE IF (INCX.EQ.0) THEN
165:           INFO = 8
166:       ELSE IF (INCY.EQ.0) THEN
167:           INFO = 11
168:       END IF
169:       IF (INFO.NE.0) THEN
170:           CALL XERBLA('SSBMV ',INFO)
171:           RETURN
172:       END IF
173: *
174: *     Quick return if possible.
175: *
176:       IF ((N.EQ.0) .OR. ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN
177: *
178: *     Set up the start points in  X  and  Y.
179: *
180:       IF (INCX.GT.0) THEN
181:           KX = 1
182:       ELSE
183:           KX = 1 - (N-1)*INCX
184:       END IF
185:       IF (INCY.GT.0) THEN
186:           KY = 1
187:       ELSE
188:           KY = 1 - (N-1)*INCY
189:       END IF
190: *
191: *     Start the operations. In this version the elements of the array A
192: *     are accessed sequentially with one pass through A.
193: *
194: *     First form  y := beta*y.
195: *
196:       IF (BETA.NE.ONE) THEN
197:           IF (INCY.EQ.1) THEN
198:               IF (BETA.EQ.ZERO) THEN
199:                   DO 10 I = 1,N
200:                       Y(I) = ZERO
201:    10             CONTINUE
202:               ELSE
203:                   DO 20 I = 1,N
204:                       Y(I) = BETA*Y(I)
205:    20             CONTINUE
206:               END IF
207:           ELSE
208:               IY = KY
209:               IF (BETA.EQ.ZERO) THEN
210:                   DO 30 I = 1,N
211:                       Y(IY) = ZERO
212:                       IY = IY + INCY
213:    30             CONTINUE
214:               ELSE
215:                   DO 40 I = 1,N
216:                       Y(IY) = BETA*Y(IY)
217:                       IY = IY + INCY
218:    40             CONTINUE
219:               END IF
220:           END IF
221:       END IF
222:       IF (ALPHA.EQ.ZERO) RETURN
223:       IF (LSAME(UPLO,'U')) THEN
224: *
225: *        Form  y  when upper triangle of A is stored.
226: *
227:           KPLUS1 = K + 1
228:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
229:               DO 60 J = 1,N
230:                   TEMP1 = ALPHA*X(J)
231:                   TEMP2 = ZERO
232:                   L = KPLUS1 - J
233:                   DO 50 I = MAX(1,J-K),J - 1
234:                       Y(I) = Y(I) + TEMP1*A(L+I,J)
235:                       TEMP2 = TEMP2 + A(L+I,J)*X(I)
236:    50             CONTINUE
237:                   Y(J) = Y(J) + TEMP1*A(KPLUS1,J) + ALPHA*TEMP2
238:    60         CONTINUE
239:           ELSE
240:               JX = KX
241:               JY = KY
242:               DO 80 J = 1,N
243:                   TEMP1 = ALPHA*X(JX)
244:                   TEMP2 = ZERO
245:                   IX = KX
246:                   IY = KY
247:                   L = KPLUS1 - J
248:                   DO 70 I = MAX(1,J-K),J - 1
249:                       Y(IY) = Y(IY) + TEMP1*A(L+I,J)
250:                       TEMP2 = TEMP2 + A(L+I,J)*X(IX)
251:                       IX = IX + INCX
252:                       IY = IY + INCY
253:    70             CONTINUE
254:                   Y(JY) = Y(JY) + TEMP1*A(KPLUS1,J) + ALPHA*TEMP2
255:                   JX = JX + INCX
256:                   JY = JY + INCY
257:                   IF (J.GT.K) THEN
258:                       KX = KX + INCX
259:                       KY = KY + INCY
260:                   END IF
261:    80         CONTINUE
262:           END IF
263:       ELSE
264: *
265: *        Form  y  when lower triangle of A is stored.
266: *
267:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
268:               DO 100 J = 1,N
269:                   TEMP1 = ALPHA*X(J)
270:                   TEMP2 = ZERO
271:                   Y(J) = Y(J) + TEMP1*A(1,J)
272:                   L = 1 - J
273:                   DO 90 I = J + 1,MIN(N,J+K)
274:                       Y(I) = Y(I) + TEMP1*A(L+I,J)
275:                       TEMP2 = TEMP2 + A(L+I,J)*X(I)
276:    90             CONTINUE
277:                   Y(J) = Y(J) + ALPHA*TEMP2
278:   100         CONTINUE
279:           ELSE
280:               JX = KX
281:               JY = KY
282:               DO 120 J = 1,N
283:                   TEMP1 = ALPHA*X(JX)
284:                   TEMP2 = ZERO
285:                   Y(JY) = Y(JY) + TEMP1*A(1,J)
286:                   L = 1 - J
287:                   IX = JX
288:                   IY = JY
289:                   DO 110 I = J + 1,MIN(N,J+K)
290:                       IX = IX + INCX
291:                       IY = IY + INCY
292:                       Y(IY) = Y(IY) + TEMP1*A(L+I,J)
293:                       TEMP2 = TEMP2 + A(L+I,J)*X(IX)
294:   110             CONTINUE
295:                   Y(JY) = Y(JY) + ALPHA*TEMP2
296:                   JX = JX + INCX
297:                   JY = JY + INCY
298:   120         CONTINUE
299:           END IF
300:       END IF
301: *
302:       RETURN
303: *
304: *     End of SSBMV .
305: *
306:       END
307: