001:       SUBROUTINE SPPTRI( UPLO, N, AP, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               AP( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SPPTRI computes the inverse of a real symmetric positive definite
020: *  matrix A using the Cholesky factorization A = U**T*U or A = L*L**T
021: *  computed by SPPTRF.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  UPLO    (input) CHARACTER*1
027: *          = 'U':  Upper triangular factor is stored in AP;
028: *          = 'L':  Lower triangular factor is stored in AP.
029: *
030: *  N       (input) INTEGER
031: *          The order of the matrix A.  N >= 0.
032: *
033: *  AP      (input/output) REAL array, dimension (N*(N+1)/2)
034: *          On entry, the triangular factor U or L from the Cholesky
035: *          factorization A = U**T*U or A = L*L**T, packed columnwise as
036: *          a linear array.  The j-th column of U or L is stored in the
037: *          array AP as follows:
038: *          if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
039: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
040: *
041: *          On exit, the upper or lower triangle of the (symmetric)
042: *          inverse of A, overwriting the input factor U or L.
043: *
044: *  INFO    (output) INTEGER
045: *          = 0:  successful exit
046: *          < 0:  if INFO = -i, the i-th argument had an illegal value
047: *          > 0:  if INFO = i, the (i,i) element of the factor U or L is
048: *                zero, and the inverse could not be computed.
049: *
050: *  =====================================================================
051: *
052: *     .. Parameters ..
053:       REAL               ONE
054:       PARAMETER          ( ONE = 1.0E+0 )
055: *     ..
056: *     .. Local Scalars ..
057:       LOGICAL            UPPER
058:       INTEGER            J, JC, JJ, JJN
059:       REAL               AJJ
060: *     ..
061: *     .. External Functions ..
062:       LOGICAL            LSAME
063:       REAL               SDOT
064:       EXTERNAL           LSAME, SDOT
065: *     ..
066: *     .. External Subroutines ..
067:       EXTERNAL           SSCAL, SSPR, STPMV, STPTRI, XERBLA
068: *     ..
069: *     .. Executable Statements ..
070: *
071: *     Test the input parameters.
072: *
073:       INFO = 0
074:       UPPER = LSAME( UPLO, 'U' )
075:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
076:          INFO = -1
077:       ELSE IF( N.LT.0 ) THEN
078:          INFO = -2
079:       END IF
080:       IF( INFO.NE.0 ) THEN
081:          CALL XERBLA( 'SPPTRI', -INFO )
082:          RETURN
083:       END IF
084: *
085: *     Quick return if possible
086: *
087:       IF( N.EQ.0 )
088:      $   RETURN
089: *
090: *     Invert the triangular Cholesky factor U or L.
091: *
092:       CALL STPTRI( UPLO, 'Non-unit', N, AP, INFO )
093:       IF( INFO.GT.0 )
094:      $   RETURN
095: *
096:       IF( UPPER ) THEN
097: *
098: *        Compute the product inv(U) * inv(U)'.
099: *
100:          JJ = 0
101:          DO 10 J = 1, N
102:             JC = JJ + 1
103:             JJ = JJ + J
104:             IF( J.GT.1 )
105:      $         CALL SSPR( 'Upper', J-1, ONE, AP( JC ), 1, AP )
106:             AJJ = AP( JJ )
107:             CALL SSCAL( J, AJJ, AP( JC ), 1 )
108:    10    CONTINUE
109: *
110:       ELSE
111: *
112: *        Compute the product inv(L)' * inv(L).
113: *
114:          JJ = 1
115:          DO 20 J = 1, N
116:             JJN = JJ + N - J + 1
117:             AP( JJ ) = SDOT( N-J+1, AP( JJ ), 1, AP( JJ ), 1 )
118:             IF( J.LT.N )
119:      $         CALL STPMV( 'Lower', 'Transpose', 'Non-unit', N-J,
120:      $                     AP( JJN ), AP( JJ+1 ), 1 )
121:             JJ = JJN
122:    20    CONTINUE
123:       END IF
124: *
125:       RETURN
126: *
127: *     End of SPPTRI
128: *
129:       END
130: