001:       SUBROUTINE ZUNGR2( M, N, K, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, K, LDA, M, N
009: *     ..
010: *     .. Array Arguments ..
011:       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  ZUNGR2 generates an m by n complex matrix Q with orthonormal rows,
018: *  which is defined as the last m rows of a product of k elementary
019: *  reflectors of order n
020: *
021: *        Q  =  H(1)' H(2)' . . . H(k)'
022: *
023: *  as returned by ZGERQF.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  M       (input) INTEGER
029: *          The number of rows of the matrix Q. M >= 0.
030: *
031: *  N       (input) INTEGER
032: *          The number of columns of the matrix Q. N >= M.
033: *
034: *  K       (input) INTEGER
035: *          The number of elementary reflectors whose product defines the
036: *          matrix Q. M >= K >= 0.
037: *
038: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
039: *          On entry, the (m-k+i)-th row must contain the vector which
040: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
041: *          returned by ZGERQF in the last k rows of its array argument
042: *          A.
043: *          On exit, the m-by-n matrix Q.
044: *
045: *  LDA     (input) INTEGER
046: *          The first dimension of the array A. LDA >= max(1,M).
047: *
048: *  TAU     (input) COMPLEX*16 array, dimension (K)
049: *          TAU(i) must contain the scalar factor of the elementary
050: *          reflector H(i), as returned by ZGERQF.
051: *
052: *  WORK    (workspace) COMPLEX*16 array, dimension (M)
053: *
054: *  INFO    (output) INTEGER
055: *          = 0: successful exit
056: *          < 0: if INFO = -i, the i-th argument has an illegal value
057: *
058: *  =====================================================================
059: *
060: *     .. Parameters ..
061:       COMPLEX*16         ONE, ZERO
062:       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ),
063:      $                   ZERO = ( 0.0D+0, 0.0D+0 ) )
064: *     ..
065: *     .. Local Scalars ..
066:       INTEGER            I, II, J, L
067: *     ..
068: *     .. External Subroutines ..
069:       EXTERNAL           XERBLA, ZLACGV, ZLARF, ZSCAL
070: *     ..
071: *     .. Intrinsic Functions ..
072:       INTRINSIC          DCONJG, MAX
073: *     ..
074: *     .. Executable Statements ..
075: *
076: *     Test the input arguments
077: *
078:       INFO = 0
079:       IF( M.LT.0 ) THEN
080:          INFO = -1
081:       ELSE IF( N.LT.M ) THEN
082:          INFO = -2
083:       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
084:          INFO = -3
085:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
086:          INFO = -5
087:       END IF
088:       IF( INFO.NE.0 ) THEN
089:          CALL XERBLA( 'ZUNGR2', -INFO )
090:          RETURN
091:       END IF
092: *
093: *     Quick return if possible
094: *
095:       IF( M.LE.0 )
096:      $   RETURN
097: *
098:       IF( K.LT.M ) THEN
099: *
100: *        Initialise rows 1:m-k to rows of the unit matrix
101: *
102:          DO 20 J = 1, N
103:             DO 10 L = 1, M - K
104:                A( L, J ) = ZERO
105:    10       CONTINUE
106:             IF( J.GT.N-M .AND. J.LE.N-K )
107:      $         A( M-N+J, J ) = ONE
108:    20    CONTINUE
109:       END IF
110: *
111:       DO 40 I = 1, K
112:          II = M - K + I
113: *
114: *        Apply H(i)' to A(1:m-k+i,1:n-k+i) from the right
115: *
116:          CALL ZLACGV( N-M+II-1, A( II, 1 ), LDA )
117:          A( II, N-M+II ) = ONE
118:          CALL ZLARF( 'Right', II-1, N-M+II, A( II, 1 ), LDA,
119:      $               DCONJG( TAU( I ) ), A, LDA, WORK )
120:          CALL ZSCAL( N-M+II-1, -TAU( I ), A( II, 1 ), LDA )
121:          CALL ZLACGV( N-M+II-1, A( II, 1 ), LDA )
122:          A( II, N-M+II ) = ONE - DCONJG( TAU( I ) )
123: *
124: *        Set A(m-k+i,n-k+i+1:n) to zero
125: *
126:          DO 30 L = N - M + II + 1, N
127:             A( II, L ) = ZERO
128:    30    CONTINUE
129:    40 CONTINUE
130:       RETURN
131: *
132: *     End of ZUNGR2
133: *
134:       END
135: