001:       REAL FUNCTION CLA_PORCOND_C( UPLO, N, A, LDA, AF, LDAF, C, CAPPLY,
002:      $                             INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       LOGICAL            CAPPLY
017:       INTEGER            N, LDA, LDAF, INFO
018: *     ..
019: *     .. Array Arguments ..
020:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * )
021:       REAL               C( * ), RWORK( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *     CLA_PORCOND_C Computes the infinity norm condition number of
028: *     op(A) * inv(diag(C)) where C is a DOUBLE PRECISION vector
029: *
030: *  Arguments
031: *  =========
032: *
033: *     UPLO    (input) CHARACTER*1
034: *       = 'U':  Upper triangle of A is stored;
035: *       = 'L':  Lower triangle of A is stored.
036: *
037: *     N       (input) INTEGER
038: *     The number of linear equations, i.e., the order of the
039: *     matrix A.  N >= 0.
040: *
041: *     A       (input) COMPLEX array, dimension (LDA,N)
042: *     On entry, the N-by-N matrix A
043: *
044: *     LDA     (input) INTEGER
045: *     The leading dimension of the array A.  LDA >= max(1,N).
046: *
047: *     AF      (input) COMPLEX array, dimension (LDAF,N)
048: *     The triangular factor U or L from the Cholesky factorization
049: *     A = U**T*U or A = L*L**T, as computed by CPOTRF.
050: *
051: *     LDAF    (input) INTEGER
052: *     The leading dimension of the array AF.  LDAF >= max(1,N).
053: *
054: *     C       (input) REAL array, dimension (N)
055: *     The vector C in the formula op(A) * inv(diag(C)).
056: *
057: *     CAPPLY  (input) LOGICAL
058: *     If .TRUE. then access the vector C in the formula above.
059: *
060: *     INFO    (output) INTEGER
061: *       = 0:  Successful exit.
062: *     i > 0:  The ith argument is invalid.
063: *
064: *     WORK    (input) COMPLEX array, dimension (2*N).
065: *     Workspace.
066: *
067: *     RWORK   (input) REAL array, dimension (N).
068: *     Workspace.
069: *
070: *  =====================================================================
071: *
072: *     .. Local Scalars ..
073:       INTEGER            KASE
074:       REAL               AINVNM, ANORM, TMP
075:       INTEGER            I, J
076:       LOGICAL            UP
077:       COMPLEX            ZDUM
078: *     ..
079: *     .. Local Arrays ..
080:       INTEGER            ISAVE( 3 )
081: *     ..
082: *     .. External Functions ..
083:       LOGICAL            LSAME
084:       EXTERNAL           LSAME
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           CLACN2, CPOTRS, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          ABS, MAX, REAL, AIMAG
091: *     ..
092: *     .. Statement Functions ..
093:       REAL CABS1
094: *     ..
095: *     .. Statement Function Definitions ..
096:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
097: *     ..
098: *     .. Executable Statements ..
099: *
100:       CLA_PORCOND_C = 0.0E+0
101: *
102:       INFO = 0
103:       IF( N.LT.0 ) THEN
104:          INFO = -2
105:       END IF
106:       IF( INFO.NE.0 ) THEN
107:          CALL XERBLA( 'CLA_PORCOND_C', -INFO )
108:          RETURN
109:       END IF
110:       UP = .FALSE.
111:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
112: *
113: *     Compute norm of op(A)*op2(C).
114: *
115:       ANORM = 0.0E+0
116:       IF ( UP ) THEN
117:          DO I = 1, N
118:             TMP = 0.0E+0
119:             IF ( CAPPLY ) THEN
120:                DO J = 1, I
121:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
122:                END DO
123:                DO J = I+1, N
124:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
125:                END DO
126:             ELSE
127:                DO J = 1, I
128:                   TMP = TMP + CABS1( A( J, I ) )
129:                END DO
130:                DO J = I+1, N
131:                   TMP = TMP + CABS1( A( I, J ) )
132:                END DO
133:             END IF
134:             RWORK( I ) = TMP
135:             ANORM = MAX( ANORM, TMP )
136:          END DO
137:       ELSE
138:          DO I = 1, N
139:             TMP = 0.0E+0
140:             IF ( CAPPLY ) THEN
141:                DO J = 1, I
142:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
143:                END DO
144:                DO J = I+1, N
145:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
146:                END DO
147:             ELSE
148:                DO J = 1, I
149:                   TMP = TMP + CABS1( A( I, J ) )
150:                END DO
151:                DO J = I+1, N
152:                   TMP = TMP + CABS1( A( J, I ) )
153:                END DO
154:             END IF
155:             RWORK( I ) = TMP
156:             ANORM = MAX( ANORM, TMP )
157:          END DO
158:       END IF
159: *
160: *     Quick return if possible.
161: *
162:       IF( N.EQ.0 ) THEN
163:          CLA_PORCOND_C = 1.0E+0
164:          RETURN
165:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
166:          RETURN
167:       END IF
168: *
169: *     Estimate the norm of inv(op(A)).
170: *
171:       AINVNM = 0.0E+0
172: *
173:       KASE = 0
174:    10 CONTINUE
175:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
176:       IF( KASE.NE.0 ) THEN
177:          IF( KASE.EQ.2 ) THEN
178: *
179: *           Multiply by R.
180: *
181:             DO I = 1, N
182:                WORK( I ) = WORK( I ) * RWORK( I )
183:             END DO
184: *
185:             IF ( UP ) THEN
186:                CALL CPOTRS( 'U', N, 1, AF, LDAF,
187:      $            WORK, N, INFO )
188:             ELSE
189:                CALL CPOTRS( 'L', N, 1, AF, LDAF,
190:      $            WORK, N, INFO )
191:             ENDIF
192: *
193: *           Multiply by inv(C).
194: *
195:             IF ( CAPPLY ) THEN
196:                DO I = 1, N
197:                   WORK( I ) = WORK( I ) * C( I )
198:                END DO
199:             END IF
200:          ELSE
201: *
202: *           Multiply by inv(C').
203: *
204:             IF ( CAPPLY ) THEN
205:                DO I = 1, N
206:                   WORK( I ) = WORK( I ) * C( I )
207:                END DO
208:             END IF
209: *
210:             IF ( UP ) THEN
211:                CALL CPOTRS( 'U', N, 1, AF, LDAF,
212:      $            WORK, N, INFO )
213:             ELSE
214:                CALL CPOTRS( 'L', N, 1, AF, LDAF,
215:      $            WORK, N, INFO )
216:             END IF
217: *
218: *           Multiply by R.
219: *
220:             DO I = 1, N
221:                WORK( I ) = WORK( I ) * RWORK( I )
222:             END DO
223:          END IF
224:          GO TO 10
225:       END IF
226: *
227: *     Compute the estimate of the reciprocal condition number.
228: *
229:       IF( AINVNM .NE. 0.0E+0 )
230:      $   CLA_PORCOND_C = 1.0E+0 / AINVNM
231: *
232:       RETURN
233: *
234:       END
235: