01:       SUBROUTINE SROTG(SA,SB,C,S)
02: *     .. Scalar Arguments ..
03:       REAL C,S,SA,SB
04: *     ..
05: *
06: *  Purpose
07: *  =======
08: *
09: *     SROTG construct givens plane rotation.
10: *
11: *  Further Details
12: *  ===============
13: *
14: *     jack dongarra, linpack, 3/11/78.
15: *
16: *  =====================================================================
17: *
18: *     .. Local Scalars ..
19:       REAL R,ROE,SCALE,Z
20: *     ..
21: *     .. Intrinsic Functions ..
22:       INTRINSIC ABS,SIGN,SQRT
23: *     ..
24:       ROE = SB
25:       IF (ABS(SA).GT.ABS(SB)) ROE = SA
26:       SCALE = ABS(SA) + ABS(SB)
27:       IF (SCALE.NE.0.0) GO TO 10
28:       C = 1.0
29:       S = 0.0
30:       R = 0.0
31:       Z = 0.0
32:       GO TO 20
33:    10 R = SCALE*SQRT((SA/SCALE)**2+ (SB/SCALE)**2)
34:       R = SIGN(1.0,ROE)*R
35:       C = SA/R
36:       S = SB/R
37:       Z = 1.0
38:       IF (ABS(SA).GT.ABS(SB)) Z = S
39:       IF (ABS(SB).GE.ABS(SA) .AND. C.NE.0.0) Z = 1.0/C
40:    20 SA = R
41:       SB = Z
42:       RETURN
43:       END
44: