001:       SUBROUTINE DGEQL2( M, N, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DGEQL2 computes a QL factorization of a real m by n matrix A:
019: *  A = Q * L.
020: *
021: *  Arguments
022: *  =========
023: *
024: *  M       (input) INTEGER
025: *          The number of rows of the matrix A.  M >= 0.
026: *
027: *  N       (input) INTEGER
028: *          The number of columns of the matrix A.  N >= 0.
029: *
030: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
031: *          On entry, the m by n matrix A.
032: *          On exit, if m >= n, the lower triangle of the subarray
033: *          A(m-n+1:m,1:n) contains the n by n lower triangular matrix L;
034: *          if m <= n, the elements on and below the (n-m)-th
035: *          superdiagonal contain the m by n lower trapezoidal matrix L;
036: *          the remaining elements, with the array TAU, represent the
037: *          orthogonal matrix Q as a product of elementary reflectors
038: *          (see Further Details).
039: *
040: *  LDA     (input) INTEGER
041: *          The leading dimension of the array A.  LDA >= max(1,M).
042: *
043: *  TAU     (output) DOUBLE PRECISION array, dimension (min(M,N))
044: *          The scalar factors of the elementary reflectors (see Further
045: *          Details).
046: *
047: *  WORK    (workspace) DOUBLE PRECISION array, dimension (N)
048: *
049: *  INFO    (output) INTEGER
050: *          = 0: successful exit
051: *          < 0: if INFO = -i, the i-th argument had an illegal value
052: *
053: *  Further Details
054: *  ===============
055: *
056: *  The matrix Q is represented as a product of elementary reflectors
057: *
058: *     Q = H(k) . . . H(2) H(1), where k = min(m,n).
059: *
060: *  Each H(i) has the form
061: *
062: *     H(i) = I - tau * v * v'
063: *
064: *  where tau is a real scalar, and v is a real vector with
065: *  v(m-k+i+1:m) = 0 and v(m-k+i) = 1; v(1:m-k+i-1) is stored on exit in
066: *  A(1:m-k+i-1,n-k+i), and tau in TAU(i).
067: *
068: *  =====================================================================
069: *
070: *     .. Parameters ..
071:       DOUBLE PRECISION   ONE
072:       PARAMETER          ( ONE = 1.0D+0 )
073: *     ..
074: *     .. Local Scalars ..
075:       INTEGER            I, K
076:       DOUBLE PRECISION   AII
077: *     ..
078: *     .. External Subroutines ..
079:       EXTERNAL           DLARF, DLARFP, XERBLA
080: *     ..
081: *     .. Intrinsic Functions ..
082:       INTRINSIC          MAX, MIN
083: *     ..
084: *     .. Executable Statements ..
085: *
086: *     Test the input arguments
087: *
088:       INFO = 0
089:       IF( M.LT.0 ) THEN
090:          INFO = -1
091:       ELSE IF( N.LT.0 ) THEN
092:          INFO = -2
093:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
094:          INFO = -4
095:       END IF
096:       IF( INFO.NE.0 ) THEN
097:          CALL XERBLA( 'DGEQL2', -INFO )
098:          RETURN
099:       END IF
100: *
101:       K = MIN( M, N )
102: *
103:       DO 10 I = K, 1, -1
104: *
105: *        Generate elementary reflector H(i) to annihilate
106: *        A(1:m-k+i-1,n-k+i)
107: *
108:          CALL DLARFP( M-K+I, A( M-K+I, N-K+I ), A( 1, N-K+I ), 1,
109:      $                TAU( I ) )
110: *
111: *        Apply H(i) to A(1:m-k+i,1:n-k+i-1) from the left
112: *
113:          AII = A( M-K+I, N-K+I )
114:          A( M-K+I, N-K+I ) = ONE
115:          CALL DLARF( 'Left', M-K+I, N-K+I-1, A( 1, N-K+I ), 1, TAU( I ),
116:      $               A, LDA, WORK )
117:          A( M-K+I, N-K+I ) = AII
118:    10 CONTINUE
119:       RETURN
120: *
121: *     End of DGEQL2
122: *
123:       END
124: