001:       SUBROUTINE DLA_GBAMV( TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X,
002:      $                      INCX, BETA, Y, INCY )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       DOUBLE PRECISION   ALPHA, BETA
016:       INTEGER            INCX, INCY, LDAB, M, N, KL, KU, TRANS
017: *     ..
018: *     .. Array Arguments ..
019:       DOUBLE PRECISION   AB( LDAB, * ), X( * ), Y( * )
020: *     ..
021: *
022: *  Purpose
023: *  =======
024: *
025: *  DLA_GBAMV  performs one of the matrix-vector operations
026: *
027: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
028: *     or   y := alpha*abs(A)'*abs(x) + beta*abs(y),
029: *
030: *  where alpha and beta are scalars, x and y are vectors and A is an
031: *  m by n matrix.
032: *
033: *  This function is primarily used in calculating error bounds.
034: *  To protect against underflow during evaluation, components in
035: *  the resulting vector are perturbed away from zero by (N+1)
036: *  times the underflow threshold.  To prevent unnecessarily large
037: *  errors for block-structure embedded in general matrices,
038: *  "symbolically" zero components are not perturbed.  A zero
039: *  entry is considered "symbolic" if all multiplications involved
040: *  in computing that entry have at least one zero multiplicand.
041: *
042: *  Arguments
043: *  ==========
044: *
045: *  TRANS  - INTEGER
046: *           On entry, TRANS specifies the operation to be performed as
047: *           follows:
048: *
049: *             BLAS_NO_TRANS      y := alpha*abs(A)*abs(x) + beta*abs(y)
050: *             BLAS_TRANS         y := alpha*abs(A')*abs(x) + beta*abs(y)
051: *             BLAS_CONJ_TRANS    y := alpha*abs(A')*abs(x) + beta*abs(y)
052: *
053: *           Unchanged on exit.
054: *
055: *  M      - INTEGER
056: *           On entry, M specifies the number of rows of the matrix A.
057: *           M must be at least zero.
058: *           Unchanged on exit.
059: *
060: *  N      - INTEGER
061: *           On entry, N specifies the number of columns of the matrix A.
062: *           N must be at least zero.
063: *           Unchanged on exit.
064: *
065: *  KL     - INTEGER
066: *           The number of subdiagonals within the band of A.  KL >= 0.
067: *
068: *  KU     - INTEGER
069: *           The number of superdiagonals within the band of A.  KU >= 0.
070: *
071: *  ALPHA  - DOUBLE PRECISION
072: *           On entry, ALPHA specifies the scalar alpha.
073: *           Unchanged on exit.
074: *
075: *  A      - DOUBLE PRECISION   array of DIMENSION ( LDA, n )
076: *           Before entry, the leading m by n part of the array A must
077: *           contain the matrix of coefficients.
078: *           Unchanged on exit.
079: *
080: *  LDA    - INTEGER
081: *           On entry, LDA specifies the first dimension of A as declared
082: *           in the calling (sub) program. LDA must be at least
083: *           max( 1, m ).
084: *           Unchanged on exit.
085: *
086: *  X      - DOUBLE PRECISION   array of DIMENSION at least
087: *           ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
088: *           and at least
089: *           ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
090: *           Before entry, the incremented array X must contain the
091: *           vector x.
092: *           Unchanged on exit.
093: *
094: *  INCX   - INTEGER
095: *           On entry, INCX specifies the increment for the elements of
096: *           X. INCX must not be zero.
097: *           Unchanged on exit.
098: *
099: *  BETA   - DOUBLE PRECISION
100: *           On entry, BETA specifies the scalar beta. When BETA is
101: *           supplied as zero then Y need not be set on input.
102: *           Unchanged on exit.
103: *
104: *  Y      - DOUBLE PRECISION   array of DIMENSION at least
105: *           ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
106: *           and at least
107: *           ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
108: *           Before entry with BETA non-zero, the incremented array Y
109: *           must contain the vector y. On exit, Y is overwritten by the
110: *           updated vector y.
111: *
112: *  INCY   - INTEGER
113: *           On entry, INCY specifies the increment for the elements of
114: *           Y. INCY must not be zero.
115: *           Unchanged on exit.
116: *
117: *
118: *  Level 2 Blas routine.
119: *
120: *  =====================================================================
121: 
122: *     .. Parameters ..
123:       DOUBLE PRECISION   ONE, ZERO
124:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
125: *     ..
126: *     .. Local Scalars ..
127:       LOGICAL            SYMB_ZERO
128:       DOUBLE PRECISION   TEMP, SAFE1
129:       INTEGER            I, INFO, IY, J, JX, KX, KY, LENX, LENY, KD, KE
130: *     ..
131: *     .. External Subroutines ..
132:       EXTERNAL           XERBLA, DLAMCH
133:       DOUBLE PRECISION   DLAMCH
134: *     ..
135: *     .. External Functions ..
136:       EXTERNAL           ILATRANS
137:       INTEGER            ILATRANS
138: *     ..
139: *     .. Intrinsic Functions ..
140:       INTRINSIC          MAX, ABS, SIGN
141: *     ..
142: *     .. Executable Statements ..
143: *
144: *     Test the input parameters.
145: *
146:       INFO = 0
147:       IF     ( .NOT.( ( TRANS.EQ.ILATRANS( 'N' ) )
148:      $           .OR. ( TRANS.EQ.ILATRANS( 'T' ) )
149:      $           .OR. ( TRANS.EQ.ILATRANS( 'C' ) ) ) ) THEN
150:          INFO = 1
151:       ELSE IF( M.LT.0 )THEN
152:          INFO = 2
153:       ELSE IF( N.LT.0 )THEN
154:          INFO = 3
155:       ELSE IF( KL.LT.0 .OR. KL.GT.M-1 ) THEN
156:          INFO = 4
157:       ELSE IF( KU.LT.0 .OR. KU.GT.N-1 ) THEN
158:          INFO = 5
159:       ELSE IF( LDAB.LT.KL+KU+1 )THEN
160:          INFO = 6
161:       ELSE IF( INCX.EQ.0 )THEN
162:          INFO = 8
163:       ELSE IF( INCY.EQ.0 )THEN
164:          INFO = 11
165:       END IF
166:       IF( INFO.NE.0 )THEN
167:          CALL XERBLA( 'DLA_GBAMV ', INFO )
168:          RETURN
169:       END IF
170: *
171: *     Quick return if possible.
172: *
173:       IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
174:      $    ( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
175:      $   RETURN
176: *
177: *     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
178: *     up the start points in  X  and  Y.
179: *
180:       IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
181:          LENX = N
182:          LENY = M
183:       ELSE
184:          LENX = M
185:          LENY = N
186:       END IF
187:       IF( INCX.GT.0 )THEN
188:          KX = 1
189:       ELSE
190:          KX = 1 - ( LENX - 1 )*INCX
191:       END IF
192:       IF( INCY.GT.0 )THEN
193:          KY = 1
194:       ELSE
195:          KY = 1 - ( LENY - 1 )*INCY
196:       END IF
197: *
198: *     Set SAFE1 essentially to be the underflow threshold times the
199: *     number of additions in each row.
200: *
201:       SAFE1 = DLAMCH( 'Safe minimum' )
202:       SAFE1 = (N+1)*SAFE1
203: *
204: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
205: *
206: *     The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
207: *     the inexact flag.  Still doesn't help change the iteration order
208: *     to per-column.
209: *
210:       KD = KU + 1
211:       KE = KL + 1
212:       IY = KY
213:       IF ( INCX.EQ.1 ) THEN
214:          IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
215:             DO I = 1, LENY
216:                IF ( BETA .EQ. ZERO ) THEN
217:                   SYMB_ZERO = .TRUE.
218:                   Y( IY ) = 0.0D+0
219:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
220:                   SYMB_ZERO = .TRUE.
221:                ELSE
222:                   SYMB_ZERO = .FALSE.
223:                   Y( IY ) = BETA * ABS( Y( IY ) )
224:                END IF
225:                IF ( ALPHA .NE. ZERO ) THEN
226:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, LENX )
227:                      TEMP = ABS( AB( KD+I-J, J ) )
228:                      SYMB_ZERO = SYMB_ZERO .AND.
229:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
230: 
231:                      Y( IY ) = Y( IY ) + ALPHA*ABS( X( J ) )*TEMP
232:                   END DO
233:                END IF
234: 
235:                IF ( .NOT.SYMB_ZERO )
236:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
237:                IY = IY + INCY
238:             END DO
239:          ELSE
240:             DO I = 1, LENY
241:                IF ( BETA .EQ. ZERO ) THEN
242:                   SYMB_ZERO = .TRUE.
243:                   Y( IY ) = 0.0D+0
244:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
245:                   SYMB_ZERO = .TRUE.
246:                ELSE
247:                   SYMB_ZERO = .FALSE.
248:                   Y( IY ) = BETA * ABS( Y( IY ) )
249:                END IF
250:                IF ( ALPHA .NE. ZERO ) THEN
251:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, LENX )
252:                      TEMP = ABS( AB( KE-I+J, I ) )
253:                      SYMB_ZERO = SYMB_ZERO .AND.
254:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
255: 
256:                      Y( IY ) = Y( IY ) + ALPHA*ABS( X( J ) )*TEMP
257:                   END DO
258:                END IF
259: 
260:                IF ( .NOT.SYMB_ZERO )
261:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
262:                IY = IY + INCY
263:             END DO
264:          END IF
265:       ELSE
266:          IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
267:             DO I = 1, LENY
268:                IF ( BETA .EQ. ZERO ) THEN
269:                   SYMB_ZERO = .TRUE.
270:                   Y( IY ) = 0.0D+0
271:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
272:                   SYMB_ZERO = .TRUE.
273:                ELSE
274:                   SYMB_ZERO = .FALSE.
275:                   Y( IY ) = BETA * ABS( Y( IY ) )
276:                END IF
277:                IF ( ALPHA .NE. ZERO ) THEN
278:                   JX = KX
279:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, LENX )
280:                      TEMP = ABS( AB( KD+I-J, J ) )
281:                      SYMB_ZERO = SYMB_ZERO .AND.
282:      $                    ( X( JX ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
283: 
284:                      Y( IY ) = Y( IY ) + ALPHA*ABS( X( JX ) )*TEMP
285:                      JX = JX + INCX
286:                   END DO
287:                END IF
288: 
289:                IF ( .NOT.SYMB_ZERO )
290:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
291: 
292:                IY = IY + INCY
293:             END DO
294:          ELSE
295:             DO I = 1, LENY
296:                IF ( BETA .EQ. ZERO ) THEN
297:                   SYMB_ZERO = .TRUE.
298:                   Y( IY ) = 0.0D+0
299:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
300:                   SYMB_ZERO = .TRUE.
301:                ELSE
302:                   SYMB_ZERO = .FALSE.
303:                   Y( IY ) = BETA * ABS( Y( IY ) )
304:                END IF
305:                IF ( ALPHA .NE. ZERO ) THEN
306:                   JX = KX
307:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, LENX )
308:                      TEMP = ABS( AB( KE-I+J, I ) )
309:                      SYMB_ZERO = SYMB_ZERO .AND.
310:      $                    ( X( JX ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
311: 
312:                      Y( IY ) = Y( IY ) + ALPHA*ABS( X( JX ) )*TEMP
313:                      JX = JX + INCX
314:                   END DO
315:                END IF
316: 
317:                IF ( .NOT.SYMB_ZERO )
318:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
319: 
320:                IY = IY + INCY
321:             END DO
322:          END IF
323: 
324:       END IF
325: *
326:       RETURN
327: *
328: *     End of DLA_GBAMV
329: *
330:       END
331: