001:       SUBROUTINE CGEEV( JOBVL, JOBVR, N, A, LDA, W, VL, LDVL, VR, LDVR,
002:      $                  WORK, LWORK, RWORK, INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          JOBVL, JOBVR
011:       INTEGER            INFO, LDA, LDVL, LDVR, LWORK, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               RWORK( * )
015:       COMPLEX            A( LDA, * ), VL( LDVL, * ), VR( LDVR, * ),
016:      $                   W( * ), WORK( * )
017: *     ..
018: *
019: *  Purpose
020: *  =======
021: *
022: *  CGEEV computes for an N-by-N complex nonsymmetric matrix A, the
023: *  eigenvalues and, optionally, the left and/or right eigenvectors.
024: *
025: *  The right eigenvector v(j) of A satisfies
026: *                   A * v(j) = lambda(j) * v(j)
027: *  where lambda(j) is its eigenvalue.
028: *  The left eigenvector u(j) of A satisfies
029: *                u(j)**H * A = lambda(j) * u(j)**H
030: *  where u(j)**H denotes the conjugate transpose of u(j).
031: *
032: *  The computed eigenvectors are normalized to have Euclidean norm
033: *  equal to 1 and largest component real.
034: *
035: *  Arguments
036: *  =========
037: *
038: *  JOBVL   (input) CHARACTER*1
039: *          = 'N': left eigenvectors of A are not computed;
040: *          = 'V': left eigenvectors of are computed.
041: *
042: *  JOBVR   (input) CHARACTER*1
043: *          = 'N': right eigenvectors of A are not computed;
044: *          = 'V': right eigenvectors of A are computed.
045: *
046: *  N       (input) INTEGER
047: *          The order of the matrix A. N >= 0.
048: *
049: *  A       (input/output) COMPLEX array, dimension (LDA,N)
050: *          On entry, the N-by-N matrix A.
051: *          On exit, A has been overwritten.
052: *
053: *  LDA     (input) INTEGER
054: *          The leading dimension of the array A.  LDA >= max(1,N).
055: *
056: *  W       (output) COMPLEX array, dimension (N)
057: *          W contains the computed eigenvalues.
058: *
059: *  VL      (output) COMPLEX array, dimension (LDVL,N)
060: *          If JOBVL = 'V', the left eigenvectors u(j) are stored one
061: *          after another in the columns of VL, in the same order
062: *          as their eigenvalues.
063: *          If JOBVL = 'N', VL is not referenced.
064: *          u(j) = VL(:,j), the j-th column of VL.
065: *
066: *  LDVL    (input) INTEGER
067: *          The leading dimension of the array VL.  LDVL >= 1; if
068: *          JOBVL = 'V', LDVL >= N.
069: *
070: *  VR      (output) COMPLEX array, dimension (LDVR,N)
071: *          If JOBVR = 'V', the right eigenvectors v(j) are stored one
072: *          after another in the columns of VR, in the same order
073: *          as their eigenvalues.
074: *          If JOBVR = 'N', VR is not referenced.
075: *          v(j) = VR(:,j), the j-th column of VR.
076: *
077: *  LDVR    (input) INTEGER
078: *          The leading dimension of the array VR.  LDVR >= 1; if
079: *          JOBVR = 'V', LDVR >= N.
080: *
081: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
082: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
083: *
084: *  LWORK   (input) INTEGER
085: *          The dimension of the array WORK.  LWORK >= max(1,2*N).
086: *          For good performance, LWORK must generally be larger.
087: *
088: *          If LWORK = -1, then a workspace query is assumed; the routine
089: *          only calculates the optimal size of the WORK array, returns
090: *          this value as the first entry of the WORK array, and no error
091: *          message related to LWORK is issued by XERBLA.
092: *
093: *  RWORK   (workspace) REAL array, dimension (2*N)
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
098: *          > 0:  if INFO = i, the QR algorithm failed to compute all the
099: *                eigenvalues, and no eigenvectors have been computed;
100: *                elements and i+1:N of W contain eigenvalues which have
101: *                converged.
102: *
103: *  =====================================================================
104: *
105: *     .. Parameters ..
106:       REAL               ZERO, ONE
107:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
108: *     ..
109: *     .. Local Scalars ..
110:       LOGICAL            LQUERY, SCALEA, WANTVL, WANTVR
111:       CHARACTER          SIDE
112:       INTEGER            HSWORK, I, IBAL, IERR, IHI, ILO, IRWORK, ITAU,
113:      $                   IWRK, K, MAXWRK, MINWRK, NOUT
114:       REAL               ANRM, BIGNUM, CSCALE, EPS, SCL, SMLNUM
115:       COMPLEX            TMP
116: *     ..
117: *     .. Local Arrays ..
118:       LOGICAL            SELECT( 1 )
119:       REAL               DUM( 1 )
120: *     ..
121: *     .. External Subroutines ..
122:       EXTERNAL           CGEBAK, CGEBAL, CGEHRD, CHSEQR, CLACPY, CLASCL,
123:      $                   CSCAL, CSSCAL, CTREVC, CUNGHR, SLABAD, XERBLA
124: *     ..
125: *     .. External Functions ..
126:       LOGICAL            LSAME
127:       INTEGER            ILAENV, ISAMAX
128:       REAL               CLANGE, SCNRM2, SLAMCH
129:       EXTERNAL           LSAME, ILAENV, ISAMAX, CLANGE, SCNRM2, SLAMCH
130: *     ..
131: *     .. Intrinsic Functions ..
132:       INTRINSIC          AIMAG, CMPLX, CONJG, MAX, REAL, SQRT
133: *     ..
134: *     .. Executable Statements ..
135: *
136: *     Test the input arguments
137: *
138:       INFO = 0
139:       LQUERY = ( LWORK.EQ.-1 )
140:       WANTVL = LSAME( JOBVL, 'V' )
141:       WANTVR = LSAME( JOBVR, 'V' )
142:       IF( ( .NOT.WANTVL ) .AND. ( .NOT.LSAME( JOBVL, 'N' ) ) ) THEN
143:          INFO = -1
144:       ELSE IF( ( .NOT.WANTVR ) .AND. ( .NOT.LSAME( JOBVR, 'N' ) ) ) THEN
145:          INFO = -2
146:       ELSE IF( N.LT.0 ) THEN
147:          INFO = -3
148:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
149:          INFO = -5
150:       ELSE IF( LDVL.LT.1 .OR. ( WANTVL .AND. LDVL.LT.N ) ) THEN
151:          INFO = -8
152:       ELSE IF( LDVR.LT.1 .OR. ( WANTVR .AND. LDVR.LT.N ) ) THEN
153:          INFO = -10
154:       END IF
155: 
156: *
157: *     Compute workspace
158: *      (Note: Comments in the code beginning "Workspace:" describe the
159: *       minimal amount of workspace needed at that point in the code,
160: *       as well as the preferred amount for good performance.
161: *       CWorkspace refers to complex workspace, and RWorkspace to real
162: *       workspace. NB refers to the optimal block size for the
163: *       immediately following subroutine, as returned by ILAENV.
164: *       HSWORK refers to the workspace preferred by CHSEQR, as
165: *       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
166: *       the worst case.)
167: *
168:       IF( INFO.EQ.0 ) THEN
169:          IF( N.EQ.0 ) THEN
170:             MINWRK = 1
171:             MAXWRK = 1
172:          ELSE
173:             MAXWRK = N + N*ILAENV( 1, 'CGEHRD', ' ', N, 1, N, 0 )
174:             MINWRK = 2*N
175:             IF( WANTVL ) THEN
176:                MAXWRK = MAX( MAXWRK, N + ( N - 1 )*ILAENV( 1, 'CUNGHR',
177:      $                       ' ', N, 1, N, -1 ) )
178:                CALL CHSEQR( 'S', 'V', N, 1, N, A, LDA, W, VL, LDVL,
179:      $                WORK, -1, INFO )
180:             ELSE IF( WANTVR ) THEN
181:                MAXWRK = MAX( MAXWRK, N + ( N - 1 )*ILAENV( 1, 'CUNGHR',
182:      $                       ' ', N, 1, N, -1 ) )
183:                CALL CHSEQR( 'S', 'V', N, 1, N, A, LDA, W, VR, LDVR,
184:      $                WORK, -1, INFO )
185:             ELSE
186:                CALL CHSEQR( 'E', 'N', N, 1, N, A, LDA, W, VR, LDVR,
187:      $                WORK, -1, INFO )
188:             END IF
189:             HSWORK = WORK( 1 )
190:             MAXWRK = MAX( MAXWRK, HSWORK, MINWRK )
191:          END IF
192:          WORK( 1 ) = MAXWRK
193: *
194:          IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
195:             INFO = -12
196:          END IF
197:       END IF
198: *
199:       IF( INFO.NE.0 ) THEN
200:          CALL XERBLA( 'CGEEV ', -INFO )
201:          RETURN
202:       ELSE IF( LQUERY ) THEN
203:          RETURN
204:       END IF
205: *
206: *     Quick return if possible
207: *
208:       IF( N.EQ.0 )
209:      $   RETURN
210: *
211: *     Get machine constants
212: *
213:       EPS = SLAMCH( 'P' )
214:       SMLNUM = SLAMCH( 'S' )
215:       BIGNUM = ONE / SMLNUM
216:       CALL SLABAD( SMLNUM, BIGNUM )
217:       SMLNUM = SQRT( SMLNUM ) / EPS
218:       BIGNUM = ONE / SMLNUM
219: *
220: *     Scale A if max element outside range [SMLNUM,BIGNUM]
221: *
222:       ANRM = CLANGE( 'M', N, N, A, LDA, DUM )
223:       SCALEA = .FALSE.
224:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
225:          SCALEA = .TRUE.
226:          CSCALE = SMLNUM
227:       ELSE IF( ANRM.GT.BIGNUM ) THEN
228:          SCALEA = .TRUE.
229:          CSCALE = BIGNUM
230:       END IF
231:       IF( SCALEA )
232:      $   CALL CLASCL( 'G', 0, 0, ANRM, CSCALE, N, N, A, LDA, IERR )
233: *
234: *     Balance the matrix
235: *     (CWorkspace: none)
236: *     (RWorkspace: need N)
237: *
238:       IBAL = 1
239:       CALL CGEBAL( 'B', N, A, LDA, ILO, IHI, RWORK( IBAL ), IERR )
240: *
241: *     Reduce to upper Hessenberg form
242: *     (CWorkspace: need 2*N, prefer N+N*NB)
243: *     (RWorkspace: none)
244: *
245:       ITAU = 1
246:       IWRK = ITAU + N
247:       CALL CGEHRD( N, ILO, IHI, A, LDA, WORK( ITAU ), WORK( IWRK ),
248:      $             LWORK-IWRK+1, IERR )
249: *
250:       IF( WANTVL ) THEN
251: *
252: *        Want left eigenvectors
253: *        Copy Householder vectors to VL
254: *
255:          SIDE = 'L'
256:          CALL CLACPY( 'L', N, N, A, LDA, VL, LDVL )
257: *
258: *        Generate unitary matrix in VL
259: *        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
260: *        (RWorkspace: none)
261: *
262:          CALL CUNGHR( N, ILO, IHI, VL, LDVL, WORK( ITAU ), WORK( IWRK ),
263:      $                LWORK-IWRK+1, IERR )
264: *
265: *        Perform QR iteration, accumulating Schur vectors in VL
266: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
267: *        (RWorkspace: none)
268: *
269:          IWRK = ITAU
270:          CALL CHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, W, VL, LDVL,
271:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
272: *
273:          IF( WANTVR ) THEN
274: *
275: *           Want left and right eigenvectors
276: *           Copy Schur vectors to VR
277: *
278:             SIDE = 'B'
279:             CALL CLACPY( 'F', N, N, VL, LDVL, VR, LDVR )
280:          END IF
281: *
282:       ELSE IF( WANTVR ) THEN
283: *
284: *        Want right eigenvectors
285: *        Copy Householder vectors to VR
286: *
287:          SIDE = 'R'
288:          CALL CLACPY( 'L', N, N, A, LDA, VR, LDVR )
289: *
290: *        Generate unitary matrix in VR
291: *        (CWorkspace: need 2*N-1, prefer N+(N-1)*NB)
292: *        (RWorkspace: none)
293: *
294:          CALL CUNGHR( N, ILO, IHI, VR, LDVR, WORK( ITAU ), WORK( IWRK ),
295:      $                LWORK-IWRK+1, IERR )
296: *
297: *        Perform QR iteration, accumulating Schur vectors in VR
298: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
299: *        (RWorkspace: none)
300: *
301:          IWRK = ITAU
302:          CALL CHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, W, VR, LDVR,
303:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
304: *
305:       ELSE
306: *
307: *        Compute eigenvalues only
308: *        (CWorkspace: need 1, prefer HSWORK (see comments) )
309: *        (RWorkspace: none)
310: *
311:          IWRK = ITAU
312:          CALL CHSEQR( 'E', 'N', N, ILO, IHI, A, LDA, W, VR, LDVR,
313:      $                WORK( IWRK ), LWORK-IWRK+1, INFO )
314:       END IF
315: *
316: *     If INFO > 0 from CHSEQR, then quit
317: *
318:       IF( INFO.GT.0 )
319:      $   GO TO 50
320: *
321:       IF( WANTVL .OR. WANTVR ) THEN
322: *
323: *        Compute left and/or right eigenvectors
324: *        (CWorkspace: need 2*N)
325: *        (RWorkspace: need 2*N)
326: *
327:          IRWORK = IBAL + N
328:          CALL CTREVC( SIDE, 'B', SELECT, N, A, LDA, VL, LDVL, VR, LDVR,
329:      $                N, NOUT, WORK( IWRK ), RWORK( IRWORK ), IERR )
330:       END IF
331: *
332:       IF( WANTVL ) THEN
333: *
334: *        Undo balancing of left eigenvectors
335: *        (CWorkspace: none)
336: *        (RWorkspace: need N)
337: *
338:          CALL CGEBAK( 'B', 'L', N, ILO, IHI, RWORK( IBAL ), N, VL, LDVL,
339:      $                IERR )
340: *
341: *        Normalize left eigenvectors and make largest component real
342: *
343:          DO 20 I = 1, N
344:             SCL = ONE / SCNRM2( N, VL( 1, I ), 1 )
345:             CALL CSSCAL( N, SCL, VL( 1, I ), 1 )
346:             DO 10 K = 1, N
347:                RWORK( IRWORK+K-1 ) = REAL( VL( K, I ) )**2 +
348:      $                               AIMAG( VL( K, I ) )**2
349:    10       CONTINUE
350:             K = ISAMAX( N, RWORK( IRWORK ), 1 )
351:             TMP = CONJG( VL( K, I ) ) / SQRT( RWORK( IRWORK+K-1 ) )
352:             CALL CSCAL( N, TMP, VL( 1, I ), 1 )
353:             VL( K, I ) = CMPLX( REAL( VL( K, I ) ), ZERO )
354:    20    CONTINUE
355:       END IF
356: *
357:       IF( WANTVR ) THEN
358: *
359: *        Undo balancing of right eigenvectors
360: *        (CWorkspace: none)
361: *        (RWorkspace: need N)
362: *
363:          CALL CGEBAK( 'B', 'R', N, ILO, IHI, RWORK( IBAL ), N, VR, LDVR,
364:      $                IERR )
365: *
366: *        Normalize right eigenvectors and make largest component real
367: *
368:          DO 40 I = 1, N
369:             SCL = ONE / SCNRM2( N, VR( 1, I ), 1 )
370:             CALL CSSCAL( N, SCL, VR( 1, I ), 1 )
371:             DO 30 K = 1, N
372:                RWORK( IRWORK+K-1 ) = REAL( VR( K, I ) )**2 +
373:      $                               AIMAG( VR( K, I ) )**2
374:    30       CONTINUE
375:             K = ISAMAX( N, RWORK( IRWORK ), 1 )
376:             TMP = CONJG( VR( K, I ) ) / SQRT( RWORK( IRWORK+K-1 ) )
377:             CALL CSCAL( N, TMP, VR( 1, I ), 1 )
378:             VR( K, I ) = CMPLX( REAL( VR( K, I ) ), ZERO )
379:    40    CONTINUE
380:       END IF
381: *
382: *     Undo scaling if necessary
383: *
384:    50 CONTINUE
385:       IF( SCALEA ) THEN
386:          CALL CLASCL( 'G', 0, 0, CSCALE, ANRM, N-INFO, 1, W( INFO+1 ),
387:      $                MAX( N-INFO, 1 ), IERR )
388:          IF( INFO.GT.0 ) THEN
389:             CALL CLASCL( 'G', 0, 0, CSCALE, ANRM, ILO-1, 1, W, N, IERR )
390:          END IF
391:       END IF
392: *
393:       WORK( 1 ) = MAXWRK
394:       RETURN
395: *
396: *     End of CGEEV
397: *
398:       END
399: