001:       SUBROUTINE SLAUUM( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SLAUUM computes the product U * U' or L' * L, where the triangular
020: *  factor U or L is stored in the upper or lower triangular part of
021: *  the array A.
022: *
023: *  If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
024: *  overwriting the factor U in A.
025: *  If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
026: *  overwriting the factor L in A.
027: *
028: *  This is the blocked form of the algorithm, calling Level 3 BLAS.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  UPLO    (input) CHARACTER*1
034: *          Specifies whether the triangular factor stored in the array A
035: *          is upper or lower triangular:
036: *          = 'U':  Upper triangular
037: *          = 'L':  Lower triangular
038: *
039: *  N       (input) INTEGER
040: *          The order of the triangular factor U or L.  N >= 0.
041: *
042: *  A       (input/output) REAL array, dimension (LDA,N)
043: *          On entry, the triangular factor U or L.
044: *          On exit, if UPLO = 'U', the upper triangle of A is
045: *          overwritten with the upper triangle of the product U * U';
046: *          if UPLO = 'L', the lower triangle of A is overwritten with
047: *          the lower triangle of the product L' * L.
048: *
049: *  LDA     (input) INTEGER
050: *          The leading dimension of the array A.  LDA >= max(1,N).
051: *
052: *  INFO    (output) INTEGER
053: *          = 0: successful exit
054: *          < 0: if INFO = -k, the k-th argument had an illegal value
055: *
056: *  =====================================================================
057: *
058: *     .. Parameters ..
059:       REAL               ONE
060:       PARAMETER          ( ONE = 1.0E+0 )
061: *     ..
062: *     .. Local Scalars ..
063:       LOGICAL            UPPER
064:       INTEGER            I, IB, NB
065: *     ..
066: *     .. External Functions ..
067:       LOGICAL            LSAME
068:       INTEGER            ILAENV
069:       EXTERNAL           LSAME, ILAENV
070: *     ..
071: *     .. External Subroutines ..
072:       EXTERNAL           SGEMM, SLAUU2, SSYRK, STRMM, XERBLA
073: *     ..
074: *     .. Intrinsic Functions ..
075:       INTRINSIC          MAX, MIN
076: *     ..
077: *     .. Executable Statements ..
078: *
079: *     Test the input parameters.
080: *
081:       INFO = 0
082:       UPPER = LSAME( UPLO, 'U' )
083:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
084:          INFO = -1
085:       ELSE IF( N.LT.0 ) THEN
086:          INFO = -2
087:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
088:          INFO = -4
089:       END IF
090:       IF( INFO.NE.0 ) THEN
091:          CALL XERBLA( 'SLAUUM', -INFO )
092:          RETURN
093:       END IF
094: *
095: *     Quick return if possible
096: *
097:       IF( N.EQ.0 )
098:      $   RETURN
099: *
100: *     Determine the block size for this environment.
101: *
102:       NB = ILAENV( 1, 'SLAUUM', UPLO, N, -1, -1, -1 )
103: *
104:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
105: *
106: *        Use unblocked code
107: *
108:          CALL SLAUU2( UPLO, N, A, LDA, INFO )
109:       ELSE
110: *
111: *        Use blocked code
112: *
113:          IF( UPPER ) THEN
114: *
115: *           Compute the product U * U'.
116: *
117:             DO 10 I = 1, N, NB
118:                IB = MIN( NB, N-I+1 )
119:                CALL STRMM( 'Right', 'Upper', 'Transpose', 'Non-unit',
120:      $                     I-1, IB, ONE, A( I, I ), LDA, A( 1, I ),
121:      $                     LDA )
122:                CALL SLAUU2( 'Upper', IB, A( I, I ), LDA, INFO )
123:                IF( I+IB.LE.N ) THEN
124:                   CALL SGEMM( 'No transpose', 'Transpose', I-1, IB,
125:      $                        N-I-IB+1, ONE, A( 1, I+IB ), LDA,
126:      $                        A( I, I+IB ), LDA, ONE, A( 1, I ), LDA )
127:                   CALL SSYRK( 'Upper', 'No transpose', IB, N-I-IB+1,
128:      $                        ONE, A( I, I+IB ), LDA, ONE, A( I, I ),
129:      $                        LDA )
130:                END IF
131:    10       CONTINUE
132:          ELSE
133: *
134: *           Compute the product L' * L.
135: *
136:             DO 20 I = 1, N, NB
137:                IB = MIN( NB, N-I+1 )
138:                CALL STRMM( 'Left', 'Lower', 'Transpose', 'Non-unit', IB,
139:      $                     I-1, ONE, A( I, I ), LDA, A( I, 1 ), LDA )
140:                CALL SLAUU2( 'Lower', IB, A( I, I ), LDA, INFO )
141:                IF( I+IB.LE.N ) THEN
142:                   CALL SGEMM( 'Transpose', 'No transpose', IB, I-1,
143:      $                        N-I-IB+1, ONE, A( I+IB, I ), LDA,
144:      $                        A( I+IB, 1 ), LDA, ONE, A( I, 1 ), LDA )
145:                   CALL SSYRK( 'Lower', 'Transpose', IB, N-I-IB+1, ONE,
146:      $                        A( I+IB, I ), LDA, ONE, A( I, I ), LDA )
147:                END IF
148:    20       CONTINUE
149:          END IF
150:       END IF
151: *
152:       RETURN
153: *
154: *     End of SLAUUM
155: *
156:       END
157: