001:       SUBROUTINE CGETRI( N, A, LDA, IPIV, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDA, LWORK, N
010: *     ..
011: *     .. Array Arguments ..
012:       INTEGER            IPIV( * )
013:       COMPLEX            A( LDA, * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CGETRI computes the inverse of a matrix using the LU factorization
020: *  computed by CGETRF.
021: *
022: *  This method inverts U and then computes inv(A) by solving the system
023: *  inv(A)*L = inv(U) for inv(A).
024: *
025: *  Arguments
026: *  =========
027: *
028: *  N       (input) INTEGER
029: *          The order of the matrix A.  N >= 0.
030: *
031: *  A       (input/output) COMPLEX array, dimension (LDA,N)
032: *          On entry, the factors L and U from the factorization
033: *          A = P*L*U as computed by CGETRF.
034: *          On exit, if INFO = 0, the inverse of the original matrix A.
035: *
036: *  LDA     (input) INTEGER
037: *          The leading dimension of the array A.  LDA >= max(1,N).
038: *
039: *  IPIV    (input) INTEGER array, dimension (N)
040: *          The pivot indices from CGETRF; for 1<=i<=N, row i of the
041: *          matrix was interchanged with row IPIV(i).
042: *
043: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
044: *          On exit, if INFO=0, then WORK(1) returns the optimal LWORK.
045: *
046: *  LWORK   (input) INTEGER
047: *          The dimension of the array WORK.  LWORK >= max(1,N).
048: *          For optimal performance LWORK >= N*NB, where NB is
049: *          the optimal blocksize returned by ILAENV.
050: *
051: *          If LWORK = -1, then a workspace query is assumed; the routine
052: *          only calculates the optimal size of the WORK array, returns
053: *          this value as the first entry of the WORK array, and no error
054: *          message related to LWORK is issued by XERBLA.
055: *
056: *  INFO    (output) INTEGER
057: *          = 0:  successful exit
058: *          < 0:  if INFO = -i, the i-th argument had an illegal value
059: *          > 0:  if INFO = i, U(i,i) is exactly zero; the matrix is
060: *                singular and its inverse could not be computed.
061: *
062: *  =====================================================================
063: *
064: *     .. Parameters ..
065:       COMPLEX            ZERO, ONE
066:       PARAMETER          ( ZERO = ( 0.0E+0, 0.0E+0 ),
067:      $                   ONE = ( 1.0E+0, 0.0E+0 ) )
068: *     ..
069: *     .. Local Scalars ..
070:       LOGICAL            LQUERY
071:       INTEGER            I, IWS, J, JB, JJ, JP, LDWORK, LWKOPT, NB,
072:      $                   NBMIN, NN
073: *     ..
074: *     .. External Functions ..
075:       INTEGER            ILAENV
076:       EXTERNAL           ILAENV
077: *     ..
078: *     .. External Subroutines ..
079:       EXTERNAL           CGEMM, CGEMV, CSWAP, CTRSM, CTRTRI, XERBLA
080: *     ..
081: *     .. Intrinsic Functions ..
082:       INTRINSIC          MAX, MIN
083: *     ..
084: *     .. Executable Statements ..
085: *
086: *     Test the input parameters.
087: *
088:       INFO = 0
089:       NB = ILAENV( 1, 'CGETRI', ' ', N, -1, -1, -1 )
090:       LWKOPT = N*NB
091:       WORK( 1 ) = LWKOPT
092:       LQUERY = ( LWORK.EQ.-1 )
093:       IF( N.LT.0 ) THEN
094:          INFO = -1
095:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
096:          INFO = -3
097:       ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
098:          INFO = -6
099:       END IF
100:       IF( INFO.NE.0 ) THEN
101:          CALL XERBLA( 'CGETRI', -INFO )
102:          RETURN
103:       ELSE IF( LQUERY ) THEN
104:          RETURN
105:       END IF
106: *
107: *     Quick return if possible
108: *
109:       IF( N.EQ.0 )
110:      $   RETURN
111: *
112: *     Form inv(U).  If INFO > 0 from CTRTRI, then U is singular,
113: *     and the inverse is not computed.
114: *
115:       CALL CTRTRI( 'Upper', 'Non-unit', N, A, LDA, INFO )
116:       IF( INFO.GT.0 )
117:      $   RETURN
118: *
119:       NBMIN = 2
120:       LDWORK = N
121:       IF( NB.GT.1 .AND. NB.LT.N ) THEN
122:          IWS = MAX( LDWORK*NB, 1 )
123:          IF( LWORK.LT.IWS ) THEN
124:             NB = LWORK / LDWORK
125:             NBMIN = MAX( 2, ILAENV( 2, 'CGETRI', ' ', N, -1, -1, -1 ) )
126:          END IF
127:       ELSE
128:          IWS = N
129:       END IF
130: *
131: *     Solve the equation inv(A)*L = inv(U) for inv(A).
132: *
133:       IF( NB.LT.NBMIN .OR. NB.GE.N ) THEN
134: *
135: *        Use unblocked code.
136: *
137:          DO 20 J = N, 1, -1
138: *
139: *           Copy current column of L to WORK and replace with zeros.
140: *
141:             DO 10 I = J + 1, N
142:                WORK( I ) = A( I, J )
143:                A( I, J ) = ZERO
144:    10       CONTINUE
145: *
146: *           Compute current column of inv(A).
147: *
148:             IF( J.LT.N )
149:      $         CALL CGEMV( 'No transpose', N, N-J, -ONE, A( 1, J+1 ),
150:      $                     LDA, WORK( J+1 ), 1, ONE, A( 1, J ), 1 )
151:    20    CONTINUE
152:       ELSE
153: *
154: *        Use blocked code.
155: *
156:          NN = ( ( N-1 ) / NB )*NB + 1
157:          DO 50 J = NN, 1, -NB
158:             JB = MIN( NB, N-J+1 )
159: *
160: *           Copy current block column of L to WORK and replace with
161: *           zeros.
162: *
163:             DO 40 JJ = J, J + JB - 1
164:                DO 30 I = JJ + 1, N
165:                   WORK( I+( JJ-J )*LDWORK ) = A( I, JJ )
166:                   A( I, JJ ) = ZERO
167:    30          CONTINUE
168:    40       CONTINUE
169: *
170: *           Compute current block column of inv(A).
171: *
172:             IF( J+JB.LE.N )
173:      $         CALL CGEMM( 'No transpose', 'No transpose', N, JB,
174:      $                     N-J-JB+1, -ONE, A( 1, J+JB ), LDA,
175:      $                     WORK( J+JB ), LDWORK, ONE, A( 1, J ), LDA )
176:             CALL CTRSM( 'Right', 'Lower', 'No transpose', 'Unit', N, JB,
177:      $                  ONE, WORK( J ), LDWORK, A( 1, J ), LDA )
178:    50    CONTINUE
179:       END IF
180: *
181: *     Apply column interchanges.
182: *
183:       DO 60 J = N - 1, 1, -1
184:          JP = IPIV( J )
185:          IF( JP.NE.J )
186:      $      CALL CSWAP( N, A( 1, J ), 1, A( 1, JP ), 1 )
187:    60 CONTINUE
188: *
189:       WORK( 1 ) = IWS
190:       RETURN
191: *
192: *     End of CGETRI
193: *
194:       END
195: