001:       SUBROUTINE CUNG2R( M, N, K, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, K, LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CUNG2R generates an m by n complex matrix Q with orthonormal columns,
019: *  which is defined as the first n columns of a product of k elementary
020: *  reflectors of order m
021: *
022: *        Q  =  H(1) H(2) . . . H(k)
023: *
024: *  as returned by CGEQRF.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  M       (input) INTEGER
030: *          The number of rows of the matrix Q. M >= 0.
031: *
032: *  N       (input) INTEGER
033: *          The number of columns of the matrix Q. M >= N >= 0.
034: *
035: *  K       (input) INTEGER
036: *          The number of elementary reflectors whose product defines the
037: *          matrix Q. N >= K >= 0.
038: *
039: *  A       (input/output) COMPLEX array, dimension (LDA,N)
040: *          On entry, the i-th column must contain the vector which
041: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
042: *          returned by CGEQRF in the first k columns of its array
043: *          argument A.
044: *          On exit, the m by n matrix Q.
045: *
046: *  LDA     (input) INTEGER
047: *          The first dimension of the array A. LDA >= max(1,M).
048: *
049: *  TAU     (input) COMPLEX array, dimension (K)
050: *          TAU(i) must contain the scalar factor of the elementary
051: *          reflector H(i), as returned by CGEQRF.
052: *
053: *  WORK    (workspace) COMPLEX array, dimension (N)
054: *
055: *  INFO    (output) INTEGER
056: *          = 0: successful exit
057: *          < 0: if INFO = -i, the i-th argument has an illegal value
058: *
059: *  =====================================================================
060: *
061: *     .. Parameters ..
062:       COMPLEX            ONE, ZERO
063:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
064:      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
065: *     ..
066: *     .. Local Scalars ..
067:       INTEGER            I, J, L
068: *     ..
069: *     .. External Subroutines ..
070:       EXTERNAL           CLARF, CSCAL, XERBLA
071: *     ..
072: *     .. Intrinsic Functions ..
073:       INTRINSIC          MAX
074: *     ..
075: *     .. Executable Statements ..
076: *
077: *     Test the input arguments
078: *
079:       INFO = 0
080:       IF( M.LT.0 ) THEN
081:          INFO = -1
082:       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
083:          INFO = -2
084:       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
085:          INFO = -3
086:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
087:          INFO = -5
088:       END IF
089:       IF( INFO.NE.0 ) THEN
090:          CALL XERBLA( 'CUNG2R', -INFO )
091:          RETURN
092:       END IF
093: *
094: *     Quick return if possible
095: *
096:       IF( N.LE.0 )
097:      $   RETURN
098: *
099: *     Initialise columns k+1:n to columns of the unit matrix
100: *
101:       DO 20 J = K + 1, N
102:          DO 10 L = 1, M
103:             A( L, J ) = ZERO
104:    10    CONTINUE
105:          A( J, J ) = ONE
106:    20 CONTINUE
107: *
108:       DO 40 I = K, 1, -1
109: *
110: *        Apply H(i) to A(i:m,i:n) from the left
111: *
112:          IF( I.LT.N ) THEN
113:             A( I, I ) = ONE
114:             CALL CLARF( 'Left', M-I+1, N-I, A( I, I ), 1, TAU( I ),
115:      $                  A( I, I+1 ), LDA, WORK )
116:          END IF
117:          IF( I.LT.M )
118:      $      CALL CSCAL( M-I, -TAU( I ), A( I+1, I ), 1 )
119:          A( I, I ) = ONE - TAU( I )
120: *
121: *        Set A(1:i-1,i) to zero
122: *
123:          DO 30 L = 1, I - 1
124:             A( L, I ) = ZERO
125:    30    CONTINUE
126:    40 CONTINUE
127:       RETURN
128: *
129: *     End of CUNG2R
130: *
131:       END
132: