001:       SUBROUTINE DPBCON( UPLO, N, KD, AB, LDAB, ANORM, RCOND, WORK,
002:      $                   IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
010: *
011: *     .. Scalar Arguments ..
012:       CHARACTER          UPLO
013:       INTEGER            INFO, KD, LDAB, N
014:       DOUBLE PRECISION   ANORM, RCOND
015: *     ..
016: *     .. Array Arguments ..
017:       INTEGER            IWORK( * )
018:       DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
019: *     ..
020: *
021: *  Purpose
022: *  =======
023: *
024: *  DPBCON estimates the reciprocal of the condition number (in the
025: *  1-norm) of a real symmetric positive definite band matrix using the
026: *  Cholesky factorization A = U**T*U or A = L*L**T computed by DPBTRF.
027: *
028: *  An estimate is obtained for norm(inv(A)), and the reciprocal of the
029: *  condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
030: *
031: *  Arguments
032: *  =========
033: *
034: *  UPLO    (input) CHARACTER*1
035: *          = 'U':  Upper triangular factor stored in AB;
036: *          = 'L':  Lower triangular factor stored in AB.
037: *
038: *  N       (input) INTEGER
039: *          The order of the matrix A.  N >= 0.
040: *
041: *  KD      (input) INTEGER
042: *          The number of superdiagonals of the matrix A if UPLO = 'U',
043: *          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
044: *
045: *  AB      (input) DOUBLE PRECISION array, dimension (LDAB,N)
046: *          The triangular factor U or L from the Cholesky factorization
047: *          A = U**T*U or A = L*L**T of the band matrix A, stored in the
048: *          first KD+1 rows of the array.  The j-th column of U or L is
049: *          stored in the j-th column of the array AB as follows:
050: *          if UPLO ='U', AB(kd+1+i-j,j) = U(i,j) for max(1,j-kd)<=i<=j;
051: *          if UPLO ='L', AB(1+i-j,j)    = L(i,j) for j<=i<=min(n,j+kd).
052: *
053: *  LDAB    (input) INTEGER
054: *          The leading dimension of the array AB.  LDAB >= KD+1.
055: *
056: *  ANORM   (input) DOUBLE PRECISION
057: *          The 1-norm (or infinity-norm) of the symmetric band matrix A.
058: *
059: *  RCOND   (output) DOUBLE PRECISION
060: *          The reciprocal of the condition number of the matrix A,
061: *          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
062: *          estimate of the 1-norm of inv(A) computed in this routine.
063: *
064: *  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
065: *
066: *  IWORK   (workspace) INTEGER array, dimension (N)
067: *
068: *  INFO    (output) INTEGER
069: *          = 0:  successful exit
070: *          < 0:  if INFO = -i, the i-th argument had an illegal value
071: *
072: *  =====================================================================
073: *
074: *     .. Parameters ..
075:       DOUBLE PRECISION   ONE, ZERO
076:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
077: *     ..
078: *     .. Local Scalars ..
079:       LOGICAL            UPPER
080:       CHARACTER          NORMIN
081:       INTEGER            IX, KASE
082:       DOUBLE PRECISION   AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
083: *     ..
084: *     .. Local Arrays ..
085:       INTEGER            ISAVE( 3 )
086: *     ..
087: *     .. External Functions ..
088:       LOGICAL            LSAME
089:       INTEGER            IDAMAX
090:       DOUBLE PRECISION   DLAMCH
091:       EXTERNAL           LSAME, IDAMAX, DLAMCH
092: *     ..
093: *     .. External Subroutines ..
094:       EXTERNAL           DLACN2, DLATBS, DRSCL, XERBLA
095: *     ..
096: *     .. Intrinsic Functions ..
097:       INTRINSIC          ABS
098: *     ..
099: *     .. Executable Statements ..
100: *
101: *     Test the input parameters.
102: *
103:       INFO = 0
104:       UPPER = LSAME( UPLO, 'U' )
105:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
106:          INFO = -1
107:       ELSE IF( N.LT.0 ) THEN
108:          INFO = -2
109:       ELSE IF( KD.LT.0 ) THEN
110:          INFO = -3
111:       ELSE IF( LDAB.LT.KD+1 ) THEN
112:          INFO = -5
113:       ELSE IF( ANORM.LT.ZERO ) THEN
114:          INFO = -6
115:       END IF
116:       IF( INFO.NE.0 ) THEN
117:          CALL XERBLA( 'DPBCON', -INFO )
118:          RETURN
119:       END IF
120: *
121: *     Quick return if possible
122: *
123:       RCOND = ZERO
124:       IF( N.EQ.0 ) THEN
125:          RCOND = ONE
126:          RETURN
127:       ELSE IF( ANORM.EQ.ZERO ) THEN
128:          RETURN
129:       END IF
130: *
131:       SMLNUM = DLAMCH( 'Safe minimum' )
132: *
133: *     Estimate the 1-norm of the inverse.
134: *
135:       KASE = 0
136:       NORMIN = 'N'
137:    10 CONTINUE
138:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
139:       IF( KASE.NE.0 ) THEN
140:          IF( UPPER ) THEN
141: *
142: *           Multiply by inv(U').
143: *
144:             CALL DLATBS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N,
145:      $                   KD, AB, LDAB, WORK, SCALEL, WORK( 2*N+1 ),
146:      $                   INFO )
147:             NORMIN = 'Y'
148: *
149: *           Multiply by inv(U).
150: *
151:             CALL DLATBS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
152:      $                   KD, AB, LDAB, WORK, SCALEU, WORK( 2*N+1 ),
153:      $                   INFO )
154:          ELSE
155: *
156: *           Multiply by inv(L).
157: *
158:             CALL DLATBS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
159:      $                   KD, AB, LDAB, WORK, SCALEL, WORK( 2*N+1 ),
160:      $                   INFO )
161:             NORMIN = 'Y'
162: *
163: *           Multiply by inv(L').
164: *
165:             CALL DLATBS( 'Lower', 'Transpose', 'Non-unit', NORMIN, N,
166:      $                   KD, AB, LDAB, WORK, SCALEU, WORK( 2*N+1 ),
167:      $                   INFO )
168:          END IF
169: *
170: *        Multiply by 1/SCALE if doing so will not cause overflow.
171: *
172:          SCALE = SCALEL*SCALEU
173:          IF( SCALE.NE.ONE ) THEN
174:             IX = IDAMAX( N, WORK, 1 )
175:             IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
176:      $         GO TO 20
177:             CALL DRSCL( N, SCALE, WORK, 1 )
178:          END IF
179:          GO TO 10
180:       END IF
181: *
182: *     Compute the estimate of the reciprocal condition number.
183: *
184:       IF( AINVNM.NE.ZERO )
185:      $   RCOND = ( ONE / AINVNM ) / ANORM
186: *
187:    20 CONTINUE
188: *
189:       RETURN
190: *
191: *     End of DPBCON
192: *
193:       END
194: