001:       SUBROUTINE CLAUU2( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CLAUU2 computes the product U * U' or L' * L, where the triangular
020: *  factor U or L is stored in the upper or lower triangular part of
021: *  the array A.
022: *
023: *  If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
024: *  overwriting the factor U in A.
025: *  If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
026: *  overwriting the factor L in A.
027: *
028: *  This is the unblocked form of the algorithm, calling Level 2 BLAS.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  UPLO    (input) CHARACTER*1
034: *          Specifies whether the triangular factor stored in the array A
035: *          is upper or lower triangular:
036: *          = 'U':  Upper triangular
037: *          = 'L':  Lower triangular
038: *
039: *  N       (input) INTEGER
040: *          The order of the triangular factor U or L.  N >= 0.
041: *
042: *  A       (input/output) COMPLEX array, dimension (LDA,N)
043: *          On entry, the triangular factor U or L.
044: *          On exit, if UPLO = 'U', the upper triangle of A is
045: *          overwritten with the upper triangle of the product U * U';
046: *          if UPLO = 'L', the lower triangle of A is overwritten with
047: *          the lower triangle of the product L' * L.
048: *
049: *  LDA     (input) INTEGER
050: *          The leading dimension of the array A.  LDA >= max(1,N).
051: *
052: *  INFO    (output) INTEGER
053: *          = 0: successful exit
054: *          < 0: if INFO = -k, the k-th argument had an illegal value
055: *
056: *  =====================================================================
057: *
058: *     .. Parameters ..
059:       COMPLEX            ONE
060:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
061: *     ..
062: *     .. Local Scalars ..
063:       LOGICAL            UPPER
064:       INTEGER            I
065:       REAL               AII
066: *     ..
067: *     .. External Functions ..
068:       LOGICAL            LSAME
069:       COMPLEX            CDOTC
070:       EXTERNAL           LSAME, CDOTC
071: *     ..
072: *     .. External Subroutines ..
073:       EXTERNAL           CGEMV, CLACGV, CSSCAL, XERBLA
074: *     ..
075: *     .. Intrinsic Functions ..
076:       INTRINSIC          CMPLX, MAX, REAL
077: *     ..
078: *     .. Executable Statements ..
079: *
080: *     Test the input parameters.
081: *
082:       INFO = 0
083:       UPPER = LSAME( UPLO, 'U' )
084:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
085:          INFO = -1
086:       ELSE IF( N.LT.0 ) THEN
087:          INFO = -2
088:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
089:          INFO = -4
090:       END IF
091:       IF( INFO.NE.0 ) THEN
092:          CALL XERBLA( 'CLAUU2', -INFO )
093:          RETURN
094:       END IF
095: *
096: *     Quick return if possible
097: *
098:       IF( N.EQ.0 )
099:      $   RETURN
100: *
101:       IF( UPPER ) THEN
102: *
103: *        Compute the product U * U'.
104: *
105:          DO 10 I = 1, N
106:             AII = A( I, I )
107:             IF( I.LT.N ) THEN
108:                A( I, I ) = AII*AII + REAL( CDOTC( N-I, A( I, I+1 ), LDA,
109:      $                     A( I, I+1 ), LDA ) )
110:                CALL CLACGV( N-I, A( I, I+1 ), LDA )
111:                CALL CGEMV( 'No transpose', I-1, N-I, ONE, A( 1, I+1 ),
112:      $                     LDA, A( I, I+1 ), LDA, CMPLX( AII ),
113:      $                     A( 1, I ), 1 )
114:                CALL CLACGV( N-I, A( I, I+1 ), LDA )
115:             ELSE
116:                CALL CSSCAL( I, AII, A( 1, I ), 1 )
117:             END IF
118:    10    CONTINUE
119: *
120:       ELSE
121: *
122: *        Compute the product L' * L.
123: *
124:          DO 20 I = 1, N
125:             AII = A( I, I )
126:             IF( I.LT.N ) THEN
127:                A( I, I ) = AII*AII + REAL( CDOTC( N-I, A( I+1, I ), 1,
128:      $                     A( I+1, I ), 1 ) )
129:                CALL CLACGV( I-1, A( I, 1 ), LDA )
130:                CALL CGEMV( 'Conjugate transpose', N-I, I-1, ONE,
131:      $                     A( I+1, 1 ), LDA, A( I+1, I ), 1,
132:      $                     CMPLX( AII ), A( I, 1 ), LDA )
133:                CALL CLACGV( I-1, A( I, 1 ), LDA )
134:             ELSE
135:                CALL CSSCAL( I, AII, A( I, 1 ), LDA )
136:             END IF
137:    20    CONTINUE
138:       END IF
139: *
140:       RETURN
141: *
142: *     End of CLAUU2
143: *
144:       END
145: