001:       SUBROUTINE CSYTRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, LWORK, N
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            IPIV( * )
014:       COMPLEX            A( LDA, * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CSYTRF computes the factorization of a complex symmetric matrix A
021: *  using the Bunch-Kaufman diagonal pivoting method.  The form of the
022: *  factorization is
023: *
024: *     A = U*D*U**T  or  A = L*D*L**T
025: *
026: *  where U (or L) is a product of permutation and unit upper (lower)
027: *  triangular matrices, and D is symmetric and block diagonal with
028: *  with 1-by-1 and 2-by-2 diagonal blocks.
029: *
030: *  This is the blocked version of the algorithm, calling Level 3 BLAS.
031: *
032: *  Arguments
033: *  =========
034: *
035: *  UPLO    (input) CHARACTER*1
036: *          = 'U':  Upper triangle of A is stored;
037: *          = 'L':  Lower triangle of A is stored.
038: *
039: *  N       (input) INTEGER
040: *          The order of the matrix A.  N >= 0.
041: *
042: *  A       (input/output) COMPLEX array, dimension (LDA,N)
043: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
044: *          N-by-N upper triangular part of A contains the upper
045: *          triangular part of the matrix A, and the strictly lower
046: *          triangular part of A is not referenced.  If UPLO = 'L', the
047: *          leading N-by-N lower triangular part of A contains the lower
048: *          triangular part of the matrix A, and the strictly upper
049: *          triangular part of A is not referenced.
050: *
051: *          On exit, the block diagonal matrix D and the multipliers used
052: *          to obtain the factor U or L (see below for further details).
053: *
054: *  LDA     (input) INTEGER
055: *          The leading dimension of the array A.  LDA >= max(1,N).
056: *
057: *  IPIV    (output) INTEGER array, dimension (N)
058: *          Details of the interchanges and the block structure of D.
059: *          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
060: *          interchanged and D(k,k) is a 1-by-1 diagonal block.
061: *          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
062: *          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
063: *          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
064: *          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
065: *          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
066: *
067: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
068: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
069: *
070: *  LWORK   (input) INTEGER
071: *          The length of WORK.  LWORK >=1.  For best performance
072: *          LWORK >= N*NB, where NB is the block size returned by ILAENV.
073: *
074: *          If LWORK = -1, then a workspace query is assumed; the routine
075: *          only calculates the optimal size of the WORK array, returns
076: *          this value as the first entry of the WORK array, and no error
077: *          message related to LWORK is issued by XERBLA.
078: *
079: *  INFO    (output) INTEGER
080: *          = 0:  successful exit
081: *          < 0:  if INFO = -i, the i-th argument had an illegal value
082: *          > 0:  if INFO = i, D(i,i) is exactly zero.  The factorization
083: *                has been completed, but the block diagonal matrix D is
084: *                exactly singular, and division by zero will occur if it
085: *                is used to solve a system of equations.
086: *
087: *  Further Details
088: *  ===============
089: *
090: *  If UPLO = 'U', then A = U*D*U', where
091: *     U = P(n)*U(n)* ... *P(k)U(k)* ...,
092: *  i.e., U is a product of terms P(k)*U(k), where k decreases from n to
093: *  1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
094: *  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
095: *  defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
096: *  that if the diagonal block D(k) is of order s (s = 1 or 2), then
097: *
098: *             (   I    v    0   )   k-s
099: *     U(k) =  (   0    I    0   )   s
100: *             (   0    0    I   )   n-k
101: *                k-s   s   n-k
102: *
103: *  If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
104: *  If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
105: *  and A(k,k), and v overwrites A(1:k-2,k-1:k).
106: *
107: *  If UPLO = 'L', then A = L*D*L', where
108: *     L = P(1)*L(1)* ... *P(k)*L(k)* ...,
109: *  i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
110: *  n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
111: *  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
112: *  defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
113: *  that if the diagonal block D(k) is of order s (s = 1 or 2), then
114: *
115: *             (   I    0     0   )  k-1
116: *     L(k) =  (   0    I     0   )  s
117: *             (   0    v     I   )  n-k-s+1
118: *                k-1   s  n-k-s+1
119: *
120: *  If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
121: *  If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
122: *  and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
123: *
124: *  =====================================================================
125: *
126: *     .. Local Scalars ..
127:       LOGICAL            LQUERY, UPPER
128:       INTEGER            IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
129: *     ..
130: *     .. External Functions ..
131:       LOGICAL            LSAME
132:       INTEGER            ILAENV
133:       EXTERNAL           LSAME, ILAENV
134: *     ..
135: *     .. External Subroutines ..
136:       EXTERNAL           CLASYF, CSYTF2, XERBLA
137: *     ..
138: *     .. Intrinsic Functions ..
139:       INTRINSIC          MAX
140: *     ..
141: *     .. Executable Statements ..
142: *
143: *     Test the input parameters.
144: *
145:       INFO = 0
146:       UPPER = LSAME( UPLO, 'U' )
147:       LQUERY = ( LWORK.EQ.-1 )
148:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
149:          INFO = -1
150:       ELSE IF( N.LT.0 ) THEN
151:          INFO = -2
152:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
153:          INFO = -4
154:       ELSE IF( LWORK.LT.1 .AND. .NOT.LQUERY ) THEN
155:          INFO = -7
156:       END IF
157: *
158:       IF( INFO.EQ.0 ) THEN
159: *
160: *        Determine the block size
161: *
162:          NB = ILAENV( 1, 'CSYTRF', UPLO, N, -1, -1, -1 )
163:          LWKOPT = N*NB
164:          WORK( 1 ) = LWKOPT
165:       END IF
166: *
167:       IF( INFO.NE.0 ) THEN
168:          CALL XERBLA( 'CSYTRF', -INFO )
169:          RETURN
170:       ELSE IF( LQUERY ) THEN
171:          RETURN
172:       END IF
173: *
174:       NBMIN = 2
175:       LDWORK = N
176:       IF( NB.GT.1 .AND. NB.LT.N ) THEN
177:          IWS = LDWORK*NB
178:          IF( LWORK.LT.IWS ) THEN
179:             NB = MAX( LWORK / LDWORK, 1 )
180:             NBMIN = MAX( 2, ILAENV( 2, 'CSYTRF', UPLO, N, -1, -1, -1 ) )
181:          END IF
182:       ELSE
183:          IWS = 1
184:       END IF
185:       IF( NB.LT.NBMIN )
186:      $   NB = N
187: *
188:       IF( UPPER ) THEN
189: *
190: *        Factorize A as U*D*U' using the upper triangle of A
191: *
192: *        K is the main loop index, decreasing from N to 1 in steps of
193: *        KB, where KB is the number of columns factorized by CLASYF;
194: *        KB is either NB or NB-1, or K for the last block
195: *
196:          K = N
197:    10    CONTINUE
198: *
199: *        If K < 1, exit from loop
200: *
201:          IF( K.LT.1 )
202:      $      GO TO 40
203: *
204:          IF( K.GT.NB ) THEN
205: *
206: *           Factorize columns k-kb+1:k of A and use blocked code to
207: *           update columns 1:k-kb
208: *
209:             CALL CLASYF( UPLO, K, NB, KB, A, LDA, IPIV, WORK, N, IINFO )
210:          ELSE
211: *
212: *           Use unblocked code to factorize columns 1:k of A
213: *
214:             CALL CSYTF2( UPLO, K, A, LDA, IPIV, IINFO )
215:             KB = K
216:          END IF
217: *
218: *        Set INFO on the first occurrence of a zero pivot
219: *
220:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
221:      $      INFO = IINFO
222: *
223: *        Decrease K and return to the start of the main loop
224: *
225:          K = K - KB
226:          GO TO 10
227: *
228:       ELSE
229: *
230: *        Factorize A as L*D*L' using the lower triangle of A
231: *
232: *        K is the main loop index, increasing from 1 to N in steps of
233: *        KB, where KB is the number of columns factorized by CLASYF;
234: *        KB is either NB or NB-1, or N-K+1 for the last block
235: *
236:          K = 1
237:    20    CONTINUE
238: *
239: *        If K > N, exit from loop
240: *
241:          IF( K.GT.N )
242:      $      GO TO 40
243: *
244:          IF( K.LE.N-NB ) THEN
245: *
246: *           Factorize columns k:k+kb-1 of A and use blocked code to
247: *           update columns k+kb:n
248: *
249:             CALL CLASYF( UPLO, N-K+1, NB, KB, A( K, K ), LDA, IPIV( K ),
250:      $                   WORK, N, IINFO )
251:          ELSE
252: *
253: *           Use unblocked code to factorize columns k:n of A
254: *
255:             CALL CSYTF2( UPLO, N-K+1, A( K, K ), LDA, IPIV( K ), IINFO )
256:             KB = N - K + 1
257:          END IF
258: *
259: *        Set INFO on the first occurrence of a zero pivot
260: *
261:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
262:      $      INFO = IINFO + K - 1
263: *
264: *        Adjust IPIV
265: *
266:          DO 30 J = K, K + KB - 1
267:             IF( IPIV( J ).GT.0 ) THEN
268:                IPIV( J ) = IPIV( J ) + K - 1
269:             ELSE
270:                IPIV( J ) = IPIV( J ) - K + 1
271:             END IF
272:    30    CONTINUE
273: *
274: *        Increase K and return to the start of the main loop
275: *
276:          K = K + KB
277:          GO TO 20
278: *
279:       END IF
280: *
281:    40 CONTINUE
282:       WORK( 1 ) = LWKOPT
283:       RETURN
284: *
285: *     End of CSYTRF
286: *
287:       END
288: