001:       SUBROUTINE DORMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  DORMRQ overwrites the general real M-by-N matrix C with
021: *
022: *                  SIDE = 'L'     SIDE = 'R'
023: *  TRANS = 'N':      Q * C          C * Q
024: *  TRANS = 'T':      Q**T * C       C * Q**T
025: *
026: *  where Q is a real orthogonal matrix defined as the product of k
027: *  elementary reflectors
028: *
029: *        Q = H(1) H(2) . . . H(k)
030: *
031: *  as returned by DGERQF. Q is of order M if SIDE = 'L' and of order N
032: *  if SIDE = 'R'.
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**T from the Left;
039: *          = 'R': apply Q or Q**T from the Right.
040: *
041: *  TRANS   (input) CHARACTER*1
042: *          = 'N':  No transpose, apply Q;
043: *          = 'T':  Transpose, apply Q**T.
044: *
045: *  M       (input) INTEGER
046: *          The number of rows of the matrix C. M >= 0.
047: *
048: *  N       (input) INTEGER
049: *          The number of columns of the matrix C. N >= 0.
050: *
051: *  K       (input) INTEGER
052: *          The number of elementary reflectors whose product defines
053: *          the matrix Q.
054: *          If SIDE = 'L', M >= K >= 0;
055: *          if SIDE = 'R', N >= K >= 0.
056: *
057: *  A       (input) DOUBLE PRECISION array, dimension
058: *                               (LDA,M) if SIDE = 'L',
059: *                               (LDA,N) if SIDE = 'R'
060: *          The i-th row must contain the vector which defines the
061: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
062: *          DGERQF in the last k rows of its array argument A.
063: *          A is modified by the routine but restored on exit.
064: *
065: *  LDA     (input) INTEGER
066: *          The leading dimension of the array A. LDA >= max(1,K).
067: *
068: *  TAU     (input) DOUBLE PRECISION array, dimension (K)
069: *          TAU(i) must contain the scalar factor of the elementary
070: *          reflector H(i), as returned by DGERQF.
071: *
072: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
073: *          On entry, the M-by-N matrix C.
074: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
081: *
082: *  LWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LWORK >= max(1,N);
085: *          if SIDE = 'R', LWORK >= max(1,M).
086: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
087: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
088: *          blocksize.
089: *
090: *          If LWORK = -1, then a workspace query is assumed; the routine
091: *          only calculates the optimal size of the WORK array, returns
092: *          this value as the first entry of the WORK array, and no error
093: *          message related to LWORK is issued by XERBLA.
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value
098: *
099: *  =====================================================================
100: *
101: *     .. Parameters ..
102:       INTEGER            NBMAX, LDT
103:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
104: *     ..
105: *     .. Local Scalars ..
106:       LOGICAL            LEFT, LQUERY, NOTRAN
107:       CHARACTER          TRANST
108:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
109:      $                   MI, NB, NBMIN, NI, NQ, NW
110: *     ..
111: *     .. Local Arrays ..
112:       DOUBLE PRECISION   T( LDT, NBMAX )
113: *     ..
114: *     .. External Functions ..
115:       LOGICAL            LSAME
116:       INTEGER            ILAENV
117:       EXTERNAL           LSAME, ILAENV
118: *     ..
119: *     .. External Subroutines ..
120:       EXTERNAL           DLARFB, DLARFT, DORMR2, XERBLA
121: *     ..
122: *     .. Intrinsic Functions ..
123:       INTRINSIC          MAX, MIN
124: *     ..
125: *     .. Executable Statements ..
126: *
127: *     Test the input arguments
128: *
129:       INFO = 0
130:       LEFT = LSAME( SIDE, 'L' )
131:       NOTRAN = LSAME( TRANS, 'N' )
132:       LQUERY = ( LWORK.EQ.-1 )
133: *
134: *     NQ is the order of Q and NW is the minimum dimension of WORK
135: *
136:       IF( LEFT ) THEN
137:          NQ = M
138:          NW = MAX( 1, N )
139:       ELSE
140:          NQ = N
141:          NW = MAX( 1, M )
142:       END IF
143:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
144:          INFO = -1
145:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
146:          INFO = -2
147:       ELSE IF( M.LT.0 ) THEN
148:          INFO = -3
149:       ELSE IF( N.LT.0 ) THEN
150:          INFO = -4
151:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
152:          INFO = -5
153:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
154:          INFO = -7
155:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
156:          INFO = -10
157:       END IF
158: *
159:       IF( INFO.EQ.0 ) THEN
160:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
161:             LWKOPT = 1
162:          ELSE
163: *
164: *           Determine the block size.  NB may be at most NBMAX, where
165: *           NBMAX is used to define the local array T.
166: *
167:             NB = MIN( NBMAX, ILAENV( 1, 'DORMRQ', SIDE // TRANS, M, N,
168:      $                               K, -1 ) )
169:             LWKOPT = NW*NB
170:          END IF
171:          WORK( 1 ) = LWKOPT
172: *
173:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
174:             INFO = -12
175:          END IF
176:       END IF
177: *
178:       IF( INFO.NE.0 ) THEN
179:          CALL XERBLA( 'DORMRQ', -INFO )
180:          RETURN
181:       ELSE IF( LQUERY ) THEN
182:          RETURN
183:       END IF
184: *
185: *     Quick return if possible
186: *
187:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
188:          RETURN
189:       END IF
190: *
191:       NBMIN = 2
192:       LDWORK = NW
193:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
194:          IWS = NW*NB
195:          IF( LWORK.LT.IWS ) THEN
196:             NB = LWORK / LDWORK
197:             NBMIN = MAX( 2, ILAENV( 2, 'DORMRQ', SIDE // TRANS, M, N, K,
198:      $              -1 ) )
199:          END IF
200:       ELSE
201:          IWS = NW
202:       END IF
203: *
204:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
205: *
206: *        Use unblocked code
207: *
208:          CALL DORMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
209:      $                IINFO )
210:       ELSE
211: *
212: *        Use blocked code
213: *
214:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
215:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
216:             I1 = 1
217:             I2 = K
218:             I3 = NB
219:          ELSE
220:             I1 = ( ( K-1 ) / NB )*NB + 1
221:             I2 = 1
222:             I3 = -NB
223:          END IF
224: *
225:          IF( LEFT ) THEN
226:             NI = N
227:          ELSE
228:             MI = M
229:          END IF
230: *
231:          IF( NOTRAN ) THEN
232:             TRANST = 'T'
233:          ELSE
234:             TRANST = 'N'
235:          END IF
236: *
237:          DO 10 I = I1, I2, I3
238:             IB = MIN( NB, K-I+1 )
239: *
240: *           Form the triangular factor of the block reflector
241: *           H = H(i+ib-1) . . . H(i+1) H(i)
242: *
243:             CALL DLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
244:      $                   A( I, 1 ), LDA, TAU( I ), T, LDT )
245:             IF( LEFT ) THEN
246: *
247: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
248: *
249:                MI = M - K + I + IB - 1
250:             ELSE
251: *
252: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
253: *
254:                NI = N - K + I + IB - 1
255:             END IF
256: *
257: *           Apply H or H'
258: *
259:             CALL DLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
260:      $                   IB, A( I, 1 ), LDA, T, LDT, C, LDC, WORK,
261:      $                   LDWORK )
262:    10    CONTINUE
263:       END IF
264:       WORK( 1 ) = LWKOPT
265:       RETURN
266: *
267: *     End of DORMRQ
268: *
269:       END
270: