001:       SUBROUTINE DORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, K, LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DORGR2 generates an m by n real matrix Q with orthonormal rows,
019: *  which is defined as the last m rows of a product of k elementary
020: *  reflectors of order n
021: *
022: *        Q  =  H(1) H(2) . . . H(k)
023: *
024: *  as returned by DGERQF.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  M       (input) INTEGER
030: *          The number of rows of the matrix Q. M >= 0.
031: *
032: *  N       (input) INTEGER
033: *          The number of columns of the matrix Q. N >= M.
034: *
035: *  K       (input) INTEGER
036: *          The number of elementary reflectors whose product defines the
037: *          matrix Q. M >= K >= 0.
038: *
039: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
040: *          On entry, the (m-k+i)-th row must contain the vector which
041: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
042: *          returned by DGERQF in the last k rows of its array argument
043: *          A.
044: *          On exit, the m by n matrix Q.
045: *
046: *  LDA     (input) INTEGER
047: *          The first dimension of the array A. LDA >= max(1,M).
048: *
049: *  TAU     (input) DOUBLE PRECISION array, dimension (K)
050: *          TAU(i) must contain the scalar factor of the elementary
051: *          reflector H(i), as returned by DGERQF.
052: *
053: *  WORK    (workspace) DOUBLE PRECISION array, dimension (M)
054: *
055: *  INFO    (output) INTEGER
056: *          = 0: successful exit
057: *          < 0: if INFO = -i, the i-th argument has an illegal value
058: *
059: *  =====================================================================
060: *
061: *     .. Parameters ..
062:       DOUBLE PRECISION   ONE, ZERO
063:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
064: *     ..
065: *     .. Local Scalars ..
066:       INTEGER            I, II, J, L
067: *     ..
068: *     .. External Subroutines ..
069:       EXTERNAL           DLARF, DSCAL, XERBLA
070: *     ..
071: *     .. Intrinsic Functions ..
072:       INTRINSIC          MAX
073: *     ..
074: *     .. Executable Statements ..
075: *
076: *     Test the input arguments
077: *
078:       INFO = 0
079:       IF( M.LT.0 ) THEN
080:          INFO = -1
081:       ELSE IF( N.LT.M ) THEN
082:          INFO = -2
083:       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
084:          INFO = -3
085:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
086:          INFO = -5
087:       END IF
088:       IF( INFO.NE.0 ) THEN
089:          CALL XERBLA( 'DORGR2', -INFO )
090:          RETURN
091:       END IF
092: *
093: *     Quick return if possible
094: *
095:       IF( M.LE.0 )
096:      $   RETURN
097: *
098:       IF( K.LT.M ) THEN
099: *
100: *        Initialise rows 1:m-k to rows of the unit matrix
101: *
102:          DO 20 J = 1, N
103:             DO 10 L = 1, M - K
104:                A( L, J ) = ZERO
105:    10       CONTINUE
106:             IF( J.GT.N-M .AND. J.LE.N-K )
107:      $         A( M-N+J, J ) = ONE
108:    20    CONTINUE
109:       END IF
110: *
111:       DO 40 I = 1, K
112:          II = M - K + I
113: *
114: *        Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
115: *
116:          A( II, N-M+II ) = ONE
117:          CALL DLARF( 'Right', II-1, N-M+II, A( II, 1 ), LDA, TAU( I ),
118:      $               A, LDA, WORK )
119:          CALL DSCAL( N-M+II-1, -TAU( I ), A( II, 1 ), LDA )
120:          A( II, N-M+II ) = ONE - TAU( I )
121: *
122: *        Set A(m-k+i,n-k+i+1:n) to zero
123: *
124:          DO 30 L = N - M + II + 1, N
125:             A( II, L ) = ZERO
126:    30    CONTINUE
127:    40 CONTINUE
128:       RETURN
129: *
130: *     End of DORGR2
131: *
132:       END
133: