001:       SUBROUTINE SLASD0( N, SQRE, D, E, U, LDU, VT, LDVT, SMLSIZ, IWORK,
002:      $                   WORK, INFO )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       INTEGER            INFO, LDU, LDVT, N, SMLSIZ, SQRE
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            IWORK( * )
014:       REAL               D( * ), E( * ), U( LDU, * ), VT( LDVT, * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  Using a divide and conquer approach, SLASD0 computes the singular
022: *  value decomposition (SVD) of a real upper bidiagonal N-by-M
023: *  matrix B with diagonal D and offdiagonal E, where M = N + SQRE.
024: *  The algorithm computes orthogonal matrices U and VT such that
025: *  B = U * S * VT. The singular values S are overwritten on D.
026: *
027: *  A related subroutine, SLASDA, computes only the singular values,
028: *  and optionally, the singular vectors in compact form.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  N      (input) INTEGER
034: *         On entry, the row dimension of the upper bidiagonal matrix.
035: *         This is also the dimension of the main diagonal array D.
036: *
037: *  SQRE   (input) INTEGER
038: *         Specifies the column dimension of the bidiagonal matrix.
039: *         = 0: The bidiagonal matrix has column dimension M = N;
040: *         = 1: The bidiagonal matrix has column dimension M = N+1;
041: *
042: *  D      (input/output) REAL array, dimension (N)
043: *         On entry D contains the main diagonal of the bidiagonal
044: *         matrix.
045: *         On exit D, if INFO = 0, contains its singular values.
046: *
047: *  E      (input) REAL array, dimension (M-1)
048: *         Contains the subdiagonal entries of the bidiagonal matrix.
049: *         On exit, E has been destroyed.
050: *
051: *  U      (output) REAL array, dimension at least (LDQ, N)
052: *         On exit, U contains the left singular vectors.
053: *
054: *  LDU    (input) INTEGER
055: *         On entry, leading dimension of U.
056: *
057: *  VT     (output) REAL array, dimension at least (LDVT, M)
058: *         On exit, VT' contains the right singular vectors.
059: *
060: *  LDVT   (input) INTEGER
061: *         On entry, leading dimension of VT.
062: *
063: *  SMLSIZ (input) INTEGER
064: *         On entry, maximum size of the subproblems at the
065: *         bottom of the computation tree.
066: *
067: *  IWORK  (workspace) INTEGER array, dimension (8*N)
068: *
069: *  WORK   (workspace) REAL array, dimension (3*M**2+2*M)
070: *
071: *  INFO   (output) INTEGER
072: *          = 0:  successful exit.
073: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
074: *          > 0:  if INFO = 1, an singular value did not converge
075: *
076: *  Further Details
077: *  ===============
078: *
079: *  Based on contributions by
080: *     Ming Gu and Huan Ren, Computer Science Division, University of
081: *     California at Berkeley, USA
082: *
083: *  =====================================================================
084: *
085: *     .. Local Scalars ..
086:       INTEGER            I, I1, IC, IDXQ, IDXQC, IM1, INODE, ITEMP, IWK,
087:      $                   J, LF, LL, LVL, M, NCC, ND, NDB1, NDIML, NDIMR,
088:      $                   NL, NLF, NLP1, NLVL, NR, NRF, NRP1, SQREI
089:       REAL               ALPHA, BETA
090: *     ..
091: *     .. External Subroutines ..
092:       EXTERNAL           SLASD1, SLASDQ, SLASDT, XERBLA
093: *     ..
094: *     .. Executable Statements ..
095: *
096: *     Test the input parameters.
097: *
098:       INFO = 0
099: *
100:       IF( N.LT.0 ) THEN
101:          INFO = -1
102:       ELSE IF( ( SQRE.LT.0 ) .OR. ( SQRE.GT.1 ) ) THEN
103:          INFO = -2
104:       END IF
105: *
106:       M = N + SQRE
107: *
108:       IF( LDU.LT.N ) THEN
109:          INFO = -6
110:       ELSE IF( LDVT.LT.M ) THEN
111:          INFO = -8
112:       ELSE IF( SMLSIZ.LT.3 ) THEN
113:          INFO = -9
114:       END IF
115:       IF( INFO.NE.0 ) THEN
116:          CALL XERBLA( 'SLASD0', -INFO )
117:          RETURN
118:       END IF
119: *
120: *     If the input matrix is too small, call SLASDQ to find the SVD.
121: *
122:       IF( N.LE.SMLSIZ ) THEN
123:          CALL SLASDQ( 'U', SQRE, N, M, N, 0, D, E, VT, LDVT, U, LDU, U,
124:      $                LDU, WORK, INFO )
125:          RETURN
126:       END IF
127: *
128: *     Set up the computation tree.
129: *
130:       INODE = 1
131:       NDIML = INODE + N
132:       NDIMR = NDIML + N
133:       IDXQ = NDIMR + N
134:       IWK = IDXQ + N
135:       CALL SLASDT( N, NLVL, ND, IWORK( INODE ), IWORK( NDIML ),
136:      $             IWORK( NDIMR ), SMLSIZ )
137: *
138: *     For the nodes on bottom level of the tree, solve
139: *     their subproblems by SLASDQ.
140: *
141:       NDB1 = ( ND+1 ) / 2
142:       NCC = 0
143:       DO 30 I = NDB1, ND
144: *
145: *     IC : center row of each node
146: *     NL : number of rows of left  subproblem
147: *     NR : number of rows of right subproblem
148: *     NLF: starting row of the left   subproblem
149: *     NRF: starting row of the right  subproblem
150: *
151:          I1 = I - 1
152:          IC = IWORK( INODE+I1 )
153:          NL = IWORK( NDIML+I1 )
154:          NLP1 = NL + 1
155:          NR = IWORK( NDIMR+I1 )
156:          NRP1 = NR + 1
157:          NLF = IC - NL
158:          NRF = IC + 1
159:          SQREI = 1
160:          CALL SLASDQ( 'U', SQREI, NL, NLP1, NL, NCC, D( NLF ), E( NLF ),
161:      $                VT( NLF, NLF ), LDVT, U( NLF, NLF ), LDU,
162:      $                U( NLF, NLF ), LDU, WORK, INFO )
163:          IF( INFO.NE.0 ) THEN
164:             RETURN
165:          END IF
166:          ITEMP = IDXQ + NLF - 2
167:          DO 10 J = 1, NL
168:             IWORK( ITEMP+J ) = J
169:    10    CONTINUE
170:          IF( I.EQ.ND ) THEN
171:             SQREI = SQRE
172:          ELSE
173:             SQREI = 1
174:          END IF
175:          NRP1 = NR + SQREI
176:          CALL SLASDQ( 'U', SQREI, NR, NRP1, NR, NCC, D( NRF ), E( NRF ),
177:      $                VT( NRF, NRF ), LDVT, U( NRF, NRF ), LDU,
178:      $                U( NRF, NRF ), LDU, WORK, INFO )
179:          IF( INFO.NE.0 ) THEN
180:             RETURN
181:          END IF
182:          ITEMP = IDXQ + IC
183:          DO 20 J = 1, NR
184:             IWORK( ITEMP+J-1 ) = J
185:    20    CONTINUE
186:    30 CONTINUE
187: *
188: *     Now conquer each subproblem bottom-up.
189: *
190:       DO 50 LVL = NLVL, 1, -1
191: *
192: *        Find the first node LF and last node LL on the
193: *        current level LVL.
194: *
195:          IF( LVL.EQ.1 ) THEN
196:             LF = 1
197:             LL = 1
198:          ELSE
199:             LF = 2**( LVL-1 )
200:             LL = 2*LF - 1
201:          END IF
202:          DO 40 I = LF, LL
203:             IM1 = I - 1
204:             IC = IWORK( INODE+IM1 )
205:             NL = IWORK( NDIML+IM1 )
206:             NR = IWORK( NDIMR+IM1 )
207:             NLF = IC - NL
208:             IF( ( SQRE.EQ.0 ) .AND. ( I.EQ.LL ) ) THEN
209:                SQREI = SQRE
210:             ELSE
211:                SQREI = 1
212:             END IF
213:             IDXQC = IDXQ + NLF - 1
214:             ALPHA = D( IC )
215:             BETA = E( IC )
216:             CALL SLASD1( NL, NR, SQREI, D( NLF ), ALPHA, BETA,
217:      $                   U( NLF, NLF ), LDU, VT( NLF, NLF ), LDVT,
218:      $                   IWORK( IDXQC ), IWORK( IWK ), WORK, INFO )
219:             IF( INFO.NE.0 ) THEN
220:                RETURN
221:             END IF
222:    40    CONTINUE
223:    50 CONTINUE
224: *
225:       RETURN
226: *
227: *     End of SLASD0
228: *
229:       END
230: