001:       SUBROUTINE CLA_SYAMV( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
002:      $                      INCY )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       REAL               ALPHA, BETA
016:       INTEGER            INCX, INCY, LDA, N
017:       INTEGER            UPLO
018: *     ..
019: *     .. Array Arguments ..
020:       COMPLEX            A( LDA, * ), X( * )
021:       REAL               Y( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *  CLA_SYAMV  performs the matrix-vector operation
028: *
029: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
030: *
031: *  where alpha and beta are scalars, x and y are vectors and A is an
032: *  n by n symmetric matrix.
033: *
034: *  This function is primarily used in calculating error bounds.
035: *  To protect against underflow during evaluation, components in
036: *  the resulting vector are perturbed away from zero by (N+1)
037: *  times the underflow threshold.  To prevent unnecessarily large
038: *  errors for block-structure embedded in general matrices,
039: *  "symbolically" zero components are not perturbed.  A zero
040: *  entry is considered "symbolic" if all multiplications involved
041: *  in computing that entry have at least one zero multiplicand.
042: *
043: *  Arguments
044: *  ==========
045: *
046: *  UPLO   - INTEGER
047: *           On entry, UPLO specifies whether the upper or lower
048: *           triangular part of the array A is to be referenced as
049: *           follows:
050: *
051: *              UPLO = BLAS_UPPER   Only the upper triangular part of A
052: *                                  is to be referenced.
053: *
054: *              UPLO = BLAS_LOWER   Only the lower triangular part of A
055: *                                  is to be referenced.
056: *
057: *           Unchanged on exit.
058: *
059: *  N      - INTEGER.
060: *           On entry, N specifies the number of columns of the matrix A.
061: *           N must be at least zero.
062: *           Unchanged on exit.
063: *
064: *  ALPHA  - REAL            .
065: *           On entry, ALPHA specifies the scalar alpha.
066: *           Unchanged on exit.
067: *
068: *  A      - COMPLEX             array of DIMENSION ( LDA, n ).
069: *           Before entry, the leading m by n part of the array A must
070: *           contain the matrix of coefficients.
071: *           Unchanged on exit.
072: *
073: *  LDA    - INTEGER.
074: *           On entry, LDA specifies the first dimension of A as declared
075: *           in the calling (sub) program. LDA must be at least
076: *           max( 1, n ).
077: *           Unchanged on exit.
078: *
079: *  X      - COMPLEX             array of DIMENSION at least
080: *           ( 1 + ( n - 1 )*abs( INCX ) )
081: *           Before entry, the incremented array X must contain the
082: *           vector x.
083: *           Unchanged on exit.
084: *
085: *  INCX   - INTEGER.
086: *           On entry, INCX specifies the increment for the elements of
087: *           X. INCX must not be zero.
088: *           Unchanged on exit.
089: *
090: *  BETA   - REAL            .
091: *           On entry, BETA specifies the scalar beta. When BETA is
092: *           supplied as zero then Y need not be set on input.
093: *           Unchanged on exit.
094: *
095: *  Y      - REAL             array of DIMENSION at least
096: *           ( 1 + ( n - 1 )*abs( INCY ) )
097: *           Before entry with BETA non-zero, the incremented array Y
098: *           must contain the vector y. On exit, Y is overwritten by the
099: *           updated vector y.
100: *
101: *  INCY   - INTEGER.
102: *           On entry, INCY specifies the increment for the elements of
103: *           Y. INCY must not be zero.
104: *           Unchanged on exit.
105: *
106: *  Further Details
107: *  ===============
108: *
109: *  Level 2 Blas routine.
110: *
111: *  -- Written on 22-October-1986.
112: *     Jack Dongarra, Argonne National Lab.
113: *     Jeremy Du Croz, Nag Central Office.
114: *     Sven Hammarling, Nag Central Office.
115: *     Richard Hanson, Sandia National Labs.
116: *  -- Modified for the absolute-value product, April 2006
117: *     Jason Riedy, UC Berkeley
118: *
119: *  =====================================================================
120: *
121: *     .. Parameters ..
122:       REAL               ONE, ZERO
123:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
124: *     ..
125: *     .. Local Scalars ..
126:       LOGICAL            SYMB_ZERO
127:       REAL               TEMP, SAFE1
128:       INTEGER            I, INFO, IY, J, JX, KX, KY
129:       COMPLEX            ZDUM
130: *     ..
131: *     .. External Subroutines ..
132:       EXTERNAL           XERBLA, SLAMCH
133:       REAL               SLAMCH
134: *     ..
135: *     .. External Functions ..
136:       EXTERNAL           ILAUPLO
137:       INTEGER            ILAUPLO
138: *     ..
139: *     .. Intrinsic Functions ..
140:       INTRINSIC          MAX, ABS, SIGN, REAL, AIMAG
141: *     ..
142: *     .. Statement Functions ..
143:       REAL               CABS1
144: *     ..
145: *     .. Statement Function Definitions ..
146:       CABS1( ZDUM ) = ABS( REAL ( ZDUM ) ) + ABS( AIMAG ( ZDUM ) )
147: *     ..
148: *     .. Executable Statements ..
149: *
150: *     Test the input parameters.
151: *
152:       INFO = 0
153:       IF     ( UPLO.NE.ILAUPLO( 'U' ) .AND.
154:      $         UPLO.NE.ILAUPLO( 'L' ) )THEN
155:          INFO = 1
156:       ELSE IF( N.LT.0 )THEN
157:          INFO = 2
158:       ELSE IF( LDA.LT.MAX( 1, N ) )THEN
159:          INFO = 5
160:       ELSE IF( INCX.EQ.0 )THEN
161:          INFO = 7
162:       ELSE IF( INCY.EQ.0 )THEN
163:          INFO = 10
164:       END IF
165:       IF( INFO.NE.0 )THEN
166:          CALL XERBLA( 'SSYMV ', INFO )
167:          RETURN
168:       END IF
169: *
170: *     Quick return if possible.
171: *
172:       IF( ( N.EQ.0 ).OR.( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
173:      $   RETURN
174: *
175: *     Set up the start points in  X  and  Y.
176: *
177:       IF( INCX.GT.0 )THEN
178:          KX = 1
179:       ELSE
180:          KX = 1 - ( N - 1 )*INCX
181:       END IF
182:       IF( INCY.GT.0 )THEN
183:          KY = 1
184:       ELSE
185:          KY = 1 - ( N - 1 )*INCY
186:       END IF
187: *
188: *     Set SAFE1 essentially to be the underflow threshold times the
189: *     number of additions in each row.
190: *
191:       SAFE1 = SLAMCH( 'Safe minimum' )
192:       SAFE1 = (N+1)*SAFE1
193: *
194: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
195: *
196: *     The O(N^2) SYMB_ZERO tests could be replaced by O(N) queries to
197: *     the inexact flag.  Still doesn't help change the iteration order
198: *     to per-column.
199: *
200:       IY = KY
201:       IF ( INCX.EQ.1 ) THEN
202:          IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
203:             DO I = 1, N
204:                IF ( BETA .EQ. ZERO ) THEN
205:                   SYMB_ZERO = .TRUE.
206:                   Y( IY ) = 0.0
207:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
208:                   SYMB_ZERO = .TRUE.
209:                ELSE
210:                   SYMB_ZERO = .FALSE.
211:                   Y( IY ) = BETA * ABS( Y( IY ) )
212:                END IF
213:                IF ( ALPHA .NE. ZERO ) THEN
214:                   DO J = 1, I
215:                      TEMP = CABS1( A( J, I ) )
216:                      SYMB_ZERO = SYMB_ZERO .AND.
217:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
218: 
219:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
220:                   END DO
221:                   DO J = I+1, N
222:                      TEMP = CABS1( A( I, J ) )
223:                      SYMB_ZERO = SYMB_ZERO .AND.
224:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
225: 
226:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
227:                   END DO
228:                END IF
229: 
230:                IF ( .NOT.SYMB_ZERO )
231:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
232: 
233:                IY = IY + INCY
234:             END DO
235:          ELSE
236:             DO I = 1, N
237:                IF ( BETA .EQ. ZERO ) THEN
238:                   SYMB_ZERO = .TRUE.
239:                   Y( IY ) = 0.0
240:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
241:                   SYMB_ZERO = .TRUE.
242:                ELSE
243:                   SYMB_ZERO = .FALSE.
244:                   Y( IY ) = BETA * ABS( Y( IY ) )
245:                END IF
246:                IF ( ALPHA .NE. ZERO ) THEN
247:                   DO J = 1, I
248:                      TEMP = CABS1( A( I, J ) )
249:                      SYMB_ZERO = SYMB_ZERO .AND.
250:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
251: 
252:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
253:                   END DO
254:                   DO J = I+1, N
255:                      TEMP = CABS1( A( J, I ) )
256:                      SYMB_ZERO = SYMB_ZERO .AND.
257:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
258: 
259:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
260:                   END DO
261:                END IF
262: 
263:                IF ( .NOT.SYMB_ZERO )
264:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
265: 
266:                IY = IY + INCY
267:             END DO
268:          END IF
269:       ELSE
270:          IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
271:             DO I = 1, N
272:                IF ( BETA .EQ. ZERO ) THEN
273:                   SYMB_ZERO = .TRUE.
274:                   Y( IY ) = 0.0
275:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
276:                   SYMB_ZERO = .TRUE.
277:                ELSE
278:                   SYMB_ZERO = .FALSE.
279:                   Y( IY ) = BETA * ABS( Y( IY ) )
280:                END IF
281:                JX = KX
282:                IF ( ALPHA .NE. ZERO ) THEN
283:                   DO J = 1, I
284:                      TEMP = CABS1( A( J, I ) )
285:                      SYMB_ZERO = SYMB_ZERO .AND.
286:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
287: 
288:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
289:                      JX = JX + INCX
290:                   END DO
291:                   DO J = I+1, N
292:                      TEMP = CABS1( A( I, J ) )
293:                      SYMB_ZERO = SYMB_ZERO .AND.
294:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
295: 
296:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
297:                      JX = JX + INCX
298:                   END DO
299:                END IF
300: 
301:                IF ( .NOT.SYMB_ZERO )
302:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
303: 
304:                IY = IY + INCY
305:             END DO
306:          ELSE
307:             DO I = 1, N
308:                IF ( BETA .EQ. ZERO ) THEN
309:                   SYMB_ZERO = .TRUE.
310:                   Y( IY ) = 0.0
311:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
312:                   SYMB_ZERO = .TRUE.
313:                ELSE
314:                   SYMB_ZERO = .FALSE.
315:                   Y( IY ) = BETA * ABS( Y( IY ) )
316:                END IF
317:                JX = KX
318:                IF ( ALPHA .NE. ZERO ) THEN
319:                   DO J = 1, I
320:                      TEMP = CABS1( A( I, J ) )
321:                      SYMB_ZERO = SYMB_ZERO .AND.
322:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
323: 
324:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
325:                      JX = JX + INCX
326:                   END DO
327:                   DO J = I+1, N
328:                      TEMP = CABS1( A( J, I ) )
329:                      SYMB_ZERO = SYMB_ZERO .AND.
330:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
331: 
332:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
333:                      JX = JX + INCX
334:                   END DO
335:                END IF
336: 
337:                IF ( .NOT.SYMB_ZERO )
338:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
339: 
340:                IY = IY + INCY
341:             END DO
342:          END IF
343: 
344:       END IF
345: *
346:       RETURN
347: *
348: *     End of CLA_SYAMV
349: *
350:       END
351: