001:       SUBROUTINE ZTRTI2( UPLO, DIAG, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          DIAG, UPLO
009:       INTEGER            INFO, LDA, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX*16         A( LDA, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZTRTI2 computes the inverse of a complex upper or lower triangular
019: *  matrix.
020: *
021: *  This is the Level 2 BLAS version of the algorithm.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  UPLO    (input) CHARACTER*1
027: *          Specifies whether the matrix A is upper or lower triangular.
028: *          = 'U':  Upper triangular
029: *          = 'L':  Lower triangular
030: *
031: *  DIAG    (input) CHARACTER*1
032: *          Specifies whether or not the matrix A is unit triangular.
033: *          = 'N':  Non-unit triangular
034: *          = 'U':  Unit triangular
035: *
036: *  N       (input) INTEGER
037: *          The order of the matrix A.  N >= 0.
038: *
039: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
040: *          On entry, the triangular matrix A.  If UPLO = 'U', the
041: *          leading n by n upper triangular part of the array A contains
042: *          the upper triangular matrix, and the strictly lower
043: *          triangular part of A is not referenced.  If UPLO = 'L', the
044: *          leading n by n lower triangular part of the array A contains
045: *          the lower triangular matrix, and the strictly upper
046: *          triangular part of A is not referenced.  If DIAG = 'U', the
047: *          diagonal elements of A are also not referenced and are
048: *          assumed to be 1.
049: *
050: *          On exit, the (triangular) inverse of the original matrix, in
051: *          the same storage format.
052: *
053: *  LDA     (input) INTEGER
054: *          The leading dimension of the array A.  LDA >= max(1,N).
055: *
056: *  INFO    (output) INTEGER
057: *          = 0: successful exit
058: *          < 0: if INFO = -k, the k-th argument had an illegal value
059: *
060: *  =====================================================================
061: *
062: *     .. Parameters ..
063:       COMPLEX*16         ONE
064:       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ) )
065: *     ..
066: *     .. Local Scalars ..
067:       LOGICAL            NOUNIT, UPPER
068:       INTEGER            J
069:       COMPLEX*16         AJJ
070: *     ..
071: *     .. External Functions ..
072:       LOGICAL            LSAME
073:       EXTERNAL           LSAME
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           XERBLA, ZSCAL, ZTRMV
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC          MAX
080: *     ..
081: *     .. Executable Statements ..
082: *
083: *     Test the input parameters.
084: *
085:       INFO = 0
086:       UPPER = LSAME( UPLO, 'U' )
087:       NOUNIT = LSAME( DIAG, 'N' )
088:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
089:          INFO = -1
090:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
091:          INFO = -2
092:       ELSE IF( N.LT.0 ) THEN
093:          INFO = -3
094:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
095:          INFO = -5
096:       END IF
097:       IF( INFO.NE.0 ) THEN
098:          CALL XERBLA( 'ZTRTI2', -INFO )
099:          RETURN
100:       END IF
101: *
102:       IF( UPPER ) THEN
103: *
104: *        Compute inverse of upper triangular matrix.
105: *
106:          DO 10 J = 1, N
107:             IF( NOUNIT ) THEN
108:                A( J, J ) = ONE / A( J, J )
109:                AJJ = -A( J, J )
110:             ELSE
111:                AJJ = -ONE
112:             END IF
113: *
114: *           Compute elements 1:j-1 of j-th column.
115: *
116:             CALL ZTRMV( 'Upper', 'No transpose', DIAG, J-1, A, LDA,
117:      $                  A( 1, J ), 1 )
118:             CALL ZSCAL( J-1, AJJ, A( 1, J ), 1 )
119:    10    CONTINUE
120:       ELSE
121: *
122: *        Compute inverse of lower triangular matrix.
123: *
124:          DO 20 J = N, 1, -1
125:             IF( NOUNIT ) THEN
126:                A( J, J ) = ONE / A( J, J )
127:                AJJ = -A( J, J )
128:             ELSE
129:                AJJ = -ONE
130:             END IF
131:             IF( J.LT.N ) THEN
132: *
133: *              Compute elements j+1:n of j-th column.
134: *
135:                CALL ZTRMV( 'Lower', 'No transpose', DIAG, N-J,
136:      $                     A( J+1, J+1 ), LDA, A( J+1, J ), 1 )
137:                CALL ZSCAL( N-J, AJJ, A( J+1, J ), 1 )
138:             END IF
139:    20    CONTINUE
140:       END IF
141: *
142:       RETURN
143: *
144: *     End of ZTRTI2
145: *
146:       END
147: