001:       SUBROUTINE SORMTR( SIDE, UPLO, TRANS, M, N, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS, UPLO
011:       INTEGER            INFO, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  SORMTR overwrites the general real M-by-N matrix C with
022: *
023: *                  SIDE = 'L'     SIDE = 'R'
024: *  TRANS = 'N':      Q * C          C * Q
025: *  TRANS = 'T':      Q**T * C       C * Q**T
026: *
027: *  where Q is a real orthogonal matrix of order nq, with nq = m if
028: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
029: *  nq-1 elementary reflectors, as returned by SSYTRD:
030: *
031: *  if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
032: *
033: *  if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
034: *
035: *  Arguments
036: *  =========
037: *
038: *  SIDE    (input) CHARACTER*1
039: *          = 'L': apply Q or Q**T from the Left;
040: *          = 'R': apply Q or Q**T from the Right.
041: *
042: *  UPLO    (input) CHARACTER*1
043: *          = 'U': Upper triangle of A contains elementary reflectors
044: *                 from SSYTRD;
045: *          = 'L': Lower triangle of A contains elementary reflectors
046: *                 from SSYTRD.
047: *
048: *  TRANS   (input) CHARACTER*1
049: *          = 'N':  No transpose, apply Q;
050: *          = 'T':  Transpose, apply Q**T.
051: *
052: *  M       (input) INTEGER
053: *          The number of rows of the matrix C. M >= 0.
054: *
055: *  N       (input) INTEGER
056: *          The number of columns of the matrix C. N >= 0.
057: *
058: *  A       (input) REAL array, dimension
059: *                               (LDA,M) if SIDE = 'L'
060: *                               (LDA,N) if SIDE = 'R'
061: *          The vectors which define the elementary reflectors, as
062: *          returned by SSYTRD.
063: *
064: *  LDA     (input) INTEGER
065: *          The leading dimension of the array A.
066: *          LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
067: *
068: *  TAU     (input) REAL array, dimension
069: *                               (M-1) if SIDE = 'L'
070: *                               (N-1) if SIDE = 'R'
071: *          TAU(i) must contain the scalar factor of the elementary
072: *          reflector H(i), as returned by SSYTRD.
073: *
074: *  C       (input/output) REAL array, dimension (LDC,N)
075: *          On entry, the M-by-N matrix C.
076: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
077: *
078: *  LDC     (input) INTEGER
079: *          The leading dimension of the array C. LDC >= max(1,M).
080: *
081: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
082: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
083: *
084: *  LWORK   (input) INTEGER
085: *          The dimension of the array WORK.
086: *          If SIDE = 'L', LWORK >= max(1,N);
087: *          if SIDE = 'R', LWORK >= max(1,M).
088: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
089: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
090: *          blocksize.
091: *
092: *          If LWORK = -1, then a workspace query is assumed; the routine
093: *          only calculates the optimal size of the WORK array, returns
094: *          this value as the first entry of the WORK array, and no error
095: *          message related to LWORK is issued by XERBLA.
096: *
097: *  INFO    (output) INTEGER
098: *          = 0:  successful exit
099: *          < 0:  if INFO = -i, the i-th argument had an illegal value
100: *
101: *  =====================================================================
102: *
103: *     .. Local Scalars ..
104:       LOGICAL            LEFT, LQUERY, UPPER
105:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NI, NB, NQ, NW
106: *     ..
107: *     .. External Functions ..
108:       LOGICAL            LSAME
109:       INTEGER            ILAENV
110:       EXTERNAL           ILAENV, LSAME
111: *     ..
112: *     .. External Subroutines ..
113:       EXTERNAL           SORMQL, SORMQR, XERBLA
114: *     ..
115: *     .. Intrinsic Functions ..
116:       INTRINSIC          MAX
117: *     ..
118: *     .. Executable Statements ..
119: *
120: *     Test the input arguments
121: *
122:       INFO = 0
123:       LEFT = LSAME( SIDE, 'L' )
124:       UPPER = LSAME( UPLO, 'U' )
125:       LQUERY = ( LWORK.EQ.-1 )
126: *
127: *     NQ is the order of Q and NW is the minimum dimension of WORK
128: *
129:       IF( LEFT ) THEN
130:          NQ = M
131:          NW = N
132:       ELSE
133:          NQ = N
134:          NW = M
135:       END IF
136:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
137:          INFO = -1
138:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
139:          INFO = -2
140:       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'T' ) )
141:      $          THEN
142:          INFO = -3
143:       ELSE IF( M.LT.0 ) THEN
144:          INFO = -4
145:       ELSE IF( N.LT.0 ) THEN
146:          INFO = -5
147:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
148:          INFO = -7
149:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
150:          INFO = -10
151:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
152:          INFO = -12
153:       END IF
154: *
155:       IF( INFO.EQ.0 ) THEN
156:          IF( UPPER ) THEN
157:             IF( LEFT ) THEN
158:                NB = ILAENV( 1, 'SORMQL', SIDE // TRANS, M-1, N, M-1,
159:      $                      -1 )
160:             ELSE
161:                NB = ILAENV( 1, 'SORMQL', SIDE // TRANS, M, N-1, N-1,
162:      $                      -1 )
163:             END IF
164:          ELSE
165:             IF( LEFT ) THEN
166:                NB = ILAENV( 1, 'SORMQR', SIDE // TRANS, M-1, N, M-1,
167:      $                      -1 )
168:             ELSE
169:                NB = ILAENV( 1, 'SORMQR', SIDE // TRANS, M, N-1, N-1,
170:      $                      -1 )
171:             END IF
172:          END IF
173:          LWKOPT = MAX( 1, NW )*NB
174:          WORK( 1 ) = LWKOPT
175:       END IF
176: *
177:       IF( INFO.NE.0 ) THEN
178:          CALL XERBLA( 'SORMTR', -INFO )
179:          RETURN
180:       ELSE IF( LQUERY ) THEN
181:          RETURN
182:       END IF
183: *
184: *     Quick return if possible
185: *
186:       IF( M.EQ.0 .OR. N.EQ.0 .OR. NQ.EQ.1 ) THEN
187:          WORK( 1 ) = 1
188:          RETURN
189:       END IF
190: *
191:       IF( LEFT ) THEN
192:          MI = M - 1
193:          NI = N
194:       ELSE
195:          MI = M
196:          NI = N - 1
197:       END IF
198: *
199:       IF( UPPER ) THEN
200: *
201: *        Q was determined by a call to SSYTRD with UPLO = 'U'
202: *
203:          CALL SORMQL( SIDE, TRANS, MI, NI, NQ-1, A( 1, 2 ), LDA, TAU, C,
204:      $                LDC, WORK, LWORK, IINFO )
205:       ELSE
206: *
207: *        Q was determined by a call to SSYTRD with UPLO = 'L'
208: *
209:          IF( LEFT ) THEN
210:             I1 = 2
211:             I2 = 1
212:          ELSE
213:             I1 = 1
214:             I2 = 2
215:          END IF
216:          CALL SORMQR( SIDE, TRANS, MI, NI, NQ-1, A( 2, 1 ), LDA, TAU,
217:      $                C( I1, I2 ), LDC, WORK, LWORK, IINFO )
218:       END IF
219:       WORK( 1 ) = LWKOPT
220:       RETURN
221: *
222: *     End of SORMTR
223: *
224:       END
225: