001:       SUBROUTINE SORMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     January 2007
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  SORMRZ overwrites the general real M-by-N matrix C with
021: *
022: *                  SIDE = 'L'     SIDE = 'R'
023: *  TRANS = 'N':      Q * C          C * Q
024: *  TRANS = 'T':      Q**T * C       C * Q**T
025: *
026: *  where Q is a real orthogonal matrix defined as the product of k
027: *  elementary reflectors
028: *
029: *        Q = H(1) H(2) . . . H(k)
030: *
031: *  as returned by STZRZF. Q is of order M if SIDE = 'L' and of order N
032: *  if SIDE = 'R'.
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**T from the Left;
039: *          = 'R': apply Q or Q**T from the Right.
040: *
041: *  TRANS   (input) CHARACTER*1
042: *          = 'N':  No transpose, apply Q;
043: *          = 'T':  Transpose, apply Q**T.
044: *
045: *  M       (input) INTEGER
046: *          The number of rows of the matrix C. M >= 0.
047: *
048: *  N       (input) INTEGER
049: *          The number of columns of the matrix C. N >= 0.
050: *
051: *  K       (input) INTEGER
052: *          The number of elementary reflectors whose product defines
053: *          the matrix Q.
054: *          If SIDE = 'L', M >= K >= 0;
055: *          if SIDE = 'R', N >= K >= 0.
056: *
057: *  L       (input) INTEGER
058: *          The number of columns of the matrix A containing
059: *          the meaningful part of the Householder reflectors.
060: *          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
061: *
062: *  A       (input) REAL array, dimension
063: *                               (LDA,M) if SIDE = 'L',
064: *                               (LDA,N) if SIDE = 'R'
065: *          The i-th row must contain the vector which defines the
066: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
067: *          STZRZF in the last k rows of its array argument A.
068: *          A is modified by the routine but restored on exit.
069: *
070: *  LDA     (input) INTEGER
071: *          The leading dimension of the array A. LDA >= max(1,K).
072: *
073: *  TAU     (input) REAL array, dimension (K)
074: *          TAU(i) must contain the scalar factor of the elementary
075: *          reflector H(i), as returned by STZRZF.
076: *
077: *  C       (input/output) REAL array, dimension (LDC,N)
078: *          On entry, the M-by-N matrix C.
079: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
080: *
081: *  LDC     (input) INTEGER
082: *          The leading dimension of the array C. LDC >= max(1,M).
083: *
084: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
085: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
086: *
087: *  LWORK   (input) INTEGER
088: *          The dimension of the array WORK.
089: *          If SIDE = 'L', LWORK >= max(1,N);
090: *          if SIDE = 'R', LWORK >= max(1,M).
091: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
092: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
093: *          blocksize.
094: *
095: *          If LWORK = -1, then a workspace query is assumed; the routine
096: *          only calculates the optimal size of the WORK array, returns
097: *          this value as the first entry of the WORK array, and no error
098: *          message related to LWORK is issued by XERBLA.
099: *
100: *  INFO    (output) INTEGER
101: *          = 0:  successful exit
102: *          < 0:  if INFO = -i, the i-th argument had an illegal value
103: *
104: *  Further Details
105: *  ===============
106: *
107: *  Based on contributions by
108: *    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
109: *
110: *  =====================================================================
111: *
112: *     .. Parameters ..
113:       INTEGER            NBMAX, LDT
114:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
115: *     ..
116: *     .. Local Scalars ..
117:       LOGICAL            LEFT, LQUERY, NOTRAN
118:       CHARACTER          TRANST
119:       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JA, JC,
120:      $                   LDWORK, LWKOPT, MI, NB, NBMIN, NI, NQ, NW
121: *     ..
122: *     .. Local Arrays ..
123:       REAL               T( LDT, NBMAX )
124: *     ..
125: *     .. External Functions ..
126:       LOGICAL            LSAME
127:       INTEGER            ILAENV
128:       EXTERNAL           LSAME, ILAENV
129: *     ..
130: *     .. External Subroutines ..
131:       EXTERNAL           SLARZB, SLARZT, SORMR3, XERBLA
132: *     ..
133: *     .. Intrinsic Functions ..
134:       INTRINSIC          MAX, MIN
135: *     ..
136: *     .. Executable Statements ..
137: *
138: *     Test the input arguments
139: *
140:       INFO = 0
141:       LEFT = LSAME( SIDE, 'L' )
142:       NOTRAN = LSAME( TRANS, 'N' )
143:       LQUERY = ( LWORK.EQ.-1 )
144: *
145: *     NQ is the order of Q and NW is the minimum dimension of WORK
146: *
147:       IF( LEFT ) THEN
148:          NQ = M
149:          NW = MAX( 1, N )
150:       ELSE
151:          NQ = N
152:          NW = MAX( 1, M )
153:       END IF
154:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
155:          INFO = -1
156:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
157:          INFO = -2
158:       ELSE IF( M.LT.0 ) THEN
159:          INFO = -3
160:       ELSE IF( N.LT.0 ) THEN
161:          INFO = -4
162:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
163:          INFO = -5
164:       ELSE IF( L.LT.0 .OR. ( LEFT .AND. ( L.GT.M ) ) .OR.
165:      $         ( .NOT.LEFT .AND. ( L.GT.N ) ) ) THEN
166:          INFO = -6
167:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
168:          INFO = -8
169:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
170:          INFO = -11
171:       END IF
172: *
173:       IF( INFO.EQ.0 ) THEN
174:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
175:             LWKOPT = 1
176:          ELSE
177: *
178: *           Determine the block size.  NB may be at most NBMAX, where
179: *           NBMAX is used to define the local array T.
180: *
181:             NB = MIN( NBMAX, ILAENV( 1, 'SORMRQ', SIDE // TRANS, M, N,
182:      $                               K, -1 ) )
183:             LWKOPT = NW*NB
184:          END IF
185:          WORK( 1 ) = LWKOPT
186: *
187:          IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
188:             INFO = -13
189:          END IF
190:       END IF
191: *
192:       IF( INFO.NE.0 ) THEN
193:          CALL XERBLA( 'SORMRZ', -INFO )
194:          RETURN
195:       ELSE IF( LQUERY ) THEN
196:          RETURN
197:       END IF
198: *
199: *     Quick return if possible
200: *
201:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
202:          RETURN
203:       END IF
204: *
205:       NBMIN = 2
206:       LDWORK = NW
207:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
208:          IWS = NW*NB
209:          IF( LWORK.LT.IWS ) THEN
210:             NB = LWORK / LDWORK
211:             NBMIN = MAX( 2, ILAENV( 2, 'SORMRQ', SIDE // TRANS, M, N, K,
212:      $              -1 ) )
213:          END IF
214:       ELSE
215:          IWS = NW
216:       END IF
217: *
218:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
219: *
220: *        Use unblocked code
221: *
222:          CALL SORMR3( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
223:      $                WORK, IINFO )
224:       ELSE
225: *
226: *        Use blocked code
227: *
228:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
229:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
230:             I1 = 1
231:             I2 = K
232:             I3 = NB
233:          ELSE
234:             I1 = ( ( K-1 ) / NB )*NB + 1
235:             I2 = 1
236:             I3 = -NB
237:          END IF
238: *
239:          IF( LEFT ) THEN
240:             NI = N
241:             JC = 1
242:             JA = M - L + 1
243:          ELSE
244:             MI = M
245:             IC = 1
246:             JA = N - L + 1
247:          END IF
248: *
249:          IF( NOTRAN ) THEN
250:             TRANST = 'T'
251:          ELSE
252:             TRANST = 'N'
253:          END IF
254: *
255:          DO 10 I = I1, I2, I3
256:             IB = MIN( NB, K-I+1 )
257: *
258: *           Form the triangular factor of the block reflector
259: *           H = H(i+ib-1) . . . H(i+1) H(i)
260: *
261:             CALL SLARZT( 'Backward', 'Rowwise', L, IB, A( I, JA ), LDA,
262:      $                   TAU( I ), T, LDT )
263: *
264:             IF( LEFT ) THEN
265: *
266: *              H or H' is applied to C(i:m,1:n)
267: *
268:                MI = M - I + 1
269:                IC = I
270:             ELSE
271: *
272: *              H or H' is applied to C(1:m,i:n)
273: *
274:                NI = N - I + 1
275:                JC = I
276:             END IF
277: *
278: *           Apply H or H'
279: *
280:             CALL SLARZB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
281:      $                   IB, L, A( I, JA ), LDA, T, LDT, C( IC, JC ),
282:      $                   LDC, WORK, LDWORK )
283:    10    CONTINUE
284: *
285:       END IF
286: *
287:       WORK( 1 ) = LWKOPT
288: *
289:       RETURN
290: *
291: *     End of SORMRZ
292: *
293:       END
294: